build.gradle

plugins {
    id 'org.jetbrains.kotlin.jvm' version '1.3.50'
    id 'java-library'
    id 'maven-publish'
    id 'jacoco'
    id 'maven'
    id 'org.jetbrains.dokka' version '0.10.0'
}

repositories {
    mavenCentral()
    jcenter()
}

dependencies {
    compile 'org.jetbrains.kotlin:kotlin-stdlib:1.3.50'
    compile 'org.jetbrains.kotlin:kotlin-reflect:1.3.50'
    compile 'com.sparkjava:spark-core:2.9.1'
    compile 'org.slf4j:slf4j-simple:1.7.28'
    compile 'org.json:json:20190722'
    compile group: 'commons-io', name: 'commons-io', version: '2.6'
    compile group: 'com.hubspot.jinjava', name: 'jinjava', version: '2.1.19'

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.1.1'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.1.1'
    testCompile 'org.seleniumhq.selenium:selenium-server:3.141.59'
    testCompile 'org.seleniumhq.selenium:selenium-support:3.141.59'
    testCompile group: 'io.github.bonigarcia', name: 'webdrivermanager', version: '3.7.1'
}

group = 'org.team5419'
version = '0.12.3' /* Change this when deploying a new version */

task sourcesJar(type: Jar) {
    from sourceSets.main.allJava
    classifier = 'sources'
}

task dokkaJavadoc(type: org.jetbrains.dokka.gradle.DokkaTask) {
    outputFormat = 'javadoc'
    outputDirectory = "$buildDir/javadoc"
    inputs.dir 'src/main/kotlin'
}

task javadocJar(type: Jar, dependsOn: dokkaJavadoc) {
    classifier = 'javadoc'
    from "$buildDir/javadoc"
}

dokka {
    outputFormat = 'javadoc'
    outputDirectory = "$buildDir/htmldoc"
}

test {
    dependsOn 'cleanTest'

    useJUnitPlatform {
        excludeTags 'webdriver'
        excludeTags 'playground'
    }

    testLogging {
        events 'PASSED', 'FAILED', 'SKIPPED'
        showStandardStreams true
    }

    afterSuite { desc, result ->
        if (!desc.parent) {
            println "\nTest result: ${result.resultType}"
            println "Test summary: ${result.testCount} tests, " +
                    "${result.successfulTestCount} succeeded, " +
                    "${result.failedTestCount} failed, " +
                    "${result.skippedTestCount} skipped"
        }
    }
}

task webdriverTest(type: Test) {
    useJUnitPlatform {
        includeTags 'webdriver'
    }

    testLogging {
        events 'PASSED', 'FAILED', 'SKIPPED'
        showStandardStreams true
    }

    afterSuite { desc, result ->
        if (!desc.parent) {
            println "\nTest result: ${result.resultType}"
            println "Test summary: ${result.testCount} tests, " +
                    "${result.successfulTestCount} succeeded, " +
                    "${result.failedTestCount} failed, " +
                    "${result.skippedTestCount} skipped"
        }
    }

    outputs.upToDateWhen { false }

    shouldRunAfter test
}

task playgroundTest(type: Test) {
    useJUnitPlatform {
        includeTags 'playground'
    }

    testLogging {
        events 'PASSED', 'FAILED', 'SKIPPED'
        showStandardStreams true
    }

    afterSuite { desc, result ->
        if (!desc.parent) {
            println "\nTest result: ${result.resultType}"
            println "Test summary: ${result.testCount} tests, " +
                    "${result.successfulTestCount} succeeded, " +
                    "${result.failedTestCount} failed, " +
                    "${result.skippedTestCount} skipped"
        }
    }

    outputs.upToDateWhen { false }

    shouldRunAfter test
}

jacoco {
    toolVersion = '0.8.2'
}

jacocoTestReport {
    reports {
        xml.enabled true
        html.enabled false
    }
}

task tox {
    doLast {
        exec {
            executable 'tox'
        }
    }
}

test.finalizedBy 'tox'
// Alias tox as 'install_hooks'
task install_hooks(dependsOn: 'tox')

publishing {
    publications {
        library(MavenPublication) {
            artifactId = 'tsunami'
            from components.java
            artifact sourcesJar
            artifact javadocJar
            pom {
                name = 'Tsunami'
                description = 'A modern frc dashboard that uses websockets'
                url = 'https://github.com/team5419/tsunami'
            }
        }
    }
    repositories {
        maven{
        }
    }
}

class PublishToMavenRepositoryWithCreds extends PublishToMavenRepository {
    @Option(option="username", description="username of the user")
    public String username

    void setUsername(String username) {
        this.username = username
    }

    String getUsername() {
        return this.username
    }

    @Option(option="password", description="password of the user")
    public String password

    void setPassword(String password) {
        this.password = password
    }

    String getPassword() {
        return this.password
    }

    @Option(option="url", description="url to deploy to")
    public String url

    void setUrl(String url) {
        this.url = url
    }

    String getUrl() {
        return this.url
    }

}

task publishToTeamRepo(type: PublishToMavenRepositoryWithCreds) {
    doFirst {
        publishing.repositories.maven.credentials.username = username
        publishing.repositories.maven.credentials.password = password
        publishing.repositories.maven.url = url
    }
    publication = publishing.publications.library
    repository = publishing.repositories.maven
}