/
modules.clj
290 lines (240 loc) · 9.12 KB
/
modules.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
(ns shadow.build.modules
(:refer-clojure :exclude (compile))
(:require [clojure.set :as set]
[shadow.cljs.util :as util]
[shadow.build.resolve :as res]
[shadow.build.compiler :as impl]
[shadow.build.resource :as rc]
[shadow.build.data :as data]
[clojure.java.io :as io]
[shadow.build.classpath :as cp]
[shadow.build.log :as cljs-log]))
(defn topo-sort-modules*
[{:keys [modules deps visited] :as state} module-id]
(let [{:keys [depends-on] :as mod}
(get modules module-id)]
(cond
(nil? mod)
(throw (ex-info "module not defined" {:missing module-id}))
(contains? deps module-id)
(throw (ex-info "module circular dependency" {:deps deps :module-id module-id}))
(contains? visited module-id)
state
:else
(-> state
(update :visited conj module-id)
(update :deps conj module-id)
(as-> state
(reduce topo-sort-modules* state depends-on))
(update :deps disj module-id)
(update :order conj module-id)))))
(defn topo-sort-modules
"sorts the :modules map, returns a vector of keywords in sorted order"
[modules]
(let [{:keys [deps visited order] :as result}
(reduce
topo-sort-modules*
{:deps #{}
:visited #{}
:order []
:modules modules}
(keys modules))]
(assert (empty? deps))
(assert (= (count visited) (count modules)))
order))
(defn compact-build-modules
"sorts modules in dependency order and remove sources provided by parent deps"
[{::keys [modules module-order] :as state}]
;; if only one module is defined we dont need all this work
(if (= 1 (count modules))
(let [mod-id (ffirst modules)]
(update-in state [::modules mod-id] assoc :goog-base true))
;; else: multiple modules must be sorted in dependency order
(let [src-refs
(->> (for [mod-id module-order
:let [{:keys [sources depends-on] :as mod} (get modules mod-id)]
src sources]
[src mod-id])
(reduce
(fn [src-refs [src dep]]
(update src-refs src util/set-conj dep))
{}))
;; could be optimized
find-mod-deps
(fn find-mod-deps [mod-id]
(let [{:keys [module-id depends-on] :as mod}
(get modules mod-id)]
(reduce set/union (into #{module-id} depends-on) (map find-mod-deps depends-on))))
find-closest-common-dependency
(fn [src deps]
(let [all
(map #(find-mod-deps %) deps)
common
(apply set/intersection all)]
(condp = (count common)
0
(throw (ex-info "no common dependency found for src" {:src src :deps deps}))
1
(first common)
(->> module-order
(reverse)
(drop-while #(not (contains? common %)))
(first)))))
all-sources
(->> module-order
(mapcat #(get-in modules [% :sources]))
(distinct)
(into []))
final-sources
(reduce
(fn [final src]
(let [deps
(get src-refs src)
target-mod
(if (= 1 (count deps))
(first deps)
(let [target-mod (find-closest-common-dependency src deps)]
;; only warn when a file is moved to a module it wouldn't be in naturally
(when-not (contains? deps target-mod)
(util/warn state {:type :module-move
:src src
:deps deps
:moved-to target-mod}))
target-mod))]
(update final target-mod util/vec-conj src)))
{}
all-sources)]
(reduce
(fn [state mod-id]
(let [sources (get final-sources mod-id)]
(when (empty? sources)
(util/log state {:type :empty-module :mod-id mod-id}))
(let [foreign-count
(->> sources
(map #(get-in state [:sources %]))
(filter util/foreign?)
(count))
all-foreign?
(= foreign-count (count sources))
;; FIXME: this is a terrible hack to ensure that we know which module contains goog/base.js
;; can't alias due to cyclic dependency, its an ordered vector, can't contains?
goog-base?
(some #(= % [:shadow.build.classpath/resource "goog/base.js"]) sources)
update
(-> {:sources sources
:foreign-count foreign-count}
(cond->
all-foreign?
(assoc :all-foreign all-foreign?)
goog-base?
(assoc :goog-base true)))]
(update-in state [::modules mod-id] merge update)
)))
state
module-order)
)))
(defn add-module-pseudo-rc [state mod-pos mod-id js]
(let [resource-id
[mod-pos mod-id]
provide
(symbol (str "shadow.module." (name mod-id) "." (name mod-pos)))
resource-name
(str "shadow/module/" (name mod-id) "/" (name mod-pos) ".js")
rc
{:resource-id resource-id
:type :goog
:cache-key [resource-id]
:last-modified 0
:resource-name resource-name
:output-name (util/flat-filename resource-name)
:ns provide
:provides #{provide}
:requires #{}
:deps []
:source js
:virtual true}]
(-> state
(data/add-source rc)
(cond->
(= ::prepend mod-pos)
(update-in [::modules mod-id :sources] #(into [resource-id] %))
(= ::append mod-pos)
(update-in [::modules mod-id :sources] conj resource-id)
))))
(defmethod cljs-log/event->str ::analyze-module
[{:keys [module-id entries] :as event}]
(format "Analyzing Module: %s" module-id))
(defn analyze-module
"resolve all deps for a given module, based on specified :entries
will update state for each module with :sources, a list of sources needed to compile this module
will add pseudo-resources if :append-js or :prepend-js are present"
[state module-id]
{:pre [(data/build-state? state)
(keyword? module-id)]}
(let [{:keys [entries append-js prepend-js] :as module}
(get-in state [::modules module-id])]
(util/with-logged-time [state {:type ::analyze-module
:entries entries
:module-id module-id}]
(let [[sources state]
(res/resolve-entries state entries)]
(-> state
(assoc-in [::modules module-id :sources] sources)
(cond->
(seq prepend-js)
(add-module-pseudo-rc ::prepend module-id prepend-js)
;; bootstrap needs to append some load info
;; this ensures that the rc is append correctly
;; it will be modified by shadow.build.bootstrap
(or (seq append-js) (:force-append module))
(add-module-pseudo-rc ::append module-id (or append-js ""))
))))))
(defn analyze-modules [{::keys [module-order] :as state}]
(reduce analyze-module state module-order))
(defn get-modules-ordered
[{::keys [modules module-order] :as state}]
(->> module-order
(map #(get modules %))
(into [])))
(defn normalize-config [config]
(reduce-kv
(fn [m module-id {:keys [output-name] :as mod}]
(assert (keyword? module-id))
(assert (map? mod))
(let [module-name
(str (name module-id) ".js")
mod (assoc mod
:module-id module-id
:module-name module-name
:output-name (or output-name module-name))]
(assoc m module-id mod)))
{}
config))
(defn configure [state config]
(let [modules (normalize-config config)]
(assoc state ::config modules)))
(defn configured? [state]
(contains? state ::config))
(defn set-build-info [state]
(let [build-modules
(get-modules-ordered state)
build-sources
(->> build-modules
(mapcat :sources)
(distinct) ;; FIXME: should already be distinct
(into []))]
(assoc state
:build-modules build-modules
:build-sources build-sources)))
(defn analyze
"prepares :modules for compilation (sort and compacts duplicate sources)"
[{::keys [config] :as state}]
(let [module-order (topo-sort-modules config)]
(-> state
(assoc
::modules config
::module-order module-order)
(analyze-modules)
(compact-build-modules)
(set-build-info)
)))