forked from pharo-project/pharo
-
Notifications
You must be signed in to change notification settings - Fork 0
/
RBCascadeNode.class.st
216 lines (181 loc) · 5.34 KB
/
RBCascadeNode.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
"
RBCascadeNode is an AST node for cascaded messages (e.g., ""self print1 ; print2"").
Instance Variables:
messages <SequenceableCollection of: RBMessageNode> the messages
semicolons <SequenceableCollection of: Integer> positions of the ; between messages
"
Class {
#name : #RBCascadeNode,
#superclass : #RBValueNode,
#instVars : [
'messages',
'semicolons'
],
#category : #'AST-Core-Nodes'
}
{ #category : #'instance creation' }
RBCascadeNode class >> messages: messageNodes [
^self new messages: messageNodes
]
{ #category : #'instance creation' }
RBCascadeNode class >> messages: messageNodes semicolons: integerCollection [
^self new messages: messageNodes semicolons: integerCollection
]
{ #category : #comparing }
RBCascadeNode >> = anObject [
self == anObject ifTrue: [^true].
self class = anObject class ifFalse: [^false].
self messages size = anObject messages size ifFalse: [^false].
self messages with: anObject messages do: [:first :second | first = second ifFalse: [^false]].
^true
]
{ #category : #visiting }
RBCascadeNode >> acceptVisitor: aProgramNodeVisitor [
^ aProgramNodeVisitor visitCascadeNode: self
]
{ #category : #querying }
RBCascadeNode >> bestNodeFor: anInterval [
| selectedChildren |
(self intersectsInterval: anInterval) ifFalse: [^nil].
(self containedBy: anInterval) ifTrue: [^self].
messages
reverseDo: [:each | (each containedBy: anInterval) ifTrue: [^each]].
selectedChildren := (messages
collect: [:each | each bestNodeFor: anInterval])
reject: [:each | each isNil].
^selectedChildren detect: [:each | true] ifNone: [nil]
]
{ #category : #accessing }
RBCascadeNode >> children [
^self messages
]
{ #category : #matching }
RBCascadeNode >> copyInContext: aDictionary [
^ self class new
messages: (self copyList: self messages inContext: aDictionary);
yourself
]
{ #category : #testing }
RBCascadeNode >> directlyUses: aNode [
^messages last = aNode and: [self isDirectlyUsed]
]
{ #category : #comparing }
RBCascadeNode >> equalTo: anObject withMapping: aDictionary [
self class = anObject class ifFalse: [^false].
self messages size = anObject messages size ifFalse: [^false].
self messages
with: anObject messages
do: [:first :second | (first equalTo: second withMapping: aDictionary) ifFalse: [^false]].
^true
]
{ #category : #comparing }
RBCascadeNode >> hash [
^ self hashForCollection: self messages
]
{ #category : #testing }
RBCascadeNode >> isCascade [
^true
]
{ #category : #testing }
RBCascadeNode >> isFaulty [
^self messages anySatisfy: [:each | each isFaulty]
]
{ #category : #accessing }
RBCascadeNode >> leftmostChainReceiver [
^ self receiver isMessage
ifTrue: [ self receiver receiver ]
ifFalse: [ self receiver ]
]
{ #category : #matching }
RBCascadeNode >> match: aNode inContext: aDictionary [
aNode class = self class ifFalse: [^false].
^self
matchList: messages
against: aNode messages
inContext: aDictionary
]
{ #category : #accessing }
RBCascadeNode >> messages [
^messages
]
{ #category : #accessing }
RBCascadeNode >> messages: messageNodeCollection [
messages := messageNodeCollection.
messages do: [:each | each parent: self]
]
{ #category : #initialization }
RBCascadeNode >> messages: messageNodes semicolons: integerCollection [
self messages: messageNodes.
semicolons := integerCollection
]
{ #category : #testing }
RBCascadeNode >> needsParenthesis [
^parent
ifNil: [false]
ifNotNil: [self precedence > parent precedence]
]
{ #category : #copying }
RBCascadeNode >> postCopy [
super postCopy.
self messages: (self messages collect: [ :each | each copy ])
]
{ #category : #accessing }
RBCascadeNode >> precedence [
^4
]
{ #category : #accessing }
RBCascadeNode >> receiver [
^self messages first receiver
]
{ #category : #'adding/removing' }
RBCascadeNode >> removeNode: aNode [
self messages remove: aNode ifAbsent: [ ]
]
{ #category : #replacing }
RBCascadeNode >> replaceNode: aNode withNode: anotherNode [
self messages: (messages
collect: [:each | each == aNode ifTrue: [anotherNode] ifFalse: [each]])
]
{ #category : #'accessing-token' }
RBCascadeNode >> semicolons [
^ semicolons
]
{ #category : #'accessing-token' }
RBCascadeNode >> semicolons: anArray [
semicolons := anArray
]
{ #category : #accessing }
RBCascadeNode >> startWithoutParentheses [
^messages first start
]
{ #category : #accessing }
RBCascadeNode >> statementComments [
| statementComments |
statementComments := OrderedCollection withAll: self comments.
statementComments addAll: messages first receiver statementComments.
messages do:
[:each |
each arguments
do: [:arg | statementComments addAll: arg statementComments]].
^statementComments asSortedCollection: [:a :b | a start < b start]
]
{ #category : #accessing }
RBCascadeNode >> stopWithoutParentheses [
^messages last stop
]
{ #category : #testing }
RBCascadeNode >> uses: aNode [
^messages last = aNode and: [self isUsed]
]
{ #category : #querying }
RBCascadeNode >> whichNodeIsContainedBy: anInterval [
| selectedChildren |
(self intersectsInterval: anInterval) ifFalse: [^nil].
(self containedBy: anInterval) ifTrue: [^self].
messages
reverseDo: [:each | (each containedBy: anInterval) ifTrue: [^each]].
selectedChildren := (messages
collect: [:each | each whichNodeIsContainedBy: anInterval])
reject: [:each | each isNil].
^selectedChildren detect: [:each | true] ifNone: [nil]
]