forked from nathanmarz/serializable-fn
-
Notifications
You must be signed in to change notification settings - Fork 6
/
fn.clj
217 lines (185 loc) · 7.56 KB
/
fn.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
(ns serializable.fn
"Serializable functions! Check it out."
(:require [clojure.tools.logging :as log])
(:import [serializable.fn Utils]
[java.io Writer])
(:refer-clojure :exclude [fn]))
(def ^:dynamic *serialize* #(Utils/serialize %))
(def ^:dynamic *deserialize* #(Utils/deserialize %))
(defn- mangle-name [name]
(clojure.lang.Compiler/munge name))
(defn- generate-function-name [line column form]
(let [first-param (first (rest form))
custom-fn-name? (not (vector? first-param))]
(if custom-fn-name?
nil
(symbol (mangle-name (str *ns* "_sfn_" line \_ column))))))
(defn- symbols [sexp]
"Returns just the symbols from the expression, including those
inside literals (sets, maps, lists, vectors)."
(set (filter symbol? (tree-seq coll? seq sexp))))
(defn- save-env [bindings form fn-name]
(let [namespace (str *ns*)
;; replace core/fn , with serializable/fn
;; give anonymous fn a name, so it will show up in stacktraces
form (with-meta
(cons `fn (if fn-name
(cons fn-name (rest form))
(rest form)))
(meta form))
used-symbols (symbols (rest form))
used-bindings (filter (clojure.core/fn [^clojure.lang.Compiler$LocalBinding b]
(used-symbols (.sym b))) bindings)
savers (for [^clojure.lang.Compiler$LocalBinding b used-bindings]
[(str (.sym b)) (.sym b)])
env-form `(into {} ~(vec savers))]
;; without the print-dup, it sometimes serializes invalid code strings (with subforms replaced with "#")
[env-form namespace (binding [*print-dup* true] (pr-str form))]))
(defmacro ^{:doc (str (:doc (meta #'clojure.core/fn))
"\n\n Oh, but it also allows serialization!!!111eleven")}
fn [& sigs]
(let [form-meta (meta &form)
line (get form-meta :line)
column (get form-meta :column)
fn-name (generate-function-name line column &form)
[env-form namespace source] (save-env (vals &env) &form fn-name)]
`(with-meta (clojure.core/fn ~@(if fn-name
(cons fn-name sigs)
sigs))
{:type ::serializable-fn
::line ~line
::column ~column
::env ~env-form
::namespace ~namespace
::source ~source})))
(defn- try-parse-num [^String s]
(try
(Long/parseLong s)
(catch NumberFormatException _
nil )))
(defn- recent-eval? [v]
(let [m (meta v)
^String name (-> m :name str)]
(and (= "clojure.core" (:ns m))
(.startsWith name "*")
(try-parse-num (.substring name 1)))))
(defn search-for-var [val]
;; get all of them, filter out *1, *2, and *3, sort by static -> dynamic
(->> (all-ns)
(map ns-map)
(mapcat identity)
(map second)
(filter #(and (var? %) (= (var-get %) val)))
(filter (complement recent-eval?))
(sort-by (fn [v] (if (-> v meta :dynamic) 1 0)))
first))
(def ^{:const true} SERIALIZED-TYPES
{:find-var 1
:serfn 2
:kryo 3
:var 4
:multifn 5})
(defn type->token [type]
(SERIALIZED-TYPES type))
(let [reversed (into {} (for [[k v] SERIALIZED-TYPES] [v k]))]
(defn token->type [token]
(reversed token)))
(defn serialize-type [val]
(cond (var? val) :var
(instance? clojure.lang.MultiFn val) :multifn
(fn? val) (if (= ::serializable-fn (-> val meta :type))
:serfn
:find-var)
:else :kryo))
(defmulti serialize-val serialize-type)
(defn serialize [val]
(let [type (serialize-type val)
serialized (serialize-val val)]
(log/trace "serializing:" val "of type:" type)
(*serialize* {:token (type->token type) :val-ser serialized})))
(defmethod serialize-val :kryo [val]
(log/trace "serializing kryo:" val)
(*serialize* val))
(defn ns-fn-name-pair [v]
(let [m (meta v)]
[(str (:ns m)) (str (:name m))]))
(defn serialize-find [val]
(let [avar (search-for-var val)]
(when-not avar
(throw (RuntimeException. "Cannot serialize regular functions that are not bound to vars")))
(serialize-val avar)))
(defmethod serialize-val :find-var [val]
(serialize-find val))
(defmethod serialize-val :multifn [val]
(serialize-find val))
(defmethod serialize-val :var [avar]
(let [[ns fn-name] (ns-fn-name-pair avar)]
(log/trace "serializing var:" ns "/" fn-name)
(*serialize* {:ns ns :fn-name fn-name})))
(defn best-effort-map-val [amap afn]
(into {}
(mapcat
(fn [[name val]]
(try
[[name (afn val)]]
(catch Exception e
(log/debug (format "caught exception: %s" e))
(log/debug (format "unable to call %s on %s in %s" afn val amap))
[]
)))
amap)))
(defmethod serialize-val :serfn [val]
(log/trace "serializing serfn:" val)
(let [[env namespace source] ((juxt ::env ::namespace ::source) (meta val))
_ (log/trace "serfn env" env)
_ (log/trace "serfn meta" (-> (meta val)
(dissoc ::env ::namespace ::source)))
ser-meta (-> (meta val)
(dissoc ::env ::namespace ::source)
(best-effort-map-val serialize)
*serialize*)
ser-env (-> env (best-effort-map-val serialize) *serialize*)]
(*serialize* {:ser-meta ser-meta :ser-env ser-env :ns namespace :source source})))
(defmulti deserialize-val (fn [token serialized]
(token->type token)))
(defn deserialize [serialized]
(let [{:keys [token val-ser]} (*deserialize* serialized)]
(deserialize-val token val-ser)))
(defmethod deserialize-val :find-var [_ serialized]
(let [{:keys [ns fn-name]} (*deserialize* serialized)]
(log/trace "deserializing find-var:" ns "/" fn-name)
(Utils/bootSimpleFn ns fn-name)))
(defmethod deserialize-val :multifn [_ serialized]
(let [{:keys [ns fn-name]} (*deserialize* serialized)]
(log/trace "deserializing multifn:" ns "/" fn-name)
(Utils/bootSimpleMultifn ns fn-name)))
(defmethod deserialize-val :var [_ serialized]
(let [{:keys [ns fn-name]} (*deserialize* serialized)]
(log/trace "deserializing var:" ns "/" fn-name)
(Utils/bootSimpleVar ns fn-name)))
(defmethod deserialize-val :kryo [_ serialized]
(log/trace "deserializing kryo")
(*deserialize* serialized))
(def ^:dynamic *global-env* {})
(defmethod deserialize-val :serfn [_ serialized]
(let [{:keys [ser-meta ser-env ns source]} (*deserialize* serialized)
_ (log/trace "deserializing serfn:" source)
rest-meta (best-effort-map-val (*deserialize* ser-meta) deserialize)
_ (log/trace "meta:" rest-meta)
env (best-effort-map-val (*deserialize* ser-env) deserialize)
_ (log/trace "env:" env)
source-form (try (read-string source) (catch Exception e
(throw (RuntimeException. (str "Could not deserialize " source)))))
namespace (symbol ns)
old-ns (-> *ns* str symbol)
bindings (mapcat (fn [[name val]] [(symbol name) `(*global-env* ~name)]) env)
to-eval `(let ~(vec bindings) ~source-form)
_ (log/trace "to-eval:" to-eval)]
(Utils/tryRequire (str namespace))
(vary-meta (binding [*ns* (create-ns namespace) *global-env* env]
(eval to-eval))
merge
rest-meta)))
(defmethod print-method ::serializable-fn [o ^Writer w]
(let [m (meta o)]
(print-method (str (::namespace m) ":" (::line m) ":" (::column m) " " (::source m)) w)))