forked from factor/factor
-
Notifications
You must be signed in to change notification settings - Fork 3
/
tables.factor
316 lines (250 loc) · 8.37 KB
/
tables.factor
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
! Copyright (C) 2008, 2009 Slava Pestov.
! See http://factorcode.org/license.txt for BSD license.
USING: accessors arrays colors fry io.styles kernel math
math.geometry.rect math.order math.vectors namespaces opengl
sequences ui.gadgets ui.gadgets.scrollers ui.gadgets.status-bar
ui.gadgets.worlds ui.gadgets.theme ui.gestures ui.render ui.text
ui.gadgets.menus models math.ranges sequences combinators ;
IN: ui.gadgets.tables
! Row rendererer protocol
GENERIC: row-columns ( row renderer -- columns )
GENERIC: row-value ( row renderer -- object )
SINGLETON: trivial-renderer
M: trivial-renderer row-columns drop ;
M: object row-value drop ;
TUPLE: table < gadget
renderer filled-column column-alignment action hook
column-widths total-width
font text-color selection-color focus-border-color
mouse-color column-line-color selection-required?
selected-index selected-value
mouse-index
focused? ;
: <table> ( rows -- table )
table new-gadget
swap >>model
trivial-renderer >>renderer
[ drop ] >>action
[ ] >>hook
f <model> >>selected-value
sans-serif-font >>font
selection-color >>selection-color
focus-border-color >>focus-border-color
dark-gray >>column-line-color
black >>mouse-color
black >>text-color ;
<PRIVATE
: line-height ( table -- n )
font>> "" text-height ;
CONSTANT: table-gap 6
: table-rows ( table -- rows )
[ control-value ] [ renderer>> ] bi '[ _ row-columns ] map ;
: (compute-column-widths) ( font rows -- total widths )
[ drop 0 { } ] [
tuck [ first length 0 <repetition> ] 2dip
[ [ text-width ] with map vmax ] with each
[ [ sum ] [ length 1 [-] table-gap * ] bi + ] keep
] if-empty ;
: compute-column-widths ( table -- total-width column-widths )
[ font>> ] [ table-rows ] bi (compute-column-widths) ;
: update-cached-widths ( table -- )
dup compute-column-widths
[ >>total-width ] [ >>column-widths ] bi*
drop ;
: filled-column-width ( table -- n )
[ dim>> first ] [ total-width>> ] bi [-] ;
: update-filled-column ( table -- )
[ filled-column-width ]
[ filled-column>> ]
[ column-widths>> ] tri
2dup empty? not and
[ [ + ] change-nth ] [ 3drop ] if ;
M: table layout*
[ update-cached-widths ] [ update-filled-column ] bi ;
: row-rect ( table row -- rect )
[ [ line-height ] dip * 0 swap 2array ]
[ drop [ dim>> first ] [ line-height ] bi 2array ] 2bi <rect> ;
: highlight-row ( table row color quot -- )
[ [ row-rect rect-bounds ] dip gl-color ] dip
'[ _ @ ] with-translation ; inline
: draw-selected-row ( table row -- )
over selection-color>> [ gl-fill-rect ] highlight-row ;
: draw-focused-row ( table row -- )
over focused?>> [
over focus-border-color>> [ gl-rect ] highlight-row
] [ 2drop ] if ;
: draw-selected ( table -- )
dup selected-index>> dup
[ [ draw-selected-row ] [ draw-focused-row ] 2bi ]
[ 2drop ]
if ;
: draw-moused ( table -- )
dup mouse-index>> dup [
over mouse-color>> [ gl-rect ] highlight-row
] [ 2drop ] if ;
: column-offsets ( table -- xs )
0 [ table-gap + + ] accumulate nip ;
: column-line-offsets ( table -- xs )
column-offsets
[ f ] [ rest-slice [ table-gap 2/ - ] map ] if-empty ;
: draw-columns ( table -- )
[ column-line-color>> gl-color ]
[
[ column-widths>> column-line-offsets ] [ dim>> second ] bi
'[ [ 0 2array ] [ _ 2array ] bi gl-line ] each
] bi ;
: y>row ( y table -- n )
line-height /i ;
: validate-row ( m table -- n )
control-value length 1- min 0 max ;
: visible-row ( table quot -- n )
'[
[ clip get @ origin get [ second ] bi@ - ] dip
y>row
] keep validate-row ; inline
: first-visible-row ( table -- n )
[ loc>> ] visible-row ;
: last-visible-row ( table -- n )
[ rect-extent nip ] visible-row 1+ ;
: column-loc ( font column width align -- loc )
[ [ text-width ] dip swap - ] dip
* 0 2array ;
: draw-column ( font column width align -- )
over [
[ 2dup ] 2dip column-loc draw-text
] dip table-gap + 0 2array gl-translate ;
: draw-row ( columns widths align font -- )
'[ [ _ ] 3dip draw-column ] 3each ;
: each-slice-index ( from to seq quot -- )
[ [ <slice> ] [ drop [a,b) ] 3bi ] dip 2each ; inline
: column-alignment ( table -- seq )
dup column-alignment>>
[ ] [ column-widths>> length 0 <repetition> ] ?if ;
: draw-rows ( table -- )
{
[ text-color>> gl-color ]
[ first-visible-row ]
[ last-visible-row ]
[ control-value ]
[ line-height ]
[ renderer>> ]
[ column-widths>> ]
[ column-alignment ]
[ font>> ]
} cleave '[
[ 0 ] dip _ * 2array [
_ row-columns _ _ _ draw-row
] with-translation
] each-slice-index ;
M: table draw-gadget*
dup control-value empty? [ drop ] [
origin get [
{
[ draw-selected ]
[ draw-columns ]
[ draw-moused ]
[ draw-rows ]
} cleave
] with-translation
] if ;
M: table pref-dim*
[ compute-column-widths drop ] keep
[ font>> "" text-height ]
[ control-value length ]
bi * 2array ;
: nth-row ( row table -- value/f ? )
over [ control-value nth t ] [ 2drop f f ] if ;
PRIVATE>
: (selected-row) ( table -- value/f ? )
[ selected-index>> ] keep nth-row ;
: selected-row ( table -- value/f ? )
[ (selected-row) ] keep
swap [ renderer>> row-value t ] [ 2drop f f ] if ;
<PRIVATE
: update-selected-value ( table -- )
[ selected-row drop ] [ selected-value>> ] bi set-model ;
: initial-selected-index ( model table -- n/f )
[ value>> length 1 >= ] [ selection-required?>> ] bi* and 0 f ? ;
: show-row-summary ( table n -- )
over nth-row
[ swap [ renderer>> row-value ] keep show-summary ]
[ 2drop ]
if ;
M: table model-changed
tuck initial-selected-index {
[ >>selected-index drop ]
[ show-row-summary ]
[ drop update-selected-value ]
[ drop relayout ]
} 2cleave ;
: thin-row-rect ( table row -- rect )
row-rect [ { 0 1 } v* ] change-dim ;
: (select-row) ( table n -- )
[ [ thin-row-rect ] [ drop ] 2bi scroll>rect ]
[ >>selected-index relayout-1 ]
2bi ;
: mouse-row ( table -- n )
[ hand-rel second ] keep y>row ;
: table-button-down ( table -- )
dup request-focus
dup control-value empty? [ drop ] [
dup [ mouse-row ] keep validate-row
[ >>mouse-index ] [ (select-row) ] bi
] if ;
PRIVATE>
: row-action ( table -- )
dup selected-row [ swap action>> call ] [ 2drop ] if ;
<PRIVATE
: table-button-up ( table -- )
hand-click# get 2 =
[ row-action ] [ update-selected-value ] if ;
: select-row ( table n -- )
over validate-row
[ (select-row) ]
[ drop update-selected-value ]
[ show-row-summary ]
2tri ;
: prev-row ( table -- )
dup selected-index>> [ 1- ] [ 0 ] if* select-row ;
: next-row ( table -- )
dup selected-index>> [ 1+ ] [ 0 ] if* select-row ;
: first-row ( table -- )
0 select-row ;
: last-row ( table -- )
dup control-value length 1- select-row ;
: hide-mouse-help ( table -- )
f >>mouse-index [ hide-status ] [ relayout-1 ] bi ;
: valid-row? ( row table -- ? )
control-value length 1- 0 swap between? ;
: if-mouse-row ( table true false -- )
[ [ mouse-row ] keep 2dup valid-row? ]
[ ] [ '[ nip @ ] ] tri* if ; inline
: show-mouse-help ( table -- )
[
swap
[ >>mouse-index relayout-1 ]
[ show-row-summary ]
2bi
] [ hide-mouse-help ] if-mouse-row ;
: show-table-menu ( table -- )
[
tuck [ nth-row drop ] [ renderer>> row-value ] [ hook>> ] tri
show-operations-menu
] [ drop ] if-mouse-row ;
table H{
{ T{ mouse-enter } [ show-mouse-help ] }
{ T{ mouse-leave } [ hide-mouse-help ] }
{ T{ motion } [ show-mouse-help ] }
{ T{ button-down } [ table-button-down ] }
{ T{ button-down f f 3 } [ show-table-menu ] }
{ T{ button-up } [ table-button-up ] }
{ T{ gain-focus } [ t >>focused? drop ] }
{ T{ lose-focus } [ f >>focused? drop ] }
{ T{ drag } [ table-button-down ] }
{ T{ key-down f f "RET" } [ row-action ] }
{ T{ key-down f f "UP" } [ prev-row ] }
{ T{ key-down f f "DOWN" } [ next-row ] }
{ T{ key-down f f "HOME" } [ first-row ] }
{ T{ key-down f f "END" } [ last-row ] }
} set-gestures
PRIVATE>