forked from pharo-project/pharo
-
Notifications
You must be signed in to change notification settings - Fork 0
/
ShiftClassBuilder.class.st
511 lines (397 loc) · 12.3 KB
/
ShiftClassBuilder.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
"
I know how to create classes in the system.
The classes are nor installed or modifies other objects. That is part of the job of the ShiftClassInstaller.
I can be extended by using a different builder enhancer.
See ShDefaultBuilderEnhancer for a default implementation.
I can be used directly to create anonymous classes, but it is better if you use the annonymous class installer.
I also can compare the old class with the configured new class to calculate the required changes.
"
Class {
#name : #ShiftClassBuilder,
#superclass : #Object,
#instVars : [
'buildEnvironment',
'superclassName',
'name',
'layoutDefinition',
'comment',
'commentStamp',
'superclass',
'category',
'newMetaclass',
'newClass',
'oldClass',
'oldMetaclass',
'builderEnhancer',
'metaclassClass',
'extensibleProperties',
'changeComparers',
'changes',
'metaSuperclass'
],
#classVars : [
'BuilderEnhancer'
],
#category : #'Shift-ClassBuilder'
}
{ #category : #'as yet unclassified' }
ShiftClassBuilder class >> defaultBuildEnhancer [
^ BuilderEnhancer ifNil: [ ShDefaultBuilderEnhancer ]
]
{ #category : #accessing }
ShiftClassBuilder class >> setDefaultBuilderEnhancer: aClass [
BuilderEnhancer := aClass
]
{ #category : #changes }
ShiftClassBuilder >> addChange: aChange [
changes add: aChange.
]
{ #category : #changes }
ShiftClassBuilder >> addChangeComparer: aChangeComparer [
changeComparers add: aChangeComparer.
]
{ #category : #building }
ShiftClassBuilder >> build [
self tryToFillOldClass.
self detectBuilderEnhancer.
self validateSuperclass.
self compareWithOldClass.
self layoutDefinition copySlotsIfUsedIn: oldClass.
self createMetaclass.
self createClass.
self createSharedVariables.
self oldClass ifNotNil: [
self newClass basicCategory: self oldClass basicCategory.
self copyOrganization.
self builderEnhancer compileMethodsFor: self. ].
self builderEnhancer afterMethodsCompiled: self.
self installSlots.
^ newClass
]
{ #category : #accessing }
ShiftClassBuilder >> buildEnvironment [
^ buildEnvironment
]
{ #category : #accessing }
ShiftClassBuilder >> buildEnvironment: anObject [
buildEnvironment := anObject
]
{ #category : #accessing }
ShiftClassBuilder >> builderEnhancer [
^ builderEnhancer ifNil: [ self detectBuilderEnhancer ]
]
{ #category : #accessing }
ShiftClassBuilder >> builderEnhancer: anObject [
builderEnhancer := anObject.
builderEnhancer initializeBuilder: self
]
{ #category : #accessing }
ShiftClassBuilder >> category [
^ category
]
{ #category : #accessing }
ShiftClassBuilder >> category: anObject [
category := anObject
]
{ #category : #accessing }
ShiftClassBuilder >> changeComparers [
^ changeComparers
]
{ #category : #accessing }
ShiftClassBuilder >> changes [
^ changes
]
{ #category : #accessing }
ShiftClassBuilder >> classNamed: aName [
^ self buildEnvironment classNamed:aName.
]
{ #category : #accessing }
ShiftClassBuilder >> classSlots: aSlotCollection [
self layoutDefinition classSlots: aSlotCollection.
]
{ #category : #accessing }
ShiftClassBuilder >> classTraitComposition [
^ extensibleProperties at: #classTraitComposition ifAbsent: {}
]
{ #category : #accessing }
ShiftClassBuilder >> classTraitComposition: aValue [
^ extensibleProperties at: #classTraitComposition put: aValue.
]
{ #category : #accessing }
ShiftClassBuilder >> comment [
^ comment
]
{ #category : #accessing }
ShiftClassBuilder >> comment: anObject [
comment := anObject
]
{ #category : #'accessing comment' }
ShiftClassBuilder >> comment:aComment stamp: anStamp [
self comment: aComment.
self commentStamp: anStamp.
]
{ #category : #accessing }
ShiftClassBuilder >> commentStamp [
^ commentStamp
]
{ #category : #accessing }
ShiftClassBuilder >> commentStamp: anObject [
commentStamp := anObject
]
{ #category : #changes }
ShiftClassBuilder >> compareWithOldClass [
oldClass ifNil: [ ^ self ].
changeComparers do: [ :e | e compareClass: oldClass with: self ].
changes ifEmpty: [ ShNoChangesInClass signal. ].
]
{ #category : #compiling }
ShiftClassBuilder >> compileMethods [
newClass compileAllFrom: self oldClass.
]
{ #category : #copying }
ShiftClassBuilder >> copyClassSlotsFromExistingClass [
"Ugly helper method: I copy over the class slots of the class in my builder environment."
| anOldClass oldSlots |
anOldClass := self environment at: name ifAbsent: [ ^ self ].
oldSlots := anOldClass class classLayout slotScope visibleSlots.
self classSlots:(oldSlots collect: [ :e | e copy index: nil; yourself ])
]
{ #category : #building }
ShiftClassBuilder >> copyOrganization [
newClass organization copyFrom: oldClass organization.
newClass class organization copyFrom: oldClass class organization.
]
{ #category : #installing }
ShiftClassBuilder >> createClass [
newClass := newMetaclass new.
newClass setName: self name.
self builderEnhancer
configureClass: newClass
superclass: self superclass
withLayoutType: self layoutDefinition layoutClass
slots: self layoutDefinition slots.
newClass environment: self buildEnvironment environment.
self builderEnhancer classCreated: self.
]
{ #category : #building }
ShiftClassBuilder >> createMetaclass [
newMetaclass := self metaclassClass new.
self builderEnhancer
configureMetaclass: newMetaclass
superclass: self metaSuperclass
withLayoutType: FixedLayout
slots: self layoutDefinition classSlots.
self builderEnhancer metaclassCreated: self.
]
{ #category : #building }
ShiftClassBuilder >> createSharedVariables [
self builderEnhancer
on: newClass
declareClassVariables: self layoutDefinition sharedVariables
sharing: self layoutDefinition sharedPoolsString.
]
{ #category : #initialization }
ShiftClassBuilder >> detectBuilderEnhancer [
| builderEnhancerClass |
builderEnhancerClass := ShDefaultBuilderEnhancer allSubclasses detect: [ :e | e isApplicableFor: self ] ifNone: [ self class defaultBuildEnhancer ].
builderEnhancer := builderEnhancerClass new.
builderEnhancer initializeBuilder: self.
^ builderEnhancer
]
{ #category : #'reflective operations' }
ShiftClassBuilder >> doesNotUnderstand: aMessage [
| selector variable setter|
selector := aMessage selector.
(selector isUnary or:[ selector isKeyword and:[ selector keywords size = 1] ])
ifFalse:[ ^ super doesNotUnderstand: aMessage].
setter := selector isKeyword.
variable := setter ifTrue:[(selector allButLast: 1) asSymbol] ifFalse:[selector].
(extensibleProperties includesKey: variable)
ifFalse: [ ^ super doesNotUnderstand: aMessage ].
setter
ifTrue:[ extensibleProperties at: variable put: aMessage argument]
ifFalse:[ ^ extensibleProperties at: variable].
]
{ #category : #accessing }
ShiftClassBuilder >> environment [
^ buildEnvironment environment
]
{ #category : #accessing }
ShiftClassBuilder >> environment: anEnvironment [
^ buildEnvironment environment: anEnvironment
]
{ #category : #initialization }
ShiftClassBuilder >> fillFor: aClass [
self
superclass: aClass superclass;
name: aClass getName;
layoutClass: aClass classLayout class;
slots: aClass slots ;
sharedVariablesFromString: aClass classVariablesString;
sharedPools: aClass sharedPoolsString;
category: aClass category;
environment: aClass environment;
copyClassSlotsFromExistingClass;
oldClass: aClass.
self builderEnhancer fillBuilder: self from: aClass.
]
{ #category : #testing }
ShiftClassBuilder >> hasToMigrateInstances [
^ self changes anySatisfy: [ :e | e hasToMigrateInstances ]
]
{ #category : #initialization }
ShiftClassBuilder >> initialize [
super initialize.
superclassName := #Object.
layoutDefinition := ShLayoutDefinition new.
layoutDefinition builder: self.
extensibleProperties := Dictionary new.
changeComparers := OrderedCollection new.
changes := Set new.
]
{ #category : #building }
ShiftClassBuilder >> installSlots [
newClass classLayout slots do: [ :each | each installingIn: newClass ].
newClass classLayout slots do: [ :each | each layoutChanged: newClass ].
newClass class classLayout slots do: [ :each | each installingIn: newClass class ].
newClass class classLayout slots do: [ :each | each layoutChanged: newClass class ].
]
{ #category : #accessing }
ShiftClassBuilder >> layoutClass: aLayoutClass [
self layoutDefinition layoutClass: aLayoutClass.
]
{ #category : #accessing }
ShiftClassBuilder >> layoutDefinition [
^ layoutDefinition
]
{ #category : #accessing }
ShiftClassBuilder >> metaSuperclass [
^ metaSuperclass ifNil:[ (superclass ifNil: [ Class ] ifNotNil: [ superclass class ]) ]
]
{ #category : #accessing }
ShiftClassBuilder >> metaSuperclass: aClass [
metaSuperclass := aClass
]
{ #category : #accessing }
ShiftClassBuilder >> metaclassClass [
^ metaclassClass ifNil: [ Metaclass ]
]
{ #category : #accessing }
ShiftClassBuilder >> metaclassClass: anObject [
metaclassClass := anObject
]
{ #category : #accessing }
ShiftClassBuilder >> name [
^ name
]
{ #category : #accessing }
ShiftClassBuilder >> name: anObject [
name := anObject.
self validateClassName.
]
{ #category : #accessing }
ShiftClassBuilder >> newClass [
^ newClass
]
{ #category : #accessing }
ShiftClassBuilder >> newMetaclass [
^ newMetaclass
]
{ #category : #changes }
ShiftClassBuilder >> notifyChanges [
changes do: #announceChanges
]
{ #category : #accessing }
ShiftClassBuilder >> oldClass [
^ oldClass
]
{ #category : #accessing }
ShiftClassBuilder >> oldClass: anObject [
oldClass := anObject.
oldClass ifNotNil: [oldMetaclass := oldClass class].
]
{ #category : #accessing }
ShiftClassBuilder >> oldMetaclass [
^ oldMetaclass
]
{ #category : #changes }
ShiftClassBuilder >> propagateChangesTo: anotherBuilder [
changes do: [ :e | e propagateToSubclasses: anotherBuilder ]
]
{ #category : #accessing }
ShiftClassBuilder >> propertyAt: aKey [
^ extensibleProperties at: aKey.
]
{ #category : #accessing }
ShiftClassBuilder >> propertyAt: aKey put: aValue [
extensibleProperties at: aKey put: aValue.
]
{ #category : #accessing }
ShiftClassBuilder >> sharedPools: aString [
self layoutDefinition sharedPools: ((aString substrings: ' ') collect: [:e | e asSymbol])
]
{ #category : #accessing }
ShiftClassBuilder >> sharedVariables: aCollection [
self layoutDefinition sharedVariables: (aCollection collect:[:e | e asClassVariable]).
]
{ #category : #accessing }
ShiftClassBuilder >> sharedVariablesFromString: aString [
layoutDefinition sharedVariables:((aString substrings: ' ') collect: [:x | x asSymbol => ClassVariable]).
]
{ #category : #accessing }
ShiftClassBuilder >> slots: aCollection [
self layoutDefinition slots: aCollection.
]
{ #category : #accessing }
ShiftClassBuilder >> superclass [
^ superclass ifNil:[ superclassName ifNotNil: [buildEnvironment classNamed: (self superclassName)]]
]
{ #category : #accessing }
ShiftClassBuilder >> superclass: aSuperclass [
aSuperclass ifNil:[superclassName := nil].
superclass := aSuperclass
]
{ #category : #accessing }
ShiftClassBuilder >> superclassName [
^ superclassName
]
{ #category : #accessing }
ShiftClassBuilder >> superclassName: anObject [
superclassName := anObject
]
{ #category : #accessing }
ShiftClassBuilder >> traitComposition [
^ extensibleProperties at: #traitComposition ifAbsent: {}
]
{ #category : #accessing }
ShiftClassBuilder >> traitComposition: aValue [
^ extensibleProperties at: #traitComposition put: aValue.
]
{ #category : #building }
ShiftClassBuilder >> tryToFillOldClass [
oldClass ifNotNil: [ ^self ].
name ifNil: [ ^self ].
self oldClass: (self buildEnvironment classNamed: self name)
]
{ #category : #'private validating' }
ShiftClassBuilder >> validateClassName [
name ifNil: [ ^self ].
"I try to convert to symbol, if there is an error the next guard will catch it"
[name := name asSymbol ] on:Error do: [ ].
name isSymbol ifFalse:[InvalidGlobalName
signal: 'Global names should be symbols'
for: name].
name isValidGlobalName ifFalse: [
InvalidGlobalName signal: 'Class name is not a valid global name. It must start with uppercase letter and continue with alphanumeric characters or underscore. Default names used in class or trait templates are not allowed.' for: name ].
DangerousClassNotifier check: name
]
{ #category : #'private validating' }
ShiftClassBuilder >> validateSuperclass [
self superclass ifNil: [ ^self ].
oldClass ifNil: [ ^ self ].
self superclass withAllSuperclassesDo: [ :aSuperclass |
aSuperclass = oldClass ifTrue:[
CircularHierarchyError signalFor: oldClass.
]
].
]