-
Notifications
You must be signed in to change notification settings - Fork 9
/
user_code_capabilities_report.ex
116 lines (100 loc) · 4.53 KB
/
user_code_capabilities_report.ex
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
defmodule Grizzly.ZWave.Commands.UserCodeCapabilitiesReport do
@moduledoc """
This command is used to advertise User Code capabilities.
## Params
* `:admin_code_supported?` - Whether the lock supports admin code functionality.
* `:admin_code_deactivation_supported?` - Whether the lock supports deactivating an admin code.
* `:user_code_checksum_supported?` - Whether the lock supports user code checksum functionality.
* `:multi_user_code_report_supported?` - Whether the lock supports reporting multiple user codes
via the Extended User Code Report command.
* `:multi_user_code_set_supported?` - Whether the lock supports setting multiple user codes via
the Extended User Code Set command.
* `:supported_user_id_statuses` - A list of supported user ID statuses.
* `:supported_keypad_modes` - A list of supported keypad modes.
* `:supported_keypad_keys` - A list of supported keypad keys.
"""
@behaviour Grizzly.ZWave.Command
import Grizzly.ZWave.Encoding
alias Grizzly.ZWave.{Command, DecodeError}
alias Grizzly.ZWave.CommandClasses.UserCode
@type ascii_char :: 0..127
@type param ::
{:admin_code_supported?, boolean()}
| {:admin_code_deactivation_supported?, boolean()}
| {:user_code_checksum_supported?, boolean()}
| {:multi_user_code_report_supported?, boolean()}
| {:multi_user_code_set_supported?, boolean()}
| {:supported_user_id_statuses, [UserCode.user_id_status()]}
| {:supported_keypad_modes, [UserCode.keypad_mode()]}
| {:supported_keypad_keys, [ascii_char()]}
@impl Grizzly.ZWave.Command
@spec new([param()]) :: {:ok, Command.t()}
def new(params) do
command = %Command{
name: :user_code_capabilities_report,
command_byte: 0x07,
command_class: UserCode,
params: params,
impl: __MODULE__
}
{:ok, command}
end
@impl Grizzly.ZWave.Command
@spec encode_params(Command.t()) :: binary()
def encode_params(command) do
mc = Command.param(command, :admin_code_supported?, false) |> bool_to_bit()
mcd = Command.param(command, :admin_code_deactivation_supported?, false) |> bool_to_bit()
ucc = Command.param(command, :user_code_checksum_supported?, false) |> bool_to_bit()
mucr = Command.param(command, :multi_user_code_report_supported?, false) |> bool_to_bit()
mucs = Command.param(command, :multi_user_code_set_supported?, false) |> bool_to_bit()
supported_user_id_statuses =
Command.param(command, :supported_user_id_statuses, [])
|> Enum.map(&UserCode.user_id_status_to_byte/1)
|> encode_bitmask()
supported_keypad_modes =
Command.param(command, :supported_keypad_modes, [])
|> Enum.map(&UserCode.keypad_mode_to_byte/1)
|> encode_bitmask()
supported_keypad_keys =
Command.param(command, :supported_keypad_keys, [])
|> encode_bitmask()
<<mc::1, mcd::1, 0::1, byte_size(supported_user_id_statuses)::5>> <>
supported_user_id_statuses <>
<<ucc::1, mucr::1, mucs::1, byte_size(supported_keypad_modes)::5>> <>
supported_keypad_modes <>
<<0::3, byte_size(supported_keypad_keys)::5>> <>
supported_keypad_keys
end
@impl Grizzly.ZWave.Command
@spec decode_params(binary()) :: {:ok, [param()]} | {:error, DecodeError.t()}
def decode_params(
<<mc_support::1, mcd_support::1, _reserved::1, user_id_status_len::5,
supported_user_id_statuses::binary-size(user_id_status_len), ucc_support::1,
mucr_support::1, mucs_support::1, keypad_modes_len::5,
supported_keypad_modes::binary-size(keypad_modes_len), _reserved2::3,
supported_keypad_keys_len::5,
supported_keypad_keys_bitmask::binary-size(supported_keypad_keys_len)>>
) do
user_id_statuses =
supported_user_id_statuses
|> decode_bitmask()
|> Enum.map(&UserCode.user_id_status_from_byte/1)
|> Enum.reject(&(&1 == :unknown))
keypad_modes =
supported_keypad_modes
|> decode_bitmask()
|> Enum.map(&UserCode.keypad_mode_from_byte/1)
|> Enum.reject(&(&1 == :unknown))
{:ok,
[
admin_code_supported?: mc_support == 1,
admin_code_deactivation_supported?: mcd_support == 1,
user_code_checksum_supported?: ucc_support == 1,
multi_user_code_report_supported?: mucr_support == 1,
multi_user_code_set_supported?: mucs_support == 1,
supported_user_id_statuses: user_id_statuses,
supported_keypad_modes: keypad_modes,
supported_keypad_keys: decode_bitmask(supported_keypad_keys_bitmask)
]}
end
end