forked from Kitware/VTK
/
FindLibHaru.cmake
69 lines (63 loc) · 2.77 KB
/
FindLibHaru.cmake
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
find_path(LibHaru_INCLUDE_DIR
NAMES hpdf.h
DOC "libharu include directory")
mark_as_advanced(LibHaru_INCLUDE_DIR)
find_library(LibHaru_LIBRARY_RELEASE
NAMES hpdf hpdfs libhpdf libhpdfs
DOC "libharu release library")
mark_as_advanced(LibHaru_LIBRARY_RELEASE)
find_library(LibHaru_LIBRARY_DEBUG
NAMES hpdfd hpdfsd libhpdfd libhpdfsd
DOC "libharu debug library")
mark_as_advanced(LibHaru_LIBRARY_DEBUG)
if (LibHaru_INCLUDE_DIR)
file(STRINGS "${LibHaru_INCLUDE_DIR}/hpdf_version.h" _libharu_version_lines
REGEX "#define HPDF_(MAJOR|MINOR|BUGFIX|EXTRA)_VERSION")
string(REGEX REPLACE ".*HPDF_MAJOR_VERSION *\([0-9]*\).*" "\\1" _libharu_version_major "${_libharu_version_lines}")
string(REGEX REPLACE ".*HPDF_MINOR_VERSION *\([0-9]*\).*" "\\1" _libharu_version_minor "${_libharu_version_lines}")
string(REGEX REPLACE ".*HPDF_BUGFIX_VERSION *\([0-9]*\).*" "\\1" _libharu_version_bugfix "${_libharu_version_lines}")
string(REGEX REPLACE ".*HPDF_EXTRA_VERSION *\"\([^\"]*\)\".*" "\\1" _libharu_version_extra "${_libharu_version_lines}")
set(LibHaru_VERSION "${_libharu_version_major}.${_libharu_version_minor}.${_libharu_version_bugfix}")
if (_libharu_version_extra)
string(APPEND LibHaru_VERSION
"-${_libharu_version_extra}")
endif ()
unset(_libharu_version_major)
unset(_libharu_version_minor)
unset(_libharu_version_bugfix)
unset(_libharu_version_extra)
unset(_libharu_version_lines)
endif ()
include(SelectLibraryConfigurations)
select_library_configurations(LibHaru)
include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(LibHaru
REQUIRED_VARS LibHaru_LIBRARY LibHaru_INCLUDE_DIR
VERSION_VAR LibHaru_VERSION)
if (LibHaru_FOUND)
set(LibHaru_INCLUDE_DIRS "${LibHaru_INCLUDE_DIR}")
set(LibHaru_LIBRARIES "${LibHaru_LIBRARY}")
if (NOT TARGET LibHaru::LibHaru)
include(vtkDetectLibraryType)
vtk_detect_library_type(libharu_library_type
PATH "${LibHaru_LIBRARY}")
add_library(LibHaru::LibHaru "${libharu_library_type}" IMPORTED)
unset(libharu_library_type)
set_target_properties(LibHaru::LibHaru PROPERTIES
INTERFACE_INCLUDE_DIRECTORIES "${LibHaru_INCLUDE_DIR}")
if (LibHaru_LIBRARY_RELEASE)
set_property(TARGET LibHaru::LibHaru APPEND PROPERTY
IMPORTED_CONFIGURATIONS RELEASE)
set_target_properties(LibHaru::LibHaru PROPERTIES
IMPORTED_LOCATION_RELEASE "${LibHaru_LIBRARY_RELEASE}"
IMPORTED_IMPLIB_RELEASE "${LibHaru_LIBRARY_RELEASE}")
endif ()
if (LibHaru_LIBRARY_DEBUG)
set_property(TARGET LibHaru::LibHaru APPEND PROPERTY
IMPORTED_CONFIGURATIONS DEBUG)
set_target_properties(LibHaru::LibHaru PROPERTIES
IMPORTED_LOCATION_DEBUG "${LibHaru_LIBRARY_DEBUG}"
IMPORTED_IMPLIB_DEBUG "${LibHaru_LIBRARY_DEBUG}")
endif ()
endif ()
endif ()