-
Notifications
You must be signed in to change notification settings - Fork 1.7k
/
OakDocument.mm
1572 lines (1316 loc) · 49 KB
/
OakDocument.mm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#import "OakDocument Private.h"
#import "OakDocumentEditor.h"
#import "EncodingView.h"
#import "Printing.h"
#import "watch.h"
#import "merge.h"
#import "document.h" // kBookmarkIdentifier
#import <OakFoundation/OakFoundation.h>
#import <OakFoundation/NSString Additions.h>
#import <OakAppKit/OakAppKit.h>
#import <OakAppKit/OakEncodingPopUpButton.h>
#import <OakAppKit/OakSavePanel.h>
#import <OakAppKit/NSAlert Additions.h>
#import <BundlesManager/BundlesManager.h>
#import <authorization/constants.h>
#import <cf/run_loop.h>
#import <ns/ns.h>
#import <settings/settings.h>
#import <settings/volume.h>
#import <buffer/buffer.h>
#import <undo/undo.h>
#import <selection/types.h>
#import <text/newlines.h>
#import <text/utf8.h>
#import <io/entries.h>
#import <file/type.h>
#import <file/open.h>
#import <file/save.h>
#import <file/reader.h>
#import <encoding/encoding.h>
namespace document
{
// =========
// = Marks =
// =========
static struct mark_tracker_t
{
void move_to_buffer (std::string const& path, ng::buffer_t& buf)
{
for(auto const& type : marks_for(path))
{
for(auto const& pos : type.second)
buf.set_mark(cap(buf, pos.first).index, type.first, pos.second);
}
_paths.erase(path);
}
void copy_from_buffer (std::string const& path, ng::buffer_t const& buf)
{
std::map<std::string, std::map<text::pos_t, std::string>> marks;
for(auto const& pair : buf.get_marks(0, buf.size()))
marks[pair.second.first].emplace(buf.convert(pair.first), pair.second.second);
_paths[path] = marks;
}
void add (std::string const& path, text::pos_t const& pos, std::string const& mark, std::string const& value)
{
marks_for(path)[mark].emplace(pos, value);
}
std::map<text::pos_t, std::string> const& get (std::string const& path, std::string const& mark)
{
return marks_for(path)[mark];
}
void remove (std::string const& path, text::pos_t const& pos, std::string const& mark)
{
marks_for(path)[mark].erase(pos);
}
void remove_all (std::string const& path, std::string const& mark)
{
auto marks = _paths.find(path);
if(marks != _paths.end())
remove_all(marks->second, mark);
}
void remove_all (std::string const& mark)
{
for(auto& marks : _paths)
remove_all(marks.second, mark);
}
private:
void remove_all (std::map<std::string, std::map<text::pos_t, std::string>>& marks, std::string const& mark)
{
if(mark == NULL_STR)
marks.clear();
else if(!mark.empty() && mark.back() == '/')
oak::erase_descendent_keys(marks, mark);
else
marks.erase(mark);
}
std::map<std::string, std::map<text::pos_t, std::string>>& marks_for (std::string const& path)
{
auto marks = _paths.find(path);
if(marks == _paths.end())
marks = _paths.emplace(path, std::map<std::string, std::map<text::pos_t, std::string>>{ { kBookmarkIdentifier, load_bookmarks(path) } }).first;
return marks->second;
}
static ng::index_t cap (ng::buffer_t const& buf, text::pos_t const& pos)
{
size_t line = oak::cap<size_t>(0, pos.line, buf.lines()-1);
size_t col = oak::cap<size_t>(0, pos.column, buf.eol(line) - buf.begin(line));
ng::index_t res = buf.sanitize_index(buf.convert(text::pos_t(line, col)));
if(pos.offset && res.index < buf.size() && buf[res.index] == "\n")
res.carry = pos.offset;
return res;
}
static std::map<text::pos_t, std::string> load_bookmarks (std::string const& path)
{
std::map<text::pos_t, std::string> res;
std::string const str = path::get_attr(path, "com.macromates.bookmarks");
if(str == NULL_STR)
return res;
plist::any_t const& plist = plist::parse(str);
if(plist::array_t const* array = boost::get<plist::array_t>(&plist))
{
for(auto const& bm : *array)
{
if(std::string const* str = boost::get<std::string>(&bm))
res.emplace(*str, std::string());
}
}
return res;
}
// path → mark type → position → mark
std::map<std::string, std::map<std::string, std::map<text::pos_t, std::string>>> _paths;
} marks;
} /* document */
// ==============================
// = OakDocument Implementation =
// ==============================
NSString* OakDocumentContentDidChangeNotification = @"OakDocumentContentDidChangeNotification";
NSString* OakDocumentMarksDidChangeNotification = @"OakDocumentMarksDidChangeNotification";
NSString* OakDocumentWillReloadNotification = @"OakDocumentWillReloadNotification";
NSString* OakDocumentDidReloadNotification = @"OakDocumentDidReloadNotification";
NSString* OakDocumentWillSaveNotification = @"OakDocumentWillSaveNotification";
NSString* OakDocumentDidSaveNotification = @"OakDocumentDidSaveNotification";
NSString* OakDocumentWillCloseNotification = @"OakDocumentWillCloseNotification";
NSString* OakDocumentWillShowAlertNotification = @"OakDocumentWillShowAlertNotification";
@interface OakDocument ()
{
OBJC_WATCH_LEAKS(OakDocument);
NSHashTable* _documentEditors;
std::unique_ptr<ng::buffer_t> _buffer;
std::unique_ptr<ng::detail::storage_t> _snapshot;
ng::callback_t* _callback;
std::unique_ptr<ng::undo_manager_t> _undoManager;
std::unique_ptr<document::watch_base_t> _fileSystemObserver;
NSTimer* _backupTimer;
}
@property (nonatomic) NSUInteger untitledCount;
@property (nonatomic) NSUInteger openCount;
@property (nonatomic, getter = isBufferEmpty) BOOL bufferEmpty;
@property (nonatomic) NSInteger backupRevision;
@property (nonatomic) BOOL observeFileSystem;
@property (nonatomic) BOOL needsImportDocumentChanges;
@property (nonatomic, readonly) BOOL shouldSniffFileType;
@property (nonatomic) NSArray<void(^)(OakDocumentIOResult, NSString*, oak::uuid_t const&)>* loadCompletionHandlers;
// These are also exposed in ‘OakDocument Private.h’
@property (nonatomic) NSInteger revision;
@property (nonatomic) NSInteger savedRevision;
@property (nonatomic) NSString* backupPath;
@property (nonatomic) NSString* folded;
@end
static struct document_container_t
{
void add (OakDocument* document)
{
std::lock_guard<std::mutex> lock(_lock);
[_documents addObject:document];
}
void set_untitled_count (OakDocument* document)
{
std::lock_guard<std::mutex> lock(_lock);
std::set<NSUInteger> reserved;
for(OakDocument* document in _documents)
{
if(!document.path && !document.customName)
reserved.insert(document.untitledCount);
}
NSUInteger available = 1;
while(reserved.find(available) != reserved.end())
++available;
document.untitledCount = available;
}
void remove_all_marks (NSString* mark)
{
std::lock_guard<std::mutex> lock(_lock);
for(OakDocument* document : _documents)
[document removeAllMarksOfType:mark];
}
private:
std::mutex _lock;
NSHashTable* _documents = [NSHashTable weakObjectsHashTable];
} DocumentContainer;
@implementation OakDocument
+ (NSSet*)keyPathsForValuesAffectingDisplayName
{
return [NSSet setWithObjects:@"path", @"customName", @"untitledCount", nil];
}
+ (NSSet*)keyPathsForValuesAffectingOpen
{
return [NSSet setWithObjects:@"openCount", nil];
}
+ (NSSet*)keyPathsForValuesAffectingDocumentEdited
{
return [NSSet setWithObjects:@"onDisk", @"revision", @"savedRevision", @"bufferEmpty", nil];
}
- (NSString*)description
{
return [NSString stringWithFormat:@"<%@: %@>", [self class], self.displayName];
}
// ==================
// = Helper Methods =
// ==================
- (void)setBufferGrammarForCurrentFileType
{
if(!_fileType || !_buffer)
return;
for(auto const& item : bundles::query(bundles::kFieldGrammarScope, to_s(_fileType), scope::wildcard, bundles::kItemTypeGrammar))
{
_buffer->set_grammar(item);
break;
}
}
- (void)snapshot
{
ASSERT(_buffer);
_snapshot = std::make_unique<ng::detail::storage_t>(_buffer->storage());
}
- (std::map<std::string, std::string>)variables
{
std::map<std::string, std::string> variables = {
{ "TM_DISPLAYNAME", to_s(self.displayName) },
{ "TM_DOCUMENT_UUID", to_s(self.identifier.UUIDString) },
};
if(_path)
{
variables["TM_FILEPATH"] = to_s(_path);
variables["TM_FILENAME"] = path::name(to_s(_path));
variables["TM_DIRECTORY"] = path::parent(to_s(_path));
}
return variables;
}
- (void)updateSpellingSettings:(BOOL)updateSpelling andIndentSettings:(BOOL)updateIndent
{
if(!_buffer)
return;
settings_t const settings = settings_for_path(to_s(_virtualPath ?: _path), to_s(_fileType), to_s(_directory ?: [_path stringByDeletingLastPathComponent]), self.variables);
if(updateSpelling)
{
self.spellingLanguage = to_ns(settings.get(kSettingsSpellingLanguageKey, ""));
self.continuousSpellCheckingEnabled = settings.get(kSettingsSpellCheckingKey, false);
}
if(updateIndent)
{
self.tabSize = std::max(1, settings.get(kSettingsTabSizeKey, 4));
self.softTabs = settings.get(kSettingsSoftTabsKey, false);
}
}
// ==================
- (instancetype)init
{
if(self = [super init])
{
_identifier = [NSUUID UUID];
_documentEditors = [NSHashTable weakObjectsHashTable];
DocumentContainer.add(self);
}
return self;
}
- (instancetype)initWithPath:(NSString*)aPath
{
if(self = [self init])
{
_path = aPath;
_onDisk = access([_path fileSystemRepresentation], F_OK) == 0;
}
return self;
}
- (instancetype)initWithData:(NSData*)someData fileType:(NSString*)aFileType customName:(NSString*)aName
{
if(self = [self init])
{
self.customName = aName;
self.fileType = aFileType;
[self createBuffer];
if([someData respondsToSelector:@selector(enumerateByteRangesUsingBlock:)]) // MAC_OS_X_VERSION_10_9
{
[someData enumerateByteRangesUsingBlock:^(void const* buf, NSRange range, BOOL*){
_buffer->insert(range.location, (char const*)buf, range.length);
}];
}
else
{
_buffer->insert(0, (char const*)[someData bytes], [someData length]);
}
}
return self;
}
- (instancetype)initWithIdentifier:(NSUUID*)anIdentifier
{
std::string const dir = to_s([[NSSearchPathForDirectoriesInDomains(NSApplicationSupportDirectory, NSUserDomainMask, YES) firstObject] stringByAppendingPathComponent:@"TextMate/Session"]);
for(auto dirEntry : path::entries(dir))
{
std::string const path = path::join(dir, dirEntry->d_name);
std::string const uuid = path::get_attr(path, "com.macromates.backup.identifier");
if(uuid == NULL_STR || ![anIdentifier isEqual:[[NSUUID alloc] initWithUUIDString:to_ns(uuid)]])
continue;
if(self = [self init])
{
_identifier = anIdentifier;
_backupPath = to_ns(path);
_path = to_ns(path::resolve(path::get_attr(path, "com.macromates.backup.path")));
_onDisk = access([_path fileSystemRepresentation], F_OK) == 0;
_fileType = to_ns(path::get_attr(path, "com.macromates.backup.file-type"));
_diskEncoding = to_ns(path::get_attr(path, "com.macromates.backup.encoding"));
_diskNewlines = to_ns(path::get_attr(path, "com.macromates.backup.newlines"));
_customName = to_ns(path::get_attr(path, "com.macromates.backup.custom-name"));
_untitledCount = atoi(path::get_attr(path, "com.macromates.backup.untitled-count").c_str());
if(path::get_attr(path, "com.macromates.backup.modified") == "YES")
_savedRevision = _revision-1;
return self;
}
}
return nil;
}
+ (instancetype)documentWithPath:(NSString*)aPath
{
return [[OakDocument alloc] initWithPath:aPath];
}
+ (instancetype)documentWithData:(NSData*)someData fileType:(NSString*)aFileType customName:(NSString*)aName
{
return [[OakDocument alloc] initWithData:someData fileType:aFileType customName:aName];
}
+ (instancetype)documentWithIdentifier:(NSUUID*)anIdentifier
{
return [[OakDocument alloc] initWithIdentifier:anIdentifier];
}
- (void)dealloc
{
[self removeBackup];
}
- (NSString*)sniffFileType
{
io::bytes_ptr firstLine = _buffer ? std::make_shared<io::bytes_t>(_buffer->substr(_buffer->begin(0), std::min<size_t>(_buffer->eol(0), 2048))) : io::bytes_ptr();
return to_ns(file::type(to_s(_path), firstLine, to_s(_virtualPath)));
}
- (NSString*)displayName
{
if(_customName)
return _customName;
if(_path)
return [[NSFileManager defaultManager] displayNameAtPath:_path];
if(self.untitledCount == 0)
DocumentContainer.set_untitled_count(self);
return _untitledCount == 1 ? @"untitled" : [NSString stringWithFormat:@"untitled %lu", _untitledCount];
}
- (NSString*)displayNameWithExtension:(BOOL)flag
{
NSString* res = [self.displayName stringByReplacingOccurrencesOfString:@"/" withString:@":"];
if(!flag)
return res;
if(_customName && OakNotEmptyString([res pathExtension]))
return res;
if(_path)
return [_path lastPathComponent];
if(_buffer && _buffer->grammar())
{
if(bundles::item_ptr item = bundles::lookup(_buffer->grammar()->uuid()))
{
if(NSString* ext = to_ns(item->value_for_field(bundles::kFieldGrammarExtension)))
return [res stringByAppendingPathExtension:ext];
}
}
else if(_fileType)
{
for(auto const& item : bundles::query(bundles::kFieldGrammarScope, to_s(_fileType)))
{
if(NSString* ext = to_ns(item->value_for_field(bundles::kFieldGrammarExtension)))
return [res stringByAppendingPathExtension:ext];
}
}
return res;
}
- (void)setPath:(NSString*)newPath
{
NSString* path = to_ns(path::resolve(to_s(newPath)));
if([_path isEqualToString:path])
return;
_path = path;
self.customName = nil;
if(_observeFileSystem)
{
self.observeFileSystem = NO;
self.observeFileSystem = YES;
}
if(self.isOpen)
{
self.onDisk = access([_path fileSystemRepresentation], F_OK) == 0;
if(NSString* fileType = [self sniffFileType])
self.fileType = fileType;
}
}
- (void)setFileType:(NSString*)newType
{
if(_fileType == newType || [_fileType isEqual:newType])
return;
_fileType = newType;
if(self.isOpen)
{
[self setBufferGrammarForCurrentFileType];
[self updateSpellingSettings:YES andIndentSettings:YES];
}
}
- (std::map<std::string, std::string>)extendedAttributeds
{
for(OakDocumentEditor* editor in self.documentEditors)
[editor documentWillSave:self];
std::map<std::string, std::string> res = {
{ "com.macromates.bookmarks", to_s([self stringifyMarksOfType:to_ns(document::kBookmarkIdentifier)]) },
{ "com.macromates.selectionRange", to_s(_selection) },
{ "com.macromates.visibleIndex", _visibleIndex ? to_s(_visibleIndex) : NULL_STR },
{ "com.macromates.crc32", NULL_STR },
{ "com.macromates.folded", NULL_STR },
{ "com.macromates.visibleRect", NULL_STR }, // Clear legacy attribute
};
if(_buffer && OakNotEmptyString(_folded))
{
boost::crc_32_type crc32;
_buffer->visit_data([&crc32](char const* bytes, size_t offset, size_t len, bool*){
crc32.process_bytes(bytes, len);
});
res["com.macromates.crc32"] = text::format("%04x", crc32.checksum());
res["com.macromates.folded"] = to_s(_folded);
}
return res;
}
// ==========
// = Backup =
// ==========
- (void)scheduleBackup
{
if(_keepBackupFile)
{
[_backupTimer invalidate];
_backupTimer = [NSTimer scheduledTimerWithTimeInterval:2 target:self selector:@selector(backupTimerDidFire:) userInfo:nil repeats:NO];
}
}
- (void)backupTimerDidFire:(NSTimer*)aTimer
{
_backupTimer = nil;
[self saveBackup:self];
}
- (void)removeBackup
{
if(_backupPath)
{
[[NSFileManager defaultManager] removeItemAtPath:_backupPath error:nullptr];
self.backupPath = nil;
}
}
- (NSString*)createAndReturnBackupPath
{
NSString* path = [[NSSearchPathForDirectoriesInDomains(NSApplicationSupportDirectory, NSUserDomainMask, YES) firstObject] stringByAppendingPathComponent:@"TextMate/Session"];
if(![[NSFileManager defaultManager] createDirectoryAtPath:path withIntermediateDirectories:YES attributes:nil error:nullptr])
return nil;
path = [path stringByAppendingPathComponent:[self displayNameWithExtension:YES]];
return to_ns(path::unique(to_s(path)));
}
- (BOOL)saveBackup:(id)sender
{
if(_buffer && (_onDisk ? _savedRevision != _revision : !_bufferEmpty))
{
if(_backupPath && _backupRevision == _revision)
return NO;
if(!_backupPath)
self.backupPath = [self createAndReturnBackupPath];
std::string const temp = path::temp("backup");
int fd = open(temp.c_str(), O_CREAT|O_TRUNC|O_WRONLY|O_CLOEXEC, S_IRUSR|S_IWUSR|S_IRGRP|S_IWGRP|S_IROTH);
if(fd == -1)
{
perrorf("saveBackup: open(\"%s\")", temp.c_str());
return NO;
}
bool error = _buffer->visit_data([fd](char const* bytes, size_t offset, size_t len, bool* stop){
if(*stop = write(fd, bytes, len) != len)
perrorf("saveBackup: write");
});
close(fd);
if(error)
return unlink(temp.c_str()), NO;
auto attr = [self extendedAttributeds];
attr["com.macromates.backup.path"] = to_s(_path);
attr["com.macromates.backup.identifier"] = to_s(_identifier.UUIDString);
attr["com.macromates.backup.file-type"] = to_s(_fileType);
attr["com.macromates.backup.encoding"] = to_s(_diskEncoding);
attr["com.macromates.backup.newlines"] = to_s(_diskNewlines);
attr["com.macromates.backup.untitled-count"] = _path || _customName ? NULL_STR : std::to_string(_untitledCount);
attr["com.macromates.backup.custom-name"] = to_s(_customName);
attr["com.macromates.backup.modified"] = self.isDocumentEdited ? "YES" : NULL_STR;
attr["com.macromates.backup.tab-size"] = std::to_string(self.tabSize);
attr["com.macromates.backup.soft-tabs"] = self.softTabs ? "YES" : NULL_STR;
path::set_attributes(temp, attr);
if(!path::rename_or_copy(temp, to_s(self.backupPath)))
return NO;
self.backupRevision = _revision;
return YES;
}
else if(_backupPath)
{
[self removeBackup];
}
return NO;
}
// =================
// = Load Document =
// =================
- (void)updateRecentDocumentMenu
{
if(_recentTrackingDisabled || !_path || _virtualPath)
return;
NSURL* url = [NSURL fileURLWithPath:_path];
CFRunLoopPerformBlock(CFRunLoopGetMain(), kCFRunLoopCommonModes, ^{
// This is not thread-safe so we ensure that we are on the main thread
[[NSDocumentController sharedDocumentController] noteNewRecentDocumentURL:url];
});
}
- (BOOL)isLoading
{
return _loadCompletionHandlers != nil;
}
- (void)loadModalForWindow:(NSWindow*)aWindow completionHandler:(void(^)(OakDocumentIOResult result, NSString* errorMessage, oak::uuid_t const& filterUUID))block
{
block = block ?: ^(OakDocumentIOResult, NSString*, oak::uuid_t const&){ };
if(++self.openCount != 1)
{
if(!_loadCompletionHandlers)
block(OakDocumentIOResultSuccess, nil, oak::uuid_t());
else _loadCompletionHandlers = [_loadCompletionHandlers arrayByAddingObject:block];
return;
}
if(_backupPath)
{
ASSERT(!_buffer);
BOOL isModified = self.isDocumentEdited;
std::string const path = to_s(_backupPath);
[self didLoadContent:std::make_shared<io::bytes_t>(path::content(path)) attributes:path::attributes(path) encoding:encoding::type(to_s(_diskNewlines), to_s(_diskEncoding))];
if(isModified)
{
_snapshot.reset();
self.savedRevision = _revision-1;
}
return block(OakDocumentIOResultSuccess, nil, oak::uuid_t());
}
struct callback_t : file::open_callback_t
{
callback_t (OakDocument* self, NSWindow* window, void(^block)(OakDocumentIOResult result, NSString* errorMessage, oak::uuid_t const& filterUUID)) : _self(self), _window(window), _block(block) { }
void select_charset (std::string const& path, io::bytes_ptr content, file::open_context_ptr context)
{
[_window.attachedSheet orderOut:_self];
EncodingWindowController* controller = [[EncodingWindowController alloc] initWithFirst:content->begin() last:content->end()];
controller.displayName = _self.displayName;
__block encoding::classifier_t db;
static std::string const kEncodingFrequenciesPath = path::join(path::home(), "Library/Caches/com.macromates.TextMate/EncodingFrequencies.binary");
db.load(kEncodingFrequenciesPath);
std::multimap<double, std::string> probabilities;
for(auto const& charset : db.charsets())
probabilities.emplace(1 - db.probability(content->begin(), content->end(), charset), charset);
if(!probabilities.empty() && probabilities.begin()->first < 1)
controller.encoding = [NSString stringWithCxxString:probabilities.begin()->second];
[[NSNotificationCenter defaultCenter] postNotificationName:OakDocumentWillShowAlertNotification object:_self];
[controller beginSheetModalForWindow:_window completionHandler:^(NSModalResponse response){
if(response != NSModalResponseAbort)
{
context->set_charset(to_s(controller.encoding));
if(controller.trainClassifier)
{
db.learn(content->begin(), content->end(), to_s(controller.encoding));
db.save(kEncodingFrequenciesPath);
}
}
}];
}
void show_error (std::string const& path, std::string const& message, oak::uuid_t const& filter)
{
[_self didLoadContent:io::bytes_ptr() attributes:{ } encoding:{ }];
_block(OakDocumentIOResultFailure, to_ns(message), filter);
}
void show_content (std::string const& path, io::bytes_ptr content, std::map<std::string, std::string> const& attributes, encoding::type const& encoding, std::vector<oak::uuid_t> const& binaryImportFilters, std::vector<oak::uuid_t> const& textImportFilters)
{
NSString* docPath = _self.virtualPath ?: _self.path;
// Check if user has an explicit binding for this path (e.g. *.md → Markdown)
if(!_self.fileType && docPath)
_self.fileType = to_ns(settings_for_path(to_s(docPath), scope::scope_t(), to_s(_self.directory ?: [_self.path stringByDeletingLastPathComponent])).get(kSettingsFileTypeKey, NULL_STR));
// Check if a grammar recognizes the content (e.g. #!/usr/bin/ruby → Ruby)
if(!_self.fileType)
_self.fileType = to_ns(file::type_from_bytes(content));
// Check if a grammar recognizes the path extension (.git/config → Git Config)
if(!_self.fileType && docPath)
_self.fileType = to_ns(file::type_from_path(to_s(docPath)));
[_self didLoadContent:content attributes:attributes encoding:encoding];
_block(OakDocumentIOResultSuccess, nil, oak::uuid_t());
}
private:
OakDocument* _self;
NSWindow* _window;
void(^_block)(OakDocumentIOResult result, NSString* errorMessage, oak::uuid_t const& filterUUID);
};
io::bytes_ptr content;
if(_buffer)
{
content = std::make_shared<io::bytes_t>(_buffer->size());
_buffer->visit_data([&](char const* bytes, size_t offset, size_t len, bool*){
memcpy(content->get() + offset, bytes, len);
});
[self deleteBuffer];
}
self.loadCompletionHandlers = @[ block ];
auto cb = std::make_shared<callback_t>(self, aWindow, ^(OakDocumentIOResult result, NSString* errorMessage, oak::uuid_t const& filterUUID){
auto blocks = self.loadCompletionHandlers;
self.loadCompletionHandlers = nil;
for(void(^f)(OakDocumentIOResult, NSString*, oak::uuid_t const&) in blocks)
f(result, errorMessage, filterUUID);
});
file::open(to_s(_path), _authorization, cb, content);
}
- (void)didLoadContent:(io::bytes_ptr)content attributes:(std::map<std::string, std::string> const&)attributes encoding:(encoding::type)encoding
{
if(!content) // Loading failed
{
--self.openCount;
return;
}
[self createBuffer];
_buffer->insert(0, content->get(), content->size());
if(_path)
document::marks.move_to_buffer(to_s(_path), *_buffer);
auto folded = attributes.find("com.macromates.folded");
if(folded != attributes.end())
{
auto crc32 = attributes.find("com.macromates.crc32");
if(crc32 != attributes.end() && crc32->second == text::format("%04x", content->crc32()))
_folded = to_ns(folded->second);
}
if(!_selection)
{
auto sel = attributes.find("com.macromates.selectionRange");
_selection = sel != attributes.end() ? to_ns(sel->second) : nil;
auto idx = attributes.find("com.macromates.visibleIndex");
if(idx != attributes.end())
{
size_t index = SIZE_T_MAX, carry = 0;
sscanf(idx->second.c_str(), "%zu:%zu", &index, &carry);
_visibleIndex = ng::index_t(_buffer->sanitize_index(index), carry);
}
}
[self setBufferGrammarForCurrentFileType];
[self updateSpellingSettings:YES andIndentSettings:YES];
_undoManager = std::make_unique<ng::undo_manager_t>(*_buffer);
_buffer->set_async_parsing(true);
_buffer->bump_revision();
self.onDisk = _path && access([_path fileSystemRepresentation], F_OK) == 0;
self.savedRevision = _buffer->revision();
self.backupRevision = _buffer->revision(); // This is ignored when backupPath is nil
self.revision = _buffer->revision();
self.diskEncoding = to_ns(encoding.charset());
self.diskNewlines = to_ns(encoding.newlines());
[self snapshot];
[self updateRecentDocumentMenu];
self.observeFileSystem = YES;
}
// =================
// = Save Document =
// =================
- (void)didSaveAtPath:(NSString*)aPath withEncoding:(encoding::type)encoding success:(BOOL)success
{
if(success)
{
self.onDisk = YES;
self.diskEncoding = to_ns(encoding.charset());
self.diskNewlines = to_ns(encoding.newlines());
self.savedRevision = _revision;
[self snapshot];
[self removeBackup];
[self updateRecentDocumentMenu];
[[NSNotificationCenter defaultCenter] postNotificationName:OakDocumentDidSaveNotification object:self];
}
self.observeFileSystem = self.isOpen;
}
- (void)saveModalForWindow:(NSWindow*)aWindow completionHandler:(void(^)(OakDocumentIOResult result, NSString* errorMessage, oak::uuid_t const& filterUUID))block
{
if(!self.isOpen && self.isDocumentEdited && _backupPath)
{
[self loadModalForWindow:aWindow completionHandler:^(OakDocumentIOResult result, NSString* errorMessage, oak::uuid_t const& filterUUID){
if(result == OakDocumentIOResultSuccess)
{
[self saveModalForWindow:aWindow completionHandler:^(OakDocumentIOResult result, NSString* errorMessage, oak::uuid_t const& filterUUID){
block(result, errorMessage, filterUUID);
[self close];
}];
}
else
{
NSString* errorMessage = [NSString stringWithFormat:@"Cannot save ‘%@’: Failed to restore backup ‘%@’.", self.displayName, [_backupPath stringByAbbreviatingWithTildeInPath]];
block(OakDocumentIOResultFailure, errorMessage, oak::uuid_t());
}
}];
return;
}
if(_buffer)
{
self.observeFileSystem = NO;
std::map<std::string, std::string> attributes;
if(volume::settings(to_s(_path)).extended_attributes())
attributes = [self extendedAttributeds];
encoding::type encoding = encoding::type(to_s(_diskNewlines), to_s(_diskEncoding));
settings_t const settings = settings_for_path(to_s(_path), to_s(_fileType), to_s(_directory ?: [_path stringByDeletingLastPathComponent]));
if(encoding.charset() == kCharsetNoEncoding)
encoding.set_charset(settings.get(kSettingsEncodingKey, kCharsetUTF8));
if(encoding.newlines() == NULL_STR)
encoding.set_newlines(settings.get(kSettingsLineEndingsKey, kLF));
struct callback_t : file::save_callback_t
{
callback_t (OakDocument* document, NSWindow* window, void(^block)(OakDocumentIOResult result, NSString* path, encoding::type const& encoding, NSString* errorMessage, oak::uuid_t const& filterUUID)) : _document(document), _window(window), _block(block)
{
}
void select_path (std::string const& path, io::bytes_ptr content, file::save_context_ptr context)
{
if(!_window)
return;
[OakSavePanel showWithPath:[_document displayNameWithExtension:YES] directory:_document.directory fowWindow:_window encoding:encoding::type(to_s(_document.diskNewlines), to_s(_document.diskEncoding)) completionHandler:^(NSString* path, encoding::type const& encoding){
if(path)
{
_document.path = path;
_document.diskEncoding = to_ns(encoding.charset());
_document.diskNewlines = to_ns(encoding.newlines());
context->set_path(to_s(path));
}
else
{
_cancel = true;
}
}];
}
void select_make_writable (std::string const& path, io::bytes_ptr content, file::save_context_ptr context)
{
if(!_window)
return;
[[NSNotificationCenter defaultCenter] postNotificationName:OakDocumentWillShowAlertNotification object:_document];
NSAlert* alert = [NSAlert tmAlertWithMessageText:[NSString stringWithFormat:@"The file “%@” is locked.", _document.displayName] informativeText:@"Do you want to overwrite it anyway?" buttons:@"Overwrite", @"Cancel", nil];
OakShowAlertForWindow(alert, _window, ^(NSInteger returnCode){
if(returnCode == NSAlertFirstButtonReturn)
context->set_make_writable(true);
else _cancel = true;
});
}
void select_create_parent (std::string const& path, io::bytes_ptr content, file::save_context_ptr context)
{
if(!_window)
return;
[[NSNotificationCenter defaultCenter] postNotificationName:OakDocumentWillShowAlertNotification object:_document];
NSAlert* alert = [NSAlert tmAlertWithMessageText:[NSString stringWithFormat:@"No parent folder for “%@”.", _document.displayName] informativeText:[NSString stringWithFormat:@"Do you wish to create a folder at “%@”?", [NSString stringWithCxxString:path::with_tilde(path::parent(path))]] buttons:@"Create Folder", @"Cancel", nil];
OakShowAlertForWindow(alert, _window, ^(NSInteger returnCode){
if(returnCode == NSAlertFirstButtonReturn)
context->set_create_parent(true);
else _cancel = true;
});
}
void obtain_authorization (std::string const& path, io::bytes_ptr content, osx::authorization_t auth, file::save_context_ptr context)
{
if(!_window)
return;
if(auth.obtain_right(kAuthRightName))
context->set_authorization(auth);
else _cancel = true;
}
void select_charset (std::string const& path, io::bytes_ptr content, std::string const& charset, file::save_context_ptr context)
{
if(charset != kCharsetNoEncoding)
{
if(!_window)
return;
[[NSNotificationCenter defaultCenter] postNotificationName:OakDocumentWillShowAlertNotification object:_document];
NSAlert* alert = [NSAlert tmAlertWithMessageText:[NSString stringWithFormat:@"Unable to save “%@” using “%@” as encoding.", _document.displayName, to_ns(charset)] informativeText:@"Please choose another encoding:" buttons:@"Save", @"Cancel", nil];
OakEncodingPopUpButton* encodingPopUp = [OakEncodingPopUpButton new];
[alert setAccessoryView:encodingPopUp];
OakShowAlertForWindow(alert, _window, ^(NSInteger returnCode){
if(returnCode == NSAlertFirstButtonReturn)
context->set_charset(to_s(encodingPopUp.encoding));
else _cancel = true;
});
[[alert window] recalculateKeyViewLoop];
}
else
{
context->set_charset(kCharsetUTF8);
}
}
void did_save (std::string const& path, io::bytes_ptr content, encoding::type const& encoding, bool success, std::string const& message, oak::uuid_t const& filter)
{
_block(success ? OakDocumentIOResultSuccess : (_cancel ? OakDocumentIOResultCancel : OakDocumentIOResultFailure), to_ns(path), encoding, to_ns(message), filter);
}
private:
OakDocument* _document;
NSWindow* _window;
bool _cancel = false;
void(^_block)(OakDocumentIOResult result, NSString* path, encoding::type const& encoding, NSString* errorMessage, oak::uuid_t const& filterUUID);
};
BOOL closeDocument = self.isOpen;
if(closeDocument)
++self.openCount;
auto cb = std::make_shared<callback_t>(self, aWindow, ^(OakDocumentIOResult result, NSString* path, encoding::type const& encoding, NSString* errorMessage, oak::uuid_t const& filterUUID){
if(closeDocument)
[self didSaveAtPath:path withEncoding:encoding success:result == OakDocumentIOResultSuccess];
if(block)
block(result, errorMessage, filterUUID);
if(closeDocument)
[self close];
});
[[NSNotificationCenter defaultCenter] postNotificationName:OakDocumentWillSaveNotification object:self];
io::bytes_ptr content = std::make_shared<io::bytes_t>(_buffer->size());
_buffer->visit_data([&](char const* bytes, size_t offset, size_t len, bool*){
memcpy(content->get() + offset, bytes, len);
});
file::save(to_s(_path), cb, _authorization, content, attributes, encoding, std::vector<oak::uuid_t>() /* binary import filters */, std::vector<oak::uuid_t>() /* text import filters */);
}
else
{
NSString* errorMessage = [NSString stringWithFormat:@"Cannot save ‘%@’: no content. Has backup %s, is edited %s.", self.displayName, BSTR(_backupPath), BSTR(self.isDocumentEdited)];
block(OakDocumentIOResultFailure, errorMessage, oak::uuid_t());
}
}
// =================
- (void)close
{
if(--self.openCount != 0)
return;
[[NSNotificationCenter defaultCenter] postNotificationName:OakDocumentWillCloseNotification object:self];