forked from pharo-project/pharo
-
Notifications
You must be signed in to change notification settings - Fork 0
/
RBBlockNode.class.st
370 lines (303 loc) · 7.79 KB
/
RBBlockNode.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
"
RBBlockNode is an AST node that represents a block ""[...]"".
Like RBMethodNode, the scope attribute is only valid after doing a semantic analyzing step.
Instance Variables:
arguments <SequenceableCollection of: RBVariableNode> the arguments for the block
bar <Integer | nil> position of the | after the arguments
body <RBSequenceNode> the code inside the block
colons <SequenceableCollection of: Integer> positions of each : before each argument
left <Integer> position of [
right <Integer> position of ]
scope <OCBlockScope | OCOptimizedBlockScope | nil> the scope associated with this code of this block
"
Class {
#name : #RBBlockNode,
#superclass : #RBValueNode,
#instVars : [
'left',
'right',
'colons',
'arguments',
'bar',
'body',
'scope',
'bcToASTCache'
],
#category : #'AST-Core-Nodes'
}
{ #category : #'instance creation' }
RBBlockNode class >> arguments: argNodes body: sequenceNode [
^(self new)
arguments: argNodes;
body: sequenceNode;
yourself
]
{ #category : #'instance creation' }
RBBlockNode class >> body: sequenceNode [
^self arguments: #() body: sequenceNode
]
{ #category : #comparing }
RBBlockNode >> = anObject [
self == anObject ifTrue: [^true].
self class = anObject class ifFalse: [^false].
self body = anObject body ifFalse: [^false].
self arguments size = anObject arguments size ifFalse: [^false].
self arguments with: anObject arguments do: [:first :second | first = second ifFalse: [^false]].
^true
]
{ #category : #visiting }
RBBlockNode >> acceptVisitor: aProgramNodeVisitor [
^ aProgramNodeVisitor visitBlockNode: self
]
{ #category : #accessing }
RBBlockNode >> allArgumentVariables [
^(self argumentNames asOrderedCollection)
addAll: super allArgumentVariables;
yourself
]
{ #category : #accessing }
RBBlockNode >> allDefinedVariables [
^(self argumentNames asOrderedCollection)
addAll: super allDefinedVariables;
yourself
]
{ #category : #accessing }
RBBlockNode >> allStatements [
"including temp variable definition."
^ self temporaries asOrderedCollection copy
addAll: super allStatements;
yourself
]
{ #category : #accessing }
RBBlockNode >> argumentNames [
^ self arguments collect: [:each | each name] as: Array
]
{ #category : #accessing }
RBBlockNode >> arguments [
^arguments
]
{ #category : #accessing }
RBBlockNode >> arguments: argCollection [
arguments := argCollection.
arguments do: [:each | each parent: self ]
]
{ #category : #'accessing-token' }
RBBlockNode >> bar [
^ bar
]
{ #category : #'accessing-token' }
RBBlockNode >> bar: anInteger [
bar := anInteger
]
{ #category : #accessing }
RBBlockNode >> blockVariables [
| vars |
vars := super blockVariables asOrderedCollection.
vars addAll: self argumentNames.
^vars
]
{ #category : #accessing }
RBBlockNode >> body [
^body
]
{ #category : #accessing }
RBBlockNode >> body: stmtsNode [
body := stmtsNode.
body parent: self
]
{ #category : #accessing }
RBBlockNode >> children [
^self arguments copyWith: self body
]
{ #category : #'accessing-token' }
RBBlockNode >> colons [
^ colons
]
{ #category : #'accessing-token' }
RBBlockNode >> colons: anArray [
colons := anArray
]
{ #category : #matching }
RBBlockNode >> copyInContext: aDictionary [
^ self class new
arguments: (self copyList: self arguments inContext: aDictionary);
body: (self body copyInContext: aDictionary);
yourself
]
{ #category : #testing }
RBBlockNode >> defines: aName [
^arguments anySatisfy: [:each | each name = aName]
]
{ #category : #testing }
RBBlockNode >> directlyUses: aNode [
^false
]
{ #category : #comparing }
RBBlockNode >> equalTo: anObject withMapping: aDictionary [
self class = anObject class ifFalse: [^false].
self arguments size = anObject arguments size ifFalse: [^false].
self arguments
with: anObject arguments
do: [:first :second | (first equalTo: second withMapping: aDictionary) ifFalse: [^false]].
(self body equalTo: anObject body withMapping: aDictionary)
ifFalse: [^false].
self arguments do: [:each | aDictionary removeKey: each name].
^true
]
{ #category : #testing }
RBBlockNode >> hasArgumentNamed: aString [
^ self arguments anySatisfy: [ :argument| argument name = aString ]
]
{ #category : #testing }
RBBlockNode >> hasArguments [
^ arguments isNotEmpty
]
{ #category : #testing }
RBBlockNode >> hasBlockReturn [
^ self body lastIsReturn
]
{ #category : #testing }
RBBlockNode >> hasTemporaries [
^ self temporaries isNotEmpty
]
{ #category : #testing }
RBBlockNode >> hasTemporaryNamed: aString [
^ self temporaries anySatisfy: [ :temp| temp name = aString ]
]
{ #category : #comparing }
RBBlockNode >> hash [
^ (self hashForCollection: self arguments) bitXor: self body hash
]
{ #category : #testing }
RBBlockNode >> headIsNotEmpty [
"Return true whether the receiver has some arguments or comments"
^ arguments isNotEmpty or: [ self comments isNotEmpty ]
]
{ #category : #initialization }
RBBlockNode >> initialize [
super initialize.
arguments := #().
colons := #().
left := 0.
right := 0
]
{ #category : #testing }
RBBlockNode >> isBlock [
^true
]
{ #category : #testing }
RBBlockNode >> isFaulty [
^(self arguments anySatisfy: [:each | each isFaulty] ) or: [ self body isFaulty]
]
{ #category : #testing }
RBBlockNode >> isImmediateNode [
^true
]
{ #category : #testing }
RBBlockNode >> isLast: aNode [
^body isLast: aNode
]
{ #category : #testing }
RBBlockNode >> lastIsReturn [
^ false
]
{ #category : #'accessing-token' }
RBBlockNode >> left [
^ left
]
{ #category : #'accessing-token' }
RBBlockNode >> left: anInteger [
left := anInteger
]
{ #category : #matching }
RBBlockNode >> match: aNode inContext: aDictionary [
aNode class = self class ifFalse: [^false].
^(self
matchList: arguments
against: aNode arguments
inContext: aDictionary)
and: [body match: aNode body inContext: aDictionary]
]
{ #category : #accessing }
RBBlockNode >> methodOrBlockNode [
"^ self"
]
{ #category : #testing }
RBBlockNode >> needsParenthesis [
^false
]
{ #category : #copying }
RBBlockNode >> postCopy [
super postCopy.
self arguments: (self arguments collect: [ :each | each copy ]).
self body: self body copy
]
{ #category : #accessing }
RBBlockNode >> precedence [
^0
]
{ #category : #testing }
RBBlockNode >> references: aVariableName [
^body references: aVariableName
]
{ #category : #'adding/removing' }
RBBlockNode >> removeTemporaryNamed: aName [
self body removeTemporaryNamed: aName
]
{ #category : #replacing }
RBBlockNode >> replaceNode: aNode withNode: anotherNode [
body == aNode ifTrue: [self body: anotherNode].
self arguments: (arguments
collect: [:each | each == aNode ifTrue: [anotherNode] ifFalse: [each]])
]
{ #category : #'accessing-token' }
RBBlockNode >> right [
^ right
]
{ #category : #'accessing-token' }
RBBlockNode >> right: anInteger [
right := anInteger
]
{ #category : #accessing }
RBBlockNode >> scope [
^ scope
]
{ #category : #accessing }
RBBlockNode >> scope: aScopedNode [
scope := aScopedNode
]
{ #category : #accessing }
RBBlockNode >> startWithoutParentheses [
^ left
]
{ #category : #accessing }
RBBlockNode >> statementComments [
"this is used for formatting comments for this node as a statement, but I don't have a single statement comment, my comments are place within the block code"
^ ''
]
{ #category : #accessing }
RBBlockNode >> statements [
^ self body statements
]
{ #category : #accessing }
RBBlockNode >> stopWithoutParentheses [
^ right
]
{ #category : #accessing }
RBBlockNode >> temporaries [
^ self body temporaries
]
{ #category : #accessing }
RBBlockNode >> temporaryNames [
^ self body temporaryNames
]
{ #category : #testing }
RBBlockNode >> uses: aNode [
aNode = body ifFalse: [^false].
^parent isMessage
ifTrue:
[(#(#ifTrue:ifFalse: #ifTrue: #ifFalse: #ifFalse:ifTrue:)
includes: parent selector) not
or: [parent isUsed]]
ifFalse: [self isUsed]
]