-
Notifications
You must be signed in to change notification settings - Fork 6
/
plantuml.clj
307 lines (266 loc) · 9.62 KB
/
plantuml.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
;;;;
;;;; PlantUML rendering and export
;;;;
(ns org.soulspace.overarch.adapter.render.plantuml
"Functions to export views to PlantUML."
(:require [clojure.set :as set]
[clojure.string :as str]
[clojure.java.io :as io]
[org.soulspace.clj.string :as sstr]
[org.soulspace.clj.java.file :as file]
[org.soulspace.overarch.domain.element :as el]
[org.soulspace.overarch.domain.view :as view]
[org.soulspace.overarch.application.render :as rndr]
[org.soulspace.overarch.util.io :as oio]
[org.soulspace.overarch.domain.model :as model]))
;;;
;;; PlantUML mappings
;;;
; FIXME remote urls
(def sprite-libraries
"Definition of sprite libraries."
{:azure {:name "azure"
:local-prefix "azure"
:local-imports ["AzureCommon"
"AzureC4Integration"]
:remote-prefix "AZURE"
:remote-url ""
:remote-imports ["AzureCommon"
"AzureC4Integration"]}
:awslib {:name "awslib"
:local-prefix "awslib14"
:local-imports ["AWSCommon"
"AWSC4Integration"]
:remote-prefix "AWS"
:remote-url ""
:remote-imports ["AWSCommon"
"AWSC4Integration"]}
:cloudinsight {:name "cloudinsight"
:local-prefix "cloudinsight"
:local-imports []
:remote-prefix "CLOUDINSIGHT"
:remote-url ""}
:cloudogu {:name "cloudogu"
:local-prefix "cloudogu"
:local-imports ["common"]
:remote-prefix "CLOUDOGU"
:remote-url ""}
:logos {:name "logos"
:local-prefix "logos"}
:devicons {:name "devicons"
:local-prefix "tupadr3"
:local-imports ["common"]
:remote-prefix "DEVICONS"
:remote-url "https://raw.githubusercontent.com/tupadr3/plantuml-icon-font-sprites/master/devicons"}
:devicons2 {:name "devicons2"
:local-prefix "tupadr3"
:local-imports ["common"]
:remote-prefix "DEVICONS2"
:remote-url "https://raw.githubusercontent.com/tupadr3/plantuml-icon-font-sprites/master/devicons2"}
:font-awesome-5 {:name "font-awesome-5"
:local-prefix "tupadr3"
:local-imports ["common"]
:remote-prefix "FONTAWESOME"
:remote-url "https://raw.githubusercontent.com/tupadr3/plantuml-icon-font-sprites/master/font-awesome-5"}
:material {:name "material"
:local-prefix "material"
:local-imports ["common"]}})
(def view-hierarchy
"Hierarchy for views"
(-> (make-hierarchy)
(derive :system-landscape-view :c4-view)
(derive :context-view :c4-view)
(derive :container-view :c4-view)
(derive :component-view :c4-view)
(derive :deployment-view :c4-view)
(derive :dynamic-view :c4-view)
(derive :use-case-view :uml-view)
(derive :state-machine-view :uml-view)
(derive :class-view :uml-view)))
(def linetypes
"Maps linetype keys to PlantUML C4."
{:orthogonal "skinparam linetype ortho"
:polygonal "skinparam linetype polyline"})
;;;
;;; Tech to Sprite mapping
;;;
(def sprite-resources
["cloudogu" "cloudinsight" "logos" "devicons" "devicons2"
"font-awesome-5" "azure" "awslib14"])
(defn load-sprite-mappings-from-dir
"Loads the mappings from the directory `dir` and returns the merged map."
[dir]
(->> (file/all-files-by-extension ".edn" dir)
(map oio/load-edn)
(reduce merge)))
(defn load-sprite-mappings-from-resource
"Loads the list of `resources` and returns the merged map."
[resources]
(->> resources
(map #(str "plantuml/" % ".edn"))
(map oio/load-edn-from-resource)
(reduce merge)))
; use (io/resource ) or load sprite mapping from options config dir
(defn load-sprite-mappings
"Loads the mappings from tech to sprite."
[options]
(if (:config-dir options)
(load-sprite-mappings-from-dir (str (:config-dir options) "/plantuml"))
(oio/load-edn-from-resource sprite-resources)))
(def tech->sprite (load-sprite-mappings-from-resource sprite-resources))
(defn sprite-path
"Returns a path for the given `sprite`."
[sprite]
(str (:prefix sprite) "/"
(if (empty? (:path sprite))
""
(str (:path sprite) "/"))
(:name sprite)))
(defn sorted-sprite-mappings
"Returns a list of sprite mappings sorted by the key."
[m]
(->> m
(keys)
(sort)
(map (fn [key] (merge {:key key} (m key))))))
(defn sprite?
"Returns true if the icon-map contains an icon for the given technology."
[tech]
(tech->sprite tech))
(comment
(load-sprite-mappings-from-resource ["azure" "awslib14"])
(count (sorted-sprite-mappings tech->sprite)))
;;;
;;; Rendering
;;;
(defn renderer
"Returns the renderer for the view."
[_ _ view]
(:el view))
(defmulti render-plantuml-view
"Renders the diagram with PlantUML."
renderer
:hierarchy #'view-hierarchy)
;;
;; Elements
;;
(defn alias-name
"Returns a valid PlantUML alias for the namespaced keyword `kw`."
[kw]
(symbol (str (str/replace (sstr/hyphen-to-camel-case (namespace kw)) \. \_) "_"
(sstr/hyphen-to-camel-case (name kw)))))
(defn short-name
"Returns a valid PlantUML alias for the name part of the keyword `kw`."
[kw]
(sstr/hyphen-to-camel-case (name kw)))
(defmulti render-c4-element
"Renders a C4 element in PlantUML.
Multifunction dispatching on the value of the :el key of the element `e`."
(fn [_ _ _ e] (:el e))
:hierarchy #'el/element-hierarchy)
(defmulti render-uml-element
"Renders a UML element in PlantUML.
Multifunction dispatching on the value of the :el key of the element `e`."
(fn [_ _ _ e] (:el e))
:hierarchy #'el/element-hierarchy)
;;;
;;; Imports
;;;
;;
;; Sprite Imports
;;
(defn sprite-collector
"Adds the sprite of `e` to the accumulator `acc`."
([] #{})
([acc] acc)
([acc e]
(set/union acc #{(:sprite e)})))
(defn collect-sprites
"Returns the set of sprites for the elements of the `coll`."
[coll]
(el/traverse :sprite sprite-collector coll))
(defn collect-all-sprites
"Collects all sprites for the collection of elements."
[coll]
(filter sprite? (set/union (el/collect-technologies coll) (collect-sprites coll))))
(defn sprites-for-view
"Collects the sprites for the `view`."
[model view]
(->> view
(view/elements-to-render model)
(collect-all-sprites)
(map #(tech->sprite %))))
(defn local-import
"Renders a local import."
([path]
(str "!include <" path ">"))
([prefix path]
(str "!include <" prefix "/" path ">")))
(defn remote-import
"Renders a remote import."
([url]
(str "!includeurl " url))
([prefix path]
(str "!includeurl " (str/upper-case prefix) "/" path)))
(defn render-sprite-import
"Renders the import for an sprite."
[view sprite]
(if (get-in view [:spec :plantuml :remote-imports])
(remote-import (sprite-path sprite))
(local-import (sprite-path sprite))))
(defn render-spritelib-import
"Renders the imports for an sprite library."
[view sprite-lib]
(if (get-in view [:spec :plantuml :remote-imports])
[(str "!define " (:remote-prefix sprite-lib) (:remote-url sprite-lib))
(map (partial remote-import (:remote-prefix sprite-lib))
(:remote-imports (sprite-libraries sprite-lib)))]
[(map (partial local-import (:local-prefix (sprite-libraries sprite-lib)))
(:local-imports (sprite-libraries sprite-lib)))]))
(defn render-sprite-imports
"Renders the imports for icon/sprite libraries."
[model view]
(let [icon-libs (get-in view [:spec :plantuml :sprite-libs])
icons (sprites-for-view model view)]
[(map (partial render-spritelib-import view) icon-libs)
(map (partial render-sprite-import view) icons)]))
(comment
(tech->sprite "Angular"))
;;;
;;; Diagram Layout
;;;
(defn render-title
"Renders the title of the diagram."
[view]
(when (:title view) (str "title " (:title view))))
;;;
;;; PlantUML Rendering dispatch
;;;
(def plantuml-views
"Contains the views to be rendered with plantuml."
#{:system-landscape-view :context-view :container-view :component-view
:deployment-view :dynamic-view :class-view :use-case-view
:state-machine-view})
(defn plantuml-view?
"Returns true, if the view is to be rendered with plantuml."
[view]
(contains? plantuml-views (:el view)))
(defmethod rndr/render-file :plantuml
[model format options view]
(let [dir-name (str (:render-dir options) "/plantuml/" (namespace (:id view)))]
(file/create-dir (io/as-file dir-name))
(io/as-file (str dir-name "/"
(name (:id view)) ".puml"))))
(defmethod rndr/render-view :plantuml
[model format options view]
(let [result (render-plantuml-view model options view)]
(with-open [wrt (io/writer (rndr/render-file model format options view))]
(binding [*out* wrt]
(println (str/join "\n" result))))))
(defmethod rndr/render :plantuml
[model format options]
(doseq [view (model/views model)]
(when (plantuml-view? view)
(rndr/render-view model format options
(assoc view :ct (view/specified-elements model view)) ; TODO do preprocessing once in build phase?
))))