/
setcmploop-x86_64.S
346 lines (337 loc) · 5.03 KB
/
setcmploop-x86_64.S
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
#define FUNC(name) \
.global name; \
.hidden name; \
.type name,@function; \
.align 16; \
name:
#define ENDF(name) \
.size name,.-name
#define Pv %rdi
#define Pend %rsi
#define Rv %rdx
#define Rend %rcx
#define Rval %r8d
#define Pval %r9d
#define Addr %r9 // clobbers Pval
#define Le %r10d
#define Ge %r11d
#define Px0 %xmm1
#define Px1 %xmm2
#define Rx %xmm3
#define L(name) .Lsse2##name
#define C(name) .Lsse2##name##__LINE__
FUNC(setcmploop_sse2)
cmpl $0,-4(Rv,Rend,4)
jl setcmploop_cmov
mov (Rv),Rval
mov (Pv),Pval
lea (Pv,Pend,4),Pend
lea (Rv,Rend,4),Rend
mov $8,Le
mov $8,Ge
L(cmp):
cmp Rval,Pval
jb L(lt)
L(ge):
add $4,Rv
cmp Rval,Pval
jne L(gt)
C(eq):
add $4,Pv
cmp Rv,Rend
je L(breakR)
mov (Rv),Rval
mov (Pv),Pval
cmp Pv,Pend
jne L(cmp)
jmp L(breakP)
L(lt2):
cmp Rval,18*4(Pv)
jae L(found18)
lea 27*4(Pv),Addr
cmp Rval,27*4(Pv)
jae L(found27)
mov Addr,Pv
L(lt):
cmp Rval,9*4(Pv)
jb L(lt2)
C(found9):
movdqu 1*4(Pv),Px0
movdqu 5*4(Pv),Px1
movd Rval,Rx
pshufd $0,Rx,Rx
movdqa Rx,%xmm0
pcmpgtd Px0,Rx
pcmpgtd Px1,%xmm0
packssdw %xmm0,Rx
pmovmskb Rx,%eax
add $1*4,Pv
xor Le,Le
not %eax
tzcnt %eax,%eax
lea (Pv,%rax,2),Pv
mov (Pv),Pval
cmp Pend,Pv
jb L(ge)
jmp L(breakP)
L(found18):
movdqu 10*4(Pv),Px0
movdqu 14*4(Pv),Px1
movd Rval,Rx
pshufd $0,Rx,Rx
movdqa Rx,%xmm0
pcmpgtd Px0,Rx
pcmpgtd Px1,%xmm0
packssdw %xmm0,Rx
pmovmskb Rx,%eax
add $10*4,Pv
xor Le,Le
not %eax
tzcnt %eax,%eax
lea (Pv,%rax,2),Pv
mov (Pv),Pval
cmp Pend,Pv
jb L(ge)
jmp L(breakP)
L(found27):
movdqu 19*4(Pv),Px0
movdqu 23*4(Pv),Px1
movd Rval,Rx
pshufd $0,Rx,Rx
movdqa Rx,%xmm0
pcmpgtd Px0,Rx
pcmpgtd Px1,%xmm0
packssdw %xmm0,Rx
pmovmskb Rx,%eax
add $19*4,Pv
xor Le,Le
not %eax
tzcnt %eax,%eax
lea (Pv,%rax,2),Pv
mov (Pv),Pval
cmp Pend,Pv
jb L(ge)
L(breakP):
xor %eax,%eax
cmp Rv,Rend
cmovne %eax,Ge
jmp L(ret)
L(gt):
xor Ge,Ge
cmp Rv,Rend
je L(breakR)
mov (Rv),Rval
jmp L(cmp)
L(breakR):
xor %eax,%eax
cmp Pv,Pend
cmovne %eax,Le
L(ret):
lea (Le,Ge,2),%ecx
mov $0x01fffe,%eax
shr %cl,%eax
movsbl %al,%eax
ret
ENDF(setcmploop_sse2)
#undef L
#undef C
#define L(name) .Lavx2##name
#define C(name) .Lavx2##name##__LINE__
FUNC(setcmploop_avx2)
cmpl $0,-4(Rv,Rend,4)
jl setcmploop_cmov
mov (Rv),Rval
mov (Pv),Pval
lea (Pv,Pend,4),Pend
lea (Rv,Rend,4),Rend
mov $8,Le
mov $8,Ge
L(cmp):
cmp Rval,Pval
jb L(lt)
L(ge):
add $4,Rv
cmp Rval,Pval
jne L(gt)
C(eq):
add $4,Pv
cmp Rv,Rend
je L(breakR)
mov (Rv),Rval
mov (Pv),Pval
cmp Pv,Pend
jne L(cmp)
jmp L(breakP)
L(lt2):
cmp Rval,18*4(Pv)
jae L(found18)
lea 27*4(Pv),Addr
cmp Rval,27*4(Pv)
jae L(found27)
mov Addr,Pv
L(lt):
cmp Rval,9*4(Pv)
jb L(lt2)
C(found9):
vmovdqu 1*4(Pv),%ymm0
vmovd Rval,%xmm1
vpbroadcastd %xmm1,%ymm1
vpcmpgtd %ymm0,%ymm1,%ymm1
vpmovmskb %ymm1,%eax
add $1*4,Pv
xor Le,Le
not %rax
tzcnt %rax,%rax
add %rax,Pv
mov (Pv),Pval
cmp Pend,Pv
jb L(ge)
jmp L(breakP)
L(found18):
vmovdqu 10*4(Pv),%ymm0
vmovd Rval,%xmm1
vpbroadcastd %xmm1,%ymm1
vpcmpgtd %ymm0,%ymm1,%ymm1
vpmovmskb %ymm1,%eax
add $10*4,Pv
xor Le,Le
not %rax
tzcnt %rax,%rax
add %rax,Pv
mov (Pv),Pval
cmp Pend,Pv
jb L(ge)
jmp L(breakP)
L(found27):
vmovdqu 19*4(Pv),%ymm0
vmovd Rval,%xmm1
vpbroadcastd %xmm1,%ymm1
vpcmpgtd %ymm0,%ymm1,%ymm1
vpmovmskb %ymm1,%eax
add $19*4,Pv
xor Le,Le
not %rax
tzcnt %rax,%rax
add %rax,Pv
mov (Pv),Pval
cmp Pend,Pv
jb L(ge)
L(breakP):
xor %eax,%eax
cmp Rv,Rend
cmovne %eax,Ge
jmp L(ret)
L(gt):
xor Ge,Ge
cmp Rv,Rend
je L(breakR)
mov (Rv),Rval
jmp L(cmp)
L(breakR):
xor %eax,%eax
cmp Pv,Pend
cmovne %eax,Le
L(ret):
vzeroupper
lea (Le,Ge,2),%ecx
mov $0x01fffe,%eax
shr %cl,%eax
movsbl %al,%eax
ret
ENDF(setcmploop_avx2)
#undef L
#undef C
#define L(name) .Lcmov##name
#define C(name) .Lcmov##name##__LINE__
FUNC(setcmploop_cmov)
mov (Rv),Rval
mov (Pv),Pval
lea (Pv,Pend,4),Pend
lea (Rv,Rend,4),Rend
mov $8,Le
mov $8,Ge
L(cmp):
cmp Rval,Pval
jb L(lt)
L(ge):
add $4,Rv
cmp Rval,Pval
jne L(gt)
C(eq):
add $4,Pv
cmp Rv,Rend
je L(breakR)
mov (Rv),Rval
mov (Pv),Pval
cmp Pv,Pend
jne L(cmp)
jmp L(breakP)
L(lt2):
cmp Rval,8*4(Pv)
jae L(found8)
lea 12*4(Pv),Addr
cmp Rval,12*4(Pv)
jae L(found12)
mov Addr,Pv
L(lt):
cmp Rval,4*4(Pv)
jb L(lt2)
C(found4):
cmp Rval,2*4(Pv)
lea 4*4(Pv),Addr
lea 2*4(Pv),Pv
cmovb Addr,Pv
xor Le,Le
lea -4(Pv),Addr
cmp Rval,-4(Pv)
cmovae Addr,Pv
mov (Pv),Pval
cmp Pv,Pend
jne L(ge)
jmp L(breakP)
L(found8):
cmp Rval,6*4(Pv)
lea 8*4(Pv),Addr
lea 6*4(Pv),Pv
cmovb Addr,Pv
xor Le,Le
lea -4(Pv),Addr
cmp Rval,-4(Pv)
cmovae Addr,Pv
mov (Pv),Pval
cmp Pv,Pend
jne L(ge)
jmp L(breakP)
L(found12):
cmp Rval,10*4(Pv)
lea 10*4(Pv),Pv
cmovb Addr,Pv
xor Le,Le
lea -4(Pv),Addr
cmp Rval,-4(Pv)
cmovae Addr,Pv
mov (Pv),Pval
cmp Pv,Pend
jne L(ge)
L(breakP):
xor %eax,%eax
cmp Rv,Rend
cmovne %eax,Ge
jmp L(ret)
L(gt):
xor Ge,Ge
cmp Rv,Rend
je L(breakR)
mov (Rv),Rval
jmp L(cmp)
L(breakR):
xor %eax,%eax
cmp Pv,Pend
cmovne %eax,Le
L(ret):
lea (Le,Ge,2),%ecx
mov $0x01fffe,%eax
shr %cl,%eax
movsbl %al,%eax
ret
ENDF(setcmploop_cmov)