-
Notifications
You must be signed in to change notification settings - Fork 3
/
IT4Kids.pro
186 lines (170 loc) · 5.54 KB
/
IT4Kids.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
#-------------------------------------------------
#
# Project created by QtCreator 2015-08-23T17:16:47
#
#-------------------------------------------------
QT += core gui multimedia
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets printsupport
CONFIG += c++11
exists($$[QT_INSTALL_HEADERS]/Qsci/qsciglobal.h) {
message(Found QScintilla2)
CONFIG += qscintilla2
DEFINES += CONF_CODE_EDITOR
}
INCLUDEPATH += src
DESTDIR=bin #Target file directory
OBJECTS_DIR=generated #Intermediate object files directory
MOC_DIR=generated #Intermediate moc files directory
# Location of python files
PYPATH = $$PWD/python
ASSETSPATH = $$PWD/Assets
TARGET = it4kids-editor
TEMPLATE = app
TRANSLATIONS = resources/translations/editor_de.ts
SOURCES += src/main.cpp\
src/mainwindow.cpp \
src/scene.cpp \
src/scriptarea.cpp \
src/dockingarea.cpp \
src/spriteselect.cpp \
src/sprite.cpp \
src/param/paramclone.cpp \
src/param/paramcolor.cpp \
src/param/paramcostume.cpp \
src/param/paramdelim.cpp \
src/param/paramdestination.cpp \
src/param/paramdirection.cpp \
src/param/paramdock.cpp \
src/param/parameffect.cpp \
src/param/paraminteraction.cpp \
src/param/paramjoinwords.cpp \
src/param/paramkey.cpp \
src/param/paramlistid.cpp \
src/param/paramlistselec.cpp \
src/param/parammath.cpp \
src/param/parammessage.cpp \
src/param/paramnumber.cpp \
src/param/paramsound.cpp \
src/param/paramstopchoices.cpp \
src/param/paramstring.cpp \
src/param/paramtouch.cpp \
src/param/paramtype.cpp \
src/param/paramvariables.cpp \
src/audio/audioengine.cpp \
src/audio/wavfile.cpp \
src/audio/soundselect.cpp \
src/costume/costume.cpp \
src/costume/costumeselect.cpp \
src/dragelem/categoryselect.cpp \
src/dragelem/commandde.cpp \
src/dragelem/draggableelement.cpp \
src/dragelem/dragelemcategory.cpp \
src/dragelem/dragelemlist.cpp \
src/dragelem/hatde.cpp \
src/dragelem/predicatede.cpp \
src/dragelem/reporterde.cpp \
src/dragelem/scriptdock.cpp \
src/dragelem/wrapperde.cpp \
src/teacher/studentlist.cpp \
src/newspritename.cpp\
src/codegenerator.cpp\
src/saveloadclass.cpp \
src/teacher/student.cpp \
src/teacher/teacher.cpp \
src/teacherlogin.cpp \
src/pythoncontroller.cpp \
src/param/paramcombobox.cpp \
src/param/param.cpp \
src/param/parampredicate.cpp
HEADERS += src/mainwindow.h \
src/scene.h \
src/scriptarea.h \
src/dockingarea.h \
src/dragelem/scriptdock.h \
src/spriteselect.h \
src/sprite.h \
src/param/param.h \
src/param/paramclone.h \
src/param/paramcolor.h \
src/param/paramcostume.h \
src/param/paramdelim.h \
src/param/paramdestination.h \
src/param/paramdirection.h \
src/param/paramdock.h \
src/param/parameffect.h \
src/param/paraminteraction.h \
src/param/paramjoinwords.h \
src/param/paramkey.h \
src/param/paramlistid.h \
src/param/paramlistselec.h \
src/param/parammath.h \
src/param/parammessage.h \
src/param/paramnumber.h \
src/param/paramsound.h \
src/param/paramstopchoices.h \
src/param/paramstring.h \
src/param/paramtouch.h \
src/param/paramtype.h \
src/param/paramvariables.h \
src/audio/audioengine.h \
src/audio/wavfile.h \
src/audio/soundselect.h \
src/costume/costume.h \
src/costume/costumeselect.h \
src/dragelem/categoryselect.h \
src/dragelem/commandde.h \
src/dragelem/draggableelement.h \
src/dragelem/dragelemcategory.h \
src/dragelem/dragelemlist.h \
src/dragelem/hatde.h \
src/dragelem/predicatede.h \
src/dragelem/reporterde.h \
src/dragelem/scriptdock.h \
src/dragelem/wrapperde.h \
src/teacher/studentlist.h \
src/newspritename.h\
src/codegenerator.h\
src/saveloadclass.h \
src/teacher/student.h \
src/teacher/teacher.h \
src/teacherlogin.h \
src/pythoncontroller.h \
src/param/paramcombobox.h \
src/param/parampredicate.h
FORMS += src/mainwindow.ui \
src/newspritename.ui \
src/teacherlogin.ui
RESOURCES += \
resources/resources.qrc
unix:{
QMAKE_CFLAGS += $$system(python3-config --cflags)
QMAKE_CXXFLAGS += $$system(python3-config --cflags)
LIBS += $$system(python3-config --ldflags)
}
win32:{
PY_VERSIONS = 3.5 3.5-32 3.4 3.3
for(PY_VERSION, PY_VERSIONS) {
PY_HOME = $$quote($$system(reg query HKCU\\SOFTWARE\\Python\\PythonCore\\$$PY_VERSION\\InstallPath /ve))
PY_HOME ~= s/.*(\\w:.*)/\\1
!exists($$PY_HOME\\include\\Python.h) {
PY_HOME = $$quote($$system(reg query HKLM\\SOFTWARE\\Python\\PythonCore\\$$PY_VERSION\\InstallPath /ve))
PY_HOME ~= s/.*(\\w:.*)/\\1
!exists($$PY_HOME\\include\\Python.h):next()
}
PY_LIB_BASENAME = python$${PY_VERSION}
PY_LIB_BASENAME ~= s/\\./
PY_LIB_BASENAME = $$section(PY_LIB_BASENAME, -, 0, 0)
CONFIG(debug, debug|release):PY_LIB_BASENAME = $${PY_LIB_BASENAME}_d
INCLUDEPATH *= $$PY_HOME\\include
LIBS *= -L$$PY_HOME\\libs -l$${PY_LIB_BASENAME}
message(Found Python$$PY_VERSION at $$PY_HOME)
break()
}
}
pythondata.commands = $(COPY_DIR) $$shell_path($$PYPATH) $$shell_path($$OUT_PWD/$$DESTDIR/python)
assetsdata.commands += $(COPY_DIR) $$shell_path($$ASSETSPATH) $$shell_path($$OUT_PWD/$$DESTDIR/Assets)
first.depends = $(first) pythondata assetsdata
export(first.depends)
export(pythondata.commands)
export(assetsdata.commands)
QMAKE_EXTRA_TARGETS += first pythondata assetsdata