-
Notifications
You must be signed in to change notification settings - Fork 0
/
draw.z80
1089 lines (1014 loc) · 30.3 KB
/
draw.z80
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
IF DEBUG_DIRTY_FLASH
DIRTY_FLASHER_INIT: EQU %10101010
temp_dirty_flasher: defb DIRTY_FLASHER_INIT ; bit pattern for flashing (bits are rotated)
FLASH: equ 255 ; what to flash with
dirty_flasher:
; using a counter, flipflop the actual data with something else
; to visually indicate which areas are being redrawn
push hl
ld hl, temp_dirty_flasher
bit 0, (hl)
jr z, @+no_flash
ld a, FLASH
@no_flash:
pop hl
ret
update_dirty_flasher:
ld hl, temp_dirty_flasher
rrc (hl)
ret
reset_dirty_flasher:
ld hl, temp_dirty_flasher
ld (hl), DIRTY_FLASHER_INIT
ret
ENDIF
box_at_hl:
; modifies bc, hl
; draw just a square outline box (used for the cursor)
; using color nibble passed in A register
; on entry, hl = screen location for drawing the box
IF DEBUG_DIRTY_FLASH
call dirty_flasher
ENDIF
; draw top (left to right)
ld (hl), a
inc l
ld (hl), a
inc l
ld (hl), a
inc l
ld (hl), a
inc l
ld (hl), a
inc l
ld (hl), a
inc l
ld (hl), a
inc l
ld (hl), a
; draw right side (downwards)
inc h
ld (hl), a
inc h
ld (hl), a
inc h
ld (hl), a
inc h
ld (hl), a
inc h
ld (hl), a
inc h
ld (hl), a
inc h
ld (hl), a
; draw left side (upwards)
ld b, a
ld a, l
sub 7
ld l, a
ld a, b
ld (hl), a
dec h
ld (hl), a
dec h
ld (hl), a
dec h
ld (hl), a
dec h
ld (hl), a
dec h
ld (hl), a
dec h
ld (hl), a
dec h
; draw odd left side (downwards)
ld a, l
add 128
ld l, a
ld a, h
adc 0
ld h, a
ld a, b
ld (hl), a
inc h
ld (hl), a
inc h
ld (hl), a
inc h
ld (hl), a
inc h
ld (hl), a
inc h
ld (hl), a
inc h
ld (hl), a
inc h
; draw bottom
ld (hl), a
inc l
ld (hl), a
inc l
ld (hl), a
inc l
ld (hl), a
inc l
ld (hl), a
inc l
ld (hl), a
inc l
ld (hl), a
inc l
ld (hl), a
; draw right side (upwards)
dec h
ld (hl), a
dec h
ld (hl), a
dec h
ld (hl), a
dec h
ld (hl), a
dec h
ld (hl), a
dec h
ld (hl), a
dec h
ld (hl), a
ret
defer_fillrect_16x2_black_at_de:
; modifies hl, bc
; see comment below, and this is even worse in terms of efficiency
; because this just blacks out 16x16 instead of 16x2
; (fall through to the same fn as below)
defer_fillrect_16x16_black_at_de:
; modifies hl, bc
; it's sortof fine for now because the blank tile IS the black 16x16
; but this disregards alignment e.g. background images TODO
; also, it's less efficient than the old plain black 16x16
xor a ; get the 'blank' tile
jp defer_draw_tile_at_de_tile_a
; TODO
; need a vertical slice, horizontal slice, and full 16x16 rect fill
; vertical slice is for horizontal sliders;
; horizontal slice is for vertical sliders and falling blocks;
; full 16x16 rect fill is for shoving a block left or right, and for cursor itself.
; can optimize later
fillrect_16x16_black_at_de:
; get a black (double) pixel
xor a
;IF DEBUG_DIRTY_FLASH
;call dirty_flasher
;ENDIF
jp fillrect_16x16_de_colorbyte_a
_draw_debug_tile_at_de_tile_a:
; modifies bc, de
; draw a fake tile, for debug purposes
; (just solid fill 16x16)
; on entry, de = screen buffer topleft corner of tile destination
; a = which tile to draw (0 = blank space, 1 = wall, 2 = triangle etc etc)
; multiply A by 17 to get a conveniently-coloured two-nibble (two pixel) value in A
ld b,a
sla a
sla a
sla a
sla a
add b
; fall through to:
fillrect_16x16_de_colorbyte_a:
; modifies bc, de
; draw a solid 16x16 using color byte A (two nibbles)
; step 1. left to right and right to left even rows
; moving down the screen (even rows only)
ld b, 4
ld c, a ; backup
@evens:
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc d
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
inc d
djnz @-evens
dec d
ld a, e
add 128
ld e, a
ld a, d
adc 0
ld d, a
; step 2. left to right and right to left odd rows
; moving up the screen (odd rows only)
ld a, c ; restore
ld b, 4
@odds:
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
dec d
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec d
djnz @-odds
ret
defer_draw_tile_at_de_tile_a:
; Adds this tile to the draw_list to draw (in the draw routine)
; modifies hl, bc
; on entry, de = screen buffer topleft corner of tile destination
; a = which tile to draw (0 = blank space, 1 = wall, 2 = triangle etc etc)
; w.r.t tile_bitmaps
; multiply a by 128 to get offset into bitmap data
ld c, 0
sra a ; shift lowest bit of A into CARRY
rr c ; shift CARRY into c
add a, tiles_bitmaps/256
ld b,a
call push_draw_list_bc_de
ret
draw_tile_at_de_tile_a:
; modifies de, hl, bc
; on entry, de = screen buffer topleft corner of tile destination
; a = which tile to draw (0 = blank space, 1 = wall, 2 = triangle etc etc)
; w.r.t tile_bitmaps
; multiply a by 128 to get offset into bitmap data
ld l, 0
sra a ; shift lowest bit of a into c
rr l ; shift c into l
add a, tiles_bitmaps/256
ld h,a
;ld hl, tiles_bitmaps
; fall through to:
draw_bitmap_16x16_hl_at_de:
; modifies de, hl, bc
; draws an unmasked full 16x16 bitmap onto screen
; bitmap is already in 'optimized' format (butterfly sequence)
; on entry, de = screen buffer topleft corner of tile destination
; hl = bitmap data (could be anything; probably a tile)
; step 1. draw left to right and right to left even rows
; moving down the screen (even rows only)
IF DEBUG_DIRTY_FLASH
; using a counter, flipflop the actual data with something else
; to visually indicate which areas are being redrawn
push hl
ld hl, temp_dirty_flasher
bit 0, (hl)
pop hl
jr z, @+_normal
ld hl, tiles_bitmaps ; blank tile
@_normal:
ENDIF
ld b, 4
ld c, 255 ; just a dummy, to avoid LDI from decrementing B!
@evens:
; comparison of techniques here:
; manual sequence ( ld a, (hl) / ld (de), a / dec e / inc l ) = 7+7+4+4 = 22
; manual sequence * 8 = 8 * 22 = 176
; LDI * 7 + manual * 1 = 16 * 7 + 22 = 134
; LDI * 8 + push/pop + DEC D = 16 * 8 + 11 + 10 + 4 = 153 ; so that's definitely not better, it's worse
;
; consider two rows (both even; or both odd) . can either go left-to-right, right-to-left
; in which case left-to-right is all LDI, right-to-left is all manual (and can just
; inc d between those two things))
; LDI * 7 + manual * 1 + manual * 8 = 176 + 134 = 310
;
; or can use LDI (left-to-right direction) for both rows, and just subtract 7 from E
; LDI * 7 + manual * 1 + adjust E + LDI * 7 + manual * 1 + adjust E = 134 + 4+7+4 + 134 + 4+7+4 = 298
;
; Looks like that second approach is (slightly) better
LDI
LDI
LDI
LDI
LDI
LDI
LDI
ld a, (hl)
ld (de), a
inc d
inc l
ld a, e
sub 7
ld e, a
LDI
LDI
LDI
LDI
LDI
LDI
LDI
ld a, (hl)
ld (de), a
inc d
inc l
ld a, e
sub 7
ld e, a
djnz @-evens
dec d
; move down one row of pixels
ld a, e
add 128
ld e, a
ld a, d
adc 0
ld d, a
; step 2. draw left to right and right to left odd rows
; moving up the screen (odd rows only)
ld b, 4
@odds:
LDI
LDI
LDI
LDI
LDI
LDI
LDI
ld a, (hl)
ld (de), a
dec d
inc l
ld a, e
sub 7
ld e, a
LDI
LDI
LDI
LDI
LDI
LDI
LDI
ld a, (hl)
ld (de), a
dec d
inc l
ld a, e
sub 7
ld e, a
djnz @-odds
ret
draw_tile_at_de_tile_a_hshift:
; modifies de, hl, bc
; on entry, de = screen buffer topleft corner of tile destination
; multiply A by 144 to get offset into bitmap data
; since shifted bitmaps are 18*16 not 16*16
; 144 = 128 + 16
; do the 128 first (that's easy), then the 16. A<16 so A*16 still fits in A.
ld b, a ; temp
ld l, 0
sra a ; shift lowest bit of A into carry
rr l ; shift carry into l - permissible since L=0 !!
ld h, a ; HL is now A * 128 (so, next get A *= 16)
ld a, b
add a, a
add a, a
add a, a
add a, a ; A *= 16
add a, l ; might generate carry, so add carry to h below
ld l, a
ld a, h
adc 0
ld h, a
; now HL is A * 144
ld bc, tiles_bitmaps_hshift
add hl, bc
; fall through to:
draw_bitmap_18x16_hl_at_de:
; modifies de, hl, bc
; draws a masked (left and right nibble only) 18x16 bitmap onto screen
; bitmap is already in 'optimized' format (butterfly sequence)
; on entry, de = screen buffer topleft corner of tile destination
; hl = bitmap data (could be anything; probably a tile)
IF DEBUG_DIRTY_FLASH
; using a counter, flipflop the actual data with something else
; to visually indicate which areas are being redrawn
push hl
ld hl, temp_dirty_flasher
bit 0, (hl)
pop hl
jr z, @+_normal
ld hl, tiles_bitmaps_hshift ; blank tile
@_normal:
ENDIF
ld b, 4
ld c, 255 ; just a dummy, to avoid LDI from decrementing B!
@evens:
; first column, custom mask
ld a, (de)
and 0xf0
or (hl)
ld (de), a
inc e
inc hl
; 14 pixels via LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
; last column, custom mask
ld a, (de)
and 0x0f
or (hl)
ld (de), a
inc d
inc hl
ld a, e
sub 8
ld e, a
; first column, custom mask
ld a, (de)
and 0xf0
or (hl)
ld (de), a
inc e
inc hl
LDI
LDI
LDI
LDI
LDI
LDI
LDI
; last column, custom mask
ld a, (de)
and 0x0f
or (hl)
ld (de), a
inc hl
inc d
ld a, e
sub 8
ld e, a
djnz @-evens
dec d
; move down one row of pixels
ld a, e
add 128
ld e, a
ld a, d
adc 0
ld d, a
ld b, 4
@odds:
ld a, (de)
and 0xf0
or (hl)
ld (de), a
inc e
inc hl
LDI
LDI
LDI
LDI
LDI
LDI
LDI
ld a, (de)
and 0x0f
or (hl)
ld (de), a
inc hl
dec d
ld a, e
sub 8
ld e, a
ld a, (de)
and 0xf0
or (hl)
ld (de), a
inc e
inc hl
LDI
LDI
LDI
LDI
LDI
LDI
LDI
ld a, (de)
and 0x0f
or (hl)
ld (de), a
inc hl
dec d
ld a, e
sub 8
ld e, a
djnz @-odds
ret
fillrect_16x2_black_at_de:
; get a black (double) pixel
xor a
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
ld a, e
add 128
ld e, a
ld a, d
adc 0
ld d, a
xor a
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
ret
fillrect_16x1_black_at_de:
; get a black (double) pixel
xor a
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
ret
fillrect_2x16_black_at_de:
; get a black (double) pixel
xor a
ld (de), a
inc d
ld (de), a
inc d
ld (de), a
inc d
ld (de), a
inc d
ld (de), a
inc d
ld (de), a
inc d
ld (de), a
inc d
ld (de), a
ld a, e
add 128
ld e, a
ld a, d
adc 0
ld d, a
xor a
ld (de), a
dec d
ld (de), a
dec d
ld (de), a
dec d
ld (de), a
dec d
ld (de), a
dec d
ld (de), a
dec d
ld (de), a
dec d
ld (de), a
ret
draw_masked_bitmap_32x16_hl_at_de:
; modifies hl, de, bc
; hl points to 32x16 bitmap with mask (first byte is mask, second byte is pixel data)
; de points to screen
@pairs_down: equ FOR 4
@row_l_to_r: equ FOR 15
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
inc e
NEXT @row_l_to_r
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
inc d
@row_r_to_l: equ FOR 15
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
dec e
NEXT @row_r_to_l
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
inc d
NEXT @pairs_down
dec d
ld a, e
add 128
ld e, a
ld a, d
adc 0
ld d, a
@pairs_up: equ FOR 4
@row_l_to_r: equ FOR 15
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
inc e
NEXT @row_l_to_r
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
dec d
@row_r_to_l: equ FOR 15
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
dec e
NEXT @row_r_to_l
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
dec d
NEXT @pairs_up
ret
draw_masked_bitmap_16x16_hl_at_de:
; modifies hl, de, bc
; hl points to 16x16 bitmap with mask (first byte is mask, second byte is pixel data)
; de points to screen
@pairs_down: equ FOR 4
@row_l_to_r: equ FOR 7
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
inc e
NEXT @row_l_to_r
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
inc d
@row_r_to_l: equ FOR 7
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
dec e
NEXT @row_r_to_l
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
inc d
NEXT @pairs_down
dec d
ld a, e
add 128
ld e, a
ld a, d
adc 0
ld d, a
@pairs_up: equ FOR 4
@row_l_to_r: equ FOR 7
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
inc e
NEXT @row_l_to_r
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
dec d
@row_r_to_l: equ FOR 7
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
dec e
NEXT @row_r_to_l
ld a, (de)
and (hl)
inc hl
or (hl)
inc hl
ld (de), a
dec d
NEXT @pairs_up
ret
fillrect_16x8_black_at_de:
; get a black (double) pixel
xor a
fillrect_16x8_de_colorbyte_a:
ld c, a
ld b, 2
@evens:
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc d
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
inc d
djnz @-evens
dec d
ld a, e ; move down one row of pixels
add 128
ld e, a
ld a, d
adc 0
ld d, a
ld a, c
ld b, 2
@odds:
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
dec d
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec d
djnz @-odds
ret
fillrect_8x8_black_at_de:
; get a black (double) pixel
xor a
fillrect_8x8_de_colorbyte_a:
push af
ld b, 2
@evens:
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc e
ld (de), a
inc d
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
dec e
ld (de), a
inc d
djnz @-evens
dec d
ld a, e ; move down one row of pixels
add 128
ld e, a
ld a, d
adc 0
ld d, a
pop af
ld b, 2
@odds:
ld (de), a
inc e
ld (de), a
inc e