/
executor.ex
333 lines (259 loc) 路 8.3 KB
/
executor.ex
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
defmodule Oban.Queue.Executor do
@moduledoc false
alias Oban.{Backoff, Config, CrashError, Engine, Job}
alias Oban.{PerformError, TimeoutError, Worker}
require Logger
@type state :: :cancelled | :discard | :exhausted | :failure | :success | :snoozed
@type t :: %__MODULE__{
conf: Config.t(),
duration: pos_integer(),
job: Job.t(),
kind: any(),
meta: map(),
queue_time: integer(),
result: term(),
start_mono: integer(),
start_time: integer(),
stop_mono: integer(),
safe: boolean(),
snooze: non_neg_integer(),
stacktrace: Exception.stacktrace(),
state: :unset | state(),
timer: reference(),
worker: Worker.t()
}
@type option :: {:ack, boolean()} | {:safe, boolean()}
@enforce_keys [:conf, :job]
defstruct [
:ack,
:conf,
:error,
:job,
:meta,
:result,
:snooze,
:start_mono,
:start_time,
:stop_mono,
:timer,
:worker,
safe: true,
duration: 0,
kind: :error,
queue_time: 0,
stacktrace: [],
state: :unset
]
@spec new(Config.t(), Job.t(), [option()]) :: t()
def new(%Config{} = conf, %Job{} = job, opts \\ []) do
struct!(__MODULE__,
ack: Keyword.get(opts, :ack, true),
conf: conf,
job: %{job | conf: conf},
meta: event_metadata(conf, job),
safe: Keyword.get(opts, :safe, true),
start_mono: System.monotonic_time(),
start_time: System.system_time()
)
end
@spec call(t()) :: t()
def call(%__MODULE__{} = exec) do
exec =
exec
|> record_started()
|> resolve_worker()
|> start_timeout()
|> perform()
|> normalize_state()
|> record_finished()
|> cancel_timeout()
complete = fn ->
exec
|> report_finished()
|> reraise_unsafe()
end
if exec.safe do
Backoff.with_retry(complete)
else
complete.()
end
end
@spec record_started(t()) :: t()
def record_started(%__MODULE__{} = exec) do
:telemetry.execute([:oban, :job, :start], %{system_time: exec.start_time}, exec.meta)
exec
end
@spec resolve_worker(t()) :: t()
def resolve_worker(%__MODULE__{} = exec) do
case Worker.from_string(exec.job.worker) do
{:ok, worker} ->
%{exec | worker: worker}
{:error, error} ->
unless exec.safe, do: raise(error)
%{exec | result: {:error, error}, state: :failure, error: error}
end
end
@spec start_timeout(t()) :: t()
def start_timeout(%__MODULE__{state: :unset} = exec) do
case exec.worker.timeout(exec.job) do
timeout when is_integer(timeout) ->
{:ok, timer} = :timer.exit_after(timeout, TimeoutError.exception({exec.worker, timeout}))
%{exec | timer: timer}
:infinity ->
exec
end
end
def start_timeout(exec), do: exec
@spec perform(t()) :: t()
def perform(%__MODULE__{job: job, state: :unset, worker: worker} = exec) do
case worker.perform(job) do
:ok ->
%{exec | state: :success, result: :ok}
{:ok, _value} = result ->
%{exec | state: :success, result: result}
{:cancel, _reason} = result ->
%{exec | result: result, state: :cancelled, error: perform_error(worker, result)}
:discard = result ->
%{exec | result: result, state: :discard, error: perform_error(worker, result)}
{:discard, _reason} = result ->
%{exec | result: result, state: :discard, error: perform_error(worker, result)}
{:error, _reason} = result ->
%{exec | result: result, state: :failure, error: perform_error(worker, result)}
{:snooze, seconds} = result when is_integer(seconds) and seconds >= 0 ->
%{exec | result: result, state: :snoozed, snooze: seconds}
returned ->
log_warning(exec, returned)
%{exec | state: :success, result: returned}
end
rescue
error ->
%{exec | state: :failure, error: error, stacktrace: __STACKTRACE__}
catch
kind, reason ->
error = CrashError.exception({kind, reason, __STACKTRACE__})
%{exec | state: :failure, error: error, stacktrace: __STACKTRACE__}
end
def perform(exec), do: exec
@spec normalize_state(t()) :: t()
def normalize_state(%__MODULE__{state: :failure, job: job} = exec)
when job.attempt >= job.max_attempts do
%{exec | state: :exhausted}
end
def normalize_state(exec), do: exec
@spec record_finished(t()) :: t()
def record_finished(%__MODULE__{} = exec) do
stop_mono = System.monotonic_time()
duration = stop_mono - exec.start_mono
queue_time =
exec.job.attempted_at
|> DateTime.diff(exec.job.scheduled_at, :nanosecond)
|> max(0)
%{exec | duration: duration, queue_time: queue_time, stop_mono: stop_mono}
end
@spec cancel_timeout(t()) :: t()
def cancel_timeout(%__MODULE__{timer: timer} = exec) do
unless is_nil(timer), do: :timer.cancel(timer)
exec
end
@spec reraise_unsafe(t()) :: t()
def reraise_unsafe(%__MODULE__{safe: false, stacktrace: [_ | _]} = exec) do
reraise exec.error, exec.stacktrace
end
def reraise_unsafe(exec), do: exec
@spec report_finished(t()) :: t()
def report_finished(%__MODULE__{} = exec) do
exec
|> record_unsaved()
|> ack_event()
|> emit_event()
end
@spec ack_event(t()) :: t()
def ack_event(%__MODULE__{ack: true, state: :success} = exec) do
Engine.complete_job(exec.conf, exec.job)
exec
end
def ack_event(%__MODULE__{ack: true, job: job, state: :failure, worker: worker} = exec) do
backoff = if worker, do: worker.backoff(job), else: Worker.backoff(job)
Engine.error_job(exec.conf, job, backoff)
exec
end
def ack_event(%__MODULE__{ack: true, state: :snoozed} = exec) do
Engine.snooze_job(exec.conf, exec.job, exec.snooze)
exec
end
def ack_event(%__MODULE__{ack: true, state: :cancelled} = exec) do
Engine.cancel_job(exec.conf, exec.job)
exec
end
def ack_event(%__MODULE__{ack: true, state: state} = exec)
when state in [:discard, :exhausted] do
Engine.discard_job(exec.conf, exec.job)
exec
end
def ack_event(exec), do: exec
@spec emit_event(t()) :: t()
def emit_event(%__MODULE__{state: state} = exec) when state in [:failure, :exhausted] do
measurements = %{duration: exec.duration, queue_time: exec.queue_time}
kind =
case exec.kind do
{:EXIT, _pid} -> :exit
kind when kind in [:exit, :throw, :error] -> kind
end
state = if state == :exhausted, do: :discard, else: state
meta =
Map.merge(exec.meta, %{
job: exec.job,
kind: kind,
error: exec.error,
reason: exec.error,
result: exec.result,
stacktrace: exec.stacktrace,
state: state
})
:telemetry.execute([:oban, :job, :exception], measurements, meta)
exec
end
def emit_event(%__MODULE__{state: state} = exec)
when state in [:cancelled, :success, :snoozed, :discard] do
measurements = %{duration: exec.duration, queue_time: exec.queue_time}
meta =
Map.merge(exec.meta, %{
job: exec.job,
state: exec.state,
result: exec.result
})
:telemetry.execute([:oban, :job, :stop], measurements, meta)
exec
end
@spec record_unsaved(t()) :: t()
def record_unsaved(%__MODULE__{error: error} = exec) when not is_nil(error) do
unsaved_error = %{kind: exec.kind, reason: exec.error, stacktrace: exec.stacktrace}
put_in(exec.job.unsaved_error, unsaved_error)
end
def record_unsaved(exec), do: exec
# Helpers
defp perform_error(worker, result), do: PerformError.exception({worker, result})
defp event_metadata(conf, job) do
job
|> Map.take([:id, :args, :queue, :worker, :attempt, :max_attempts, :tags])
|> Map.merge(%{conf: conf, job: job, prefix: conf.prefix})
end
defp log_warning(%__MODULE__{safe: true, worker: worker}, returned) do
Logger.warning(fn ->
"""
Expected #{worker}.perform/1 to return:
- `:ok`
- `:discard`
- `{:ok, value}`
- `{:error, reason}`,
- `{:cancel, reason}`
- `{:discard, reason}`
- `{:snooze, seconds}`
Instead received:
#{inspect(returned, pretty: true)}
The job will be considered a success.
"""
end)
end
defp log_warning(_exec, _returned), do: :noop
end