-
Notifications
You must be signed in to change notification settings - Fork 3
/
gen.cljc
223 lines (180 loc) · 5.3 KB
/
gen.cljc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
(ns shadow.markup.css.impl.gen
(:require [clojure.string :as str])
#?(:cljs
(:import [goog.string StringBuffer])))
(defprotocol IElement
(el-selector [x])
(el-type [x])
(el-css [x env]))
(defprotocol IStyleGen
(gen-css [x writer tag class]))
(declare map->root)
(defn generate-css
[env el]
(let [rule
(el-css el env)
tag
(el-type el)
class
(el-selector el)
sb
#?(:cljs
(StringBuffer.)
:clj
(StringBuilder.)) ;; StringBuffer synchronized in java
rule
(if (map? rule)
(map->root rule)
rule)]
(gen-css rule sb tag class)
(.toString sb)
))
(defn css-value-to-str [key value]
(cond
(string? value)
value
(number? value)
(if (zero? value)
"0"
(case key
:flex (str value)
:font-weight (str value)
:z-index (str value)
:opacity (str value)
(str value "px")))
(vector? value)
(let [[t r b l]
value]
(->> value
(map #(css-value-to-str key %))
(str/join " "))
)))
(defn -write-css-attrs [writer attrs]
(reduce-kv
(fn [_ key value]
(doto writer
(.append "\n ")
(.append (name key))
(.append ": ")
(.append (css-value-to-str key value))
(.append ";")))
nil
attrs))
(defn -write-rule [writer selector attrs]
(when (seq attrs)
(doto writer
(.append selector)
(.append " {")
(-write-css-attrs attrs)
(.append "\n}\n\n"))))
(defn merge-selector [selector tag class]
(cond
(str/includes? selector "%")
(-> selector
(str/replace #"%" tag)
(str/replace #"&" (str "." class)))
:else
(str/replace selector #"&" (str tag "." class))))
(deftype Rule [type selector attrs rules]
IStyleGen
(gen-css [this writer tag class]
(case type
:root
(do (-write-rule writer (str tag "." class) attrs)
(doseq [rule rules]
(gen-css rule writer tag class)))
:rule
(let [selector (merge-selector selector tag class)]
(-write-rule writer selector attrs)
(doseq [rule rules]
(gen-css rule writer tag class)))
:group
(do (doto writer
(.append selector)
(.append " {\n\n"))
(-write-rule writer (str tag "." class) attrs)
(doseq [rule rules]
(gen-css rule writer tag class))
(doto writer
(.append "\n}\n\n")))
)))
(defn rule? [x]
(instance? Rule x))
(defn group* [query attrs rules]
{:pre [(string? query)
(map? attrs)
(every? rule? rules)]}
(Rule. :group query attrs rules))
(defn media [query attrs & rules]
(group* (str "@media" query) attrs rules))
(defn rule [selector attrs]
{:pre [(string? selector)
(map? attrs)]}
(when-not (str/includes? selector "&")
(throw (ex-info "rules must contain & to place prefix (&:hover instead of :hover)" {:selector selector :attrs attrs})))
(Rule. :rule selector attrs []))
(defn nested-rule [parent attrs]
(let [selector
(cond
(satisfies? IElement parent)
(str "." (el-selector parent) " &")
(and (vector? parent)
(= 1 (count parent))
(and (satisfies? IElement (first parent))))
(str "." (el-selector (first parent)) " &")
(and (vector? parent)
(= 2 (count parent)))
(let [[el suffix] parent]
(when-not (satisfies? IElement el)
(throw (ex-info "need to be nested in IElement" {:parent parent :attrs attrs})))
(str "." (el-selector el) suffix " &")))]
(Rule. :rule selector attrs [])))
(defn root* [attrs rules]
{:pre [(map? attrs)
(every? rule? rules)]}
(Rule. :root nil attrs rules))
(defn root [attrs & rules]
(root* attrs rules))
(defn attrs-from-map [m]
(reduce-kv
(fn [m k v]
(if-not (keyword? k)
m
(assoc m k v)))
{}
m))
(defn- no-nested-rules!
[selector rules]
(when (seq rules)
(throw (ex-info "selector cannot have nested rules" {:selector selector :rules (map :selector rules)}))))
(defn rules-from-map [m]
(->> m
(keys)
(filter (complement keyword?))
(map
(fn [selector]
(let [v (get m selector)
sub-rules
(rules-from-map v)
attrs
(attrs-from-map v)]
(cond
(and (string? selector)
(str/starts-with? selector "@"))
(group* selector attrs sub-rules)
;; FIXME: we could allow nesting but styles get messy at that point
(string? selector)
(do (no-nested-rules! selector sub-rules)
(rule selector attrs))
(satisfies? IElement selector)
(do (no-nested-rules! selector sub-rules)
(nested-rule selector attrs))
(vector? selector)
(do (no-nested-rules! selector sub-rules)
(nested-rule selector attrs))
:else
(throw (ex-info "invalid key in map" {:key selector :value v}))
))))
(into [])))
(defn map->root [m]
(root* (attrs-from-map m) (rules-from-map m)))