-
Notifications
You must be signed in to change notification settings - Fork 80
/
timers.clj
129 lines (101 loc) · 2.97 KB
/
timers.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
(ns metrics.timers
(:require [metrics.core :refer [default-registry metric-name]]
[metrics.utils :refer [get-percentiles desugared-title snapshot]])
(:import [com.codahale.metrics MetricRegistry Timer Timer$Context]
java.util.concurrent.TimeUnit))
(defn ^com.codahale.metrics.Timer timer
"Create and return a new Timer metric with the given title. If a
Timer already exists with the given title, will return that Timer.
Title can be a plain string like \"foo\" or a vector of three strings (group,
type, and title) like:
[\"myapp\" \"webserver\" \"connections\"]
"
([title]
(timer default-registry title))
([^MetricRegistry reg title]
(.timer reg (metric-name title))))
(defmacro deftimer
"Define a new Timer metric with the given title.
The title uses some basic desugaring to let you concisely define metrics:
; Define a timer titled \"default.default.foo\" into var foo
(deftimer foo)
(deftimer \"foo\")
; Define a timer titled \"a.b.c\" into var c
(deftimer [a b c])
(deftimer [\"a\" \"b\" \"c\"])
(deftimer [a \"b\" c])
"
([title]
(let [[s title] (desugared-title title)]
`(def ~s (timer '~title))))
([^MetricRegistry reg title]
(let [[s title] (desugared-title title)]
`(def ~s (timer ~reg '~title)))))
(defn rate-one
[^Timer m]
(.getOneMinuteRate m))
(defn rate-five
[^Timer m]
(.getFiveMinuteRate m))
(defn rate-fifteen
[^Timer m]
(.getFifteenMinuteRate m))
(defn rate-mean
[^Timer m]
(.getMeanRate m))
(defn ^long number-recorded
[^Timer t]
(.getCount t))
(defn rates
[^Timer m]
{1 (rate-one m)
5 (rate-five m)
15 (rate-fifteen m)
:total (number-recorded m)})
(defn mean
[^Timer t]
(.getMean (snapshot t)))
(defn std-dev
[^Timer t]
(.getStdDev (snapshot t)))
(defn percentiles
"Returns timing percentiles seen by a timer, in nanoseconds"
([^Timer t]
(percentiles t [0.75 0.95 0.99 0.999 1.0]))
([^Timer t ps]
(get-percentiles t ps)))
(defn largest
"Returns the greatest timing seen by a timer, in nanoseconds"
[^Timer t]
(.getMax (snapshot t)))
(defn smallest
"Returns the smallest timing seen by a timer, in nanoseconds"
[^Timer t]
(.getMin (snapshot t)))
(defn sample
[^Timer t]
(.getValues (snapshot t)))
(defmacro time!
[^Timer t & body]
`(.time ~(vary-meta t assoc :tag `Timer)
(proxy [Callable] []
(call [] (do ~@body)))))
(defn time-fn!
[^Timer t ^clojure.lang.IFn f]
(.time t (cast Callable f)))
(defn start
"Start a timer, returning the context object that will be used to
stop this particular instance."
^com.codahale.metrics.Timer$Context [^Timer t]
(.time t))
(defn stop
"Stop an instance of a timer, given the Timer$Context instance that
was returned when it was started."
[^Timer$Context tc]
(.stop tc))
(defmacro start-stop-time!
[^Timer t & body]
`(let [^Timer$Context start# (start ~t)
out# (do ~@body)]
(metrics.timers/stop start#)
out#))