-
Notifications
You must be signed in to change notification settings - Fork 0
/
String.purs
195 lines (169 loc) · 4.9 KB
/
String.purs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
module InteractiveData.DataUIs.String
( StringMsg
, StringState
, CfgString
, string
, string_
, defaultCfgString
) where
import InteractiveData.Core.Prelude
import Chameleon as C
import Data.Int as Int
import Data.String as Str
-------------------------------------------------------------------------------
--- Types
-------------------------------------------------------------------------------
data StringMsg
= SetString String
| Clear
| TrimString
newtype StringState = StringState String
derive newtype instance Show StringState
-------------------------------------------------------------------------------
--- Extract
-------------------------------------------------------------------------------
extract :: StringState -> DataResult String
extract (StringState s) = Right s
-------------------------------------------------------------------------------
--- Init
-------------------------------------------------------------------------------
init :: Maybe String -> StringState
init optStr = StringState $ fromMaybe "" optStr
-------------------------------------------------------------------------------
--- Update
-------------------------------------------------------------------------------
update :: StringMsg -> StringState -> StringState
update msg (StringState state) =
case msg of
SetString newString -> StringState newString
Clear -> StringState ""
TrimString -> StringState $ Str.trim state
-------------------------------------------------------------------------------
--- View
-------------------------------------------------------------------------------
type CfgView =
{ multiline :: Boolean
, maxLength :: Maybe Int
, rows :: Int
}
view :: forall html. IDHtml html => CfgView -> StringState -> html StringMsg
view
{ multiline, maxLength, rows }
(StringState state) =
withCtx \ctx ->
let
el =
{ root: C.div
, input: styleLeaf C.input
[ "width: 100%"
, "border: 1px solid #ccc"
, "border-radius: 3px"
]
, textarea: styleNode C.textarea
[ "width: 100%"
, "font-family: 'Signika Negative'"
, "border: 1px solid #ccc"
, "border-radius: 3px"
]
, details: styleNode C.div
[ "font-size: 10px"
, "margin-top: 5px"
]
}
multiLineInput :: html StringMsg
multiLineInput =
el.textarea
[ C.onInput SetString
, C.value state
, C.rows $ Int.toNumber rows
, maybe C.noProp C.maxlength maxLength
]
[]
singleLineInput :: html StringMsg
singleLineInput =
el.input
[ C.type_ "text"
, C.onInput SetString
, C.value state
, maybe C.noProp C.maxlength maxLength
]
getLineInput :: Boolean -> html StringMsg
getLineInput isMultiline =
if isMultiline then multiLineInput
else singleLineInput
in
case ctx.viewMode of
Standalone ->
el.root []
[ getLineInput multiline
, el.details []
[ C.text ("Length: " <> show (Str.length state)) ]
]
Inline ->
el.root []
[ singleLineInput
]
-------------------------------------------------------------------------------
--- DataActions
-------------------------------------------------------------------------------
actions :: Array (DataAction StringMsg)
actions =
[ DataAction
{ label: "Clear"
, msg: This $ Clear
, description: "Clear the string"
}
, DataAction
{ label: "Trim"
, msg: This $ TrimString
, description: "Trim whitespace from string"
}
]
-------------------------------------------------------------------------------
--- DataUI
-------------------------------------------------------------------------------
type CfgString msg =
{ text :: Maybe String
, multiline :: Boolean
, rows :: Int
, actions :: Array (DataAction msg)
, maxLength :: Maybe Int
}
defaultCfgString :: CfgString StringMsg
defaultCfgString =
{ text: Nothing
, multiline: false
, rows: 5
, actions
, maxLength: Nothing
}
string
:: forall opt html fm fs
. OptArgs (CfgString StringMsg) opt
=> IDHtml html
=> opt
-> DataUI (IDSurface html) fm fs StringMsg StringState String
string opt =
let
cfg :: CfgString StringMsg
cfg = getAllArgs defaultCfgString opt
in
DataUI \_ -> DataUiInterface
{ name: "String"
, view: \state -> IDSurface \_ ->
DataTree
{ view: view (pick cfg) state
, actions
, children: Fields []
, meta: Nothing
, text: cfg.text
}
, extract
, update
, init
}
string_
:: forall html fm fs
. IDHtml html
=> DataUI (IDSurface html) fm fs StringMsg StringState String
string_ = string {}