forked from Kitware/VTK
-
Notifications
You must be signed in to change notification settings - Fork 0
/
CMakeLists.txt
85 lines (72 loc) · 3.02 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
# This project builds the test directories from all VTK modules as a separate
# project outside the main VTK build tree as if they were an application.
cmake_minimum_required(VERSION 3.3...3.12 FATAL_ERROR)
project(VTKTestExternal)
if(VTK_SOURCE_DIR OR VTK_BINARY_DIR)
message(FATAL_ERROR "This directory may build only outside VTK!")
endif()
include(CTest)
# Find the top of the main VTK source tree.
get_filename_component(VTK_TOP_DIR ${VTKTestExternal_SOURCE_DIR}/../.. ABSOLUTE)
set(ExternalData_SOURCE_ROOT ${VTK_TOP_DIR})
# Load module infrastructure macros.
list(APPEND CMAKE_MODULE_PATH ${VTK_TOP_DIR}/CMake)
include(vtkModuleMacros)
include(vtkExternalData)
include(vtkEncodeString)
include(vtkTestingMacros)
# Find the VTK build or install tree. Assume the version matches exactly.
# One should provide VTK_DIR explicitly in our intended use cases.
find_package(VTK REQUIRED NO_MODULE)
# Use VTK's flags.
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${VTK_REQUIRED_C_FLAGS}")
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${VTK_REQUIRED_CXX_FLAGS}")
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${VTK_REQUIRED_EXE_LINKER_FLAGS}")
set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${VTK_REQUIRED_SHARED_LINKER_FLAGS}")
set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} ${VTK_REQUIRED_MODULE_LINKER_FLAGS}")
# This is a cross-platform project so we cannot use the MS _s API.
if(WIN32 AND "x${CMAKE_C_COMPILER_ID}" STREQUAL "xIntel")
set(_INTEL_WINDOWS 1)
endif()
if(MSVC OR _INTEL_WINDOWS)
add_definitions(
-D_CRT_NONSTDC_NO_DEPRECATE
-D_CRT_SECURE_NO_DEPRECATE
-D_SCL_SECURE_NO_DEPRECATE
)
endif()
# Glob the set of modules in the source tree including test modules.
vtk_module_glob("${VTK_TOP_DIR}" "${VTKTestExternal_BINARY_DIR}" Cxx)
# Input information for test build files.
option(VTK_USE_LARGE_DATA "Enable tests requiring \"large\" data" OFF)
set(VTK_TEST_DATA_DIR "${ExternalData_BINARY_ROOT}/Testing")
set(VTK_TEST_INPUT_DIR "${VTK_TOP_DIR}/Testing/Data")
set(VTK_TEST_OUTPUT_DIR "${VTKTestExternal_BINARY_DIR}/Testing/Temporary")
include(vtkLegacyData)
# If vtkParallelMPI is found then look for MPI and bring in
# vtkTestingMPISupport.
if(vtkParallelMPI_LOADED)
find_package(MPI REQUIRED)
include(vtkTestingMPISupport)
endif()
# Add the test directory for each enabled module that has tests
# whose dependencies are also enabled.
foreach(mod ${VTK_MODULES_ALL})
if(${mod}_TESTS_FOR AND ${${mod}_TESTS_FOR}_LOADED)
set(missing "")
foreach(dep IN LISTS ${mod}_DEPENDS)
if(NOT ${dep}_LOADED)
set(missing "${missing} ${dep}\n")
endif()
endforeach()
if(NOT missing)
set(vtk-module ${${mod}_TESTS_FOR})
add_subdirectory(${${mod}_SOURCE_DIR} ${${mod}_BINARY_DIR})
else()
message(STATUS "Skipping ${mod} due to missing dependencies:\n${missing}")
endif()
endif()
endforeach()
# Create target to download data from the VTKData group. This must come after
# all tests have been added that reference the group, so we put it last.
ExternalData_Add_Target(VTKData)