forked from modelica/ModelicaSpecification
/
Parser_expressions.g
145 lines (112 loc) · 2.51 KB
/
Parser_expressions.g
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
parser grammar Parser_expressions;
// Expressions
start_rule: expression;
expression :
simple_expression
| 'if' expression 'then' expression ( 'elseif' expression 'then' expression )*
'else' expression
;
simple_expression :
logical_expression ( ':' logical_expression ( ':' logical_expression )? )?
;
logical_expression :
logical_term ( 'or' logical_term )*
;
logical_term :
logical_factor ( 'and' logical_factor )*
;
logical_factor :
'not'? relation
;
relation :
arithmetic_expression ( relational_operator arithmetic_expression )?
;
relational_operator :
'<' | '<=' | '>' | '>=' | '==' | '<>'
;
arithmetic_expression :
add_operator? term ( add_operator term )*
;
add_operator :
'+' | '-' | '.+' | '.-'
;
term :
factor ( mul_operator factor )*
;
mul_operator :
'*' | '/' | '.*' | './'
;
factor :
primary ( ('^' | '.^') primary )?
;
primary :
UNSIGNED_NUMBER
| STRING
| 'false'
| 'true'
| ('der' | 'initial' | 'pure' ) function_call_args
| component_reference function_call_args?
| '(' output_expression_list ')'
| '[' expression_list ( ';' expression_list )* ']'
| '{' array_arguments '}'
| 'end'
;
type_specifier :
'.'? name
;
name :
IDENT ( '.' IDENT )*
;
component_reference :
'.'? IDENT array_subscripts? ( '.' IDENT array_subscripts? )*
;
function_call_args :
'(' function_arguments? ')'
;
function_arguments
: expression ( ',' function_arguments_non_first | 'for' for_indices )?
| function_partial_application (',' function_arguments_non_first)?
| named_arguments
;
function_arguments_non_first
: ( function_argument (',' function_arguments_non_first)?
| named_arguments
)
;
array_arguments :
expression ( ( ',' expression /* TODO: This changed the grammar */ )* | 'for' for_indices )
;
named_arguments :
named_argument ( ',' named_argument )* /* TODO: Changed to repetition */
;
named_argument :
IDENT '=' function_argument
;
function_argument
: function_partial_application
| expression
;
function_partial_application /* TODO: This is a new rule; refactored out */
: 'function' type_specifier '(' named_arguments? ')'
;
output_expression_list :
expression? ( ',' expression? )*
;
expression_list :
expression ( ',' expression? )*
;
array_subscripts :
'[' subscript ( ',' subscript )* ']'
;
subscript :
':' | expression
;
comment :
string_comment annotation_comment?
;
string_comment :
( STRING ( '+' STRING )* )?
;
annotation_comment :
'annotation' class_modification
;