PKGBUILD

# Maintainer: Evangelos Foutras <foutrelis@gmail.com>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgname=php52-suhosin-apache
pkgver=5.2.16
pkgrel=1
_suhosinver=${pkgver}-0.9.7
pkgdesc='A high-level scripting language'
arch=('i686' 'x86_64')
license=('PHP')
url='http://www.php.net'
backup=('etc/php/php.ini')
depends=('glibc' 'readline' 'ncurses' 'libxml2' 'pcre' 'apache' 'apr-util')
makedepends=('postgresql-libs' 'mysql' 'libldap'
#'smtp-server'
             'libpng' 'libjpeg' 'sqlite3' 'unixodbc' 'gmp'
             'tidyhtml' 'aspell' 'libtool' 'freetype2' 'libjpeg'
             'curl' 'libxslt' 'pam' 'openssl' 'bzip2' 'gdbm' 'db')
optdepends=('bzip2: bz2'
            'curl: curl'
            'gdbm: dba'
            'libpng: gd'
            'libjpeg: gd'
            'freetype2: gd'
            'pam: imap'
            'libldap: ldap'
            'libmcrypt: mcrypt'
            'libtool: mcrypt'
            'libmysqlclient: mysql/mysqli/pdo_mysql'
            'unixodbc: odbc/pdo_odbc'
            'openssl: openssl'
            'postgresql-libs: pgsql/pdo_pgsql'
            'aspell: pspell'
            'net-snmp: snmp'
            'sqlite3: pdo_sqlite'
            'tidyhtml: tidy'
            'libxslt: xsl'
            'mhash: mhash'
            'gmp: gmp'
            )
provides=("php=$pkgver")
conflicts=('php')
source=("http://www.php.net/distributions/php-${pkgver}.tar.bz2"
        "http://download.suhosin.org/suhosin-patch-${_suhosinver}.patch.gz"
        'gmp-fix.patch'
        'apache.conf'
        'php.ini')
#        'db-configure.patch')
md5sums=('3b0bd012bd53bac9a5fefca61eccd5c6'
         'd815fc99a0c25c21f5df28551fcbb001'
         'a8016acf83c0812f817ef5d1e1b796aa'
         'dec2cbaad64e3abf4f0ec70e1de4e8e9'
         '50b6a4ce330b016e19cb922d202ab170')
#         '74e5ce5a02488ec91b1c59f539e42936')

build() {
  phpconfig="--prefix=/usr \
  --sysconfdir=/etc/php \
  --with-layout=GNU \
  --with-config-file-path=/etc/php \
  --with-config-file-scan-dir=/etc/php/conf.d \
  --enable-inline-optimization \
  --disable-debug \
  --disable-rpath \
  --disable-static \
  --enable-shared \
  --mandir=/usr/share/man \
  "

  phpextensions="--with-openssl=shared \
  --with-zlib=shared \
  --enable-bcmath=shared \
  --with-bz2=shared \
  --enable-calendar=shared \
  --with-curl=shared \
  --enable-dba=shared \
  --without-db2 \
  --without-db3 \
  --without-db4 \
  --with-gdbm=shared \
  --enable-dbase=shared \
  --enable-exif=shared \
  --enable-ftp=shared \
  --with-gd=shared \
  --enable-gd-native-ttf \
  --with-jpeg-dir=shared,/usr \
  --with-png-dir=shared,/usr \
  --with-gettext=shared \
  --without-imap \
  --without-imap-ssl \
  --with-ldap=shared \
  --enable-mbstring=shared \
  --without-mcrypt \
  --with-mysql=shared \
  --with-mysql-sock=/tmp/mysql.sock \
  --with-mysql=shared \
  --with-mysqli=shared \
  --with-ncurses=shared \
  --with-unixODBC=shared,/usr \
  --enable-pdo=shared \
  --with-pdo-mysql=shared \
  --with-pdo-sqlite=shared,/usr \
  --with-pdo-odbc=shared,unixODBC,/usr \
  --with-pdo-pgsql=shared \
  --with-sqlite=shared \
  --enable-sqlite-utf8 \
  --with-pgsql=shared \
  --enable-shmop=shared \
  --without-snmp \
  --enable-soap=shared \
  --enable-sysvmsg=shared \
  --enable-sysvsem=shared \
  --enable-sysvshm=shared \
  --with-tidy=shared \
  --with-xsl=shared \
  --enable-zip=shared \
  --enable-posix=shared \
  --enable-sockets=shared \
  --enable-xml \
  --with-ttf=shared \
  --enable-session=shared \
  --with-regex=php \
  --with-pcre-regex=/usr \
  --enable-mbstring=all \
  --enable-mbregex \
  --enable-json=shared \
  --with-iconv=shared \
  --with-xmlrpc=shared \
  --with-pspell=shared \
  --with-freetype-dir=shared,/usr \
  --with-mime-magic=shared \
  --with-gmp=shared \
  --without-mhash \
  "

  PEAR_INSTALLDIR=/usr/share/pear
  export PEAR_INSTALLDIR

  cd ${srcdir}/php-${pkgver}

  # apply GMP fix patch
  patch -p1 -i ${srcdir}/gmp-fix.patch

  # apply suhosin patch
  patch -p1 -i ${srcdir}/suhosin-patch-${_suhosinver}.patch

  # cli
  ./configure ${phpconfig} \
    --disable-cgi \
    --with-readline \
    --enable-pcntl \
    --with-pear=/usr/share/pear \
    ${phpextensions}
  make
  # make test
  make INSTALL_ROOT=${pkgdir} install

  # cleanup
  rm -f ${pkgdir}`${pkgdir}/usr/bin/php-config --extension-dir`/*.a
  # install php.ini
  install -D -m644 ${srcdir}/php.ini ${pkgdir}/etc/php/php.ini
  install -d -m755 ${pkgdir}/etc/php/conf.d/

#  # cgi and fcgi
#  ./configure ${phpconfig} \
#    --enable-fastcgi \
#    --enable-cgi \
#    --enable-discard-path \
#    --enable-force-cgi-redirect \
#    --disable-cli \
#    ${phpextensions}
#  make
#  install -D -m755 sapi/cgi/php-cgi ${pkgdir}/usr/bin/php-cgi

  # mod_php
  ./configure ${phpconfig} \
    --with-apxs2 \
    --disable-cli \
    ${phpextensions}
  make
  install -D -m644 libs/libphp5.so ${pkgdir}/usr/lib/httpd/modules/libphp5.so
  install -D -m644 ${srcdir}/apache.conf ${pkgdir}/etc/httpd/conf/extra/php5_module.conf
}