/
thrift.y
421 lines (358 loc) · 10.5 KB
/
thrift.y
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
%{
package internal
import "github.com/thriftrw/thriftrw-go/ast"
%}
%union {
// Used to record line numbers when the line number at the start point is
// required.
line int
// Holds the final AST for the file.
prog *ast.Program
// Other intermediate variables:
bul bool
str string
i64 int64
dub float64
fieldType ast.Type
structType ast.StructureType
baseTypeID ast.BaseTypeID
fieldRequired ast.Requiredness
field *ast.Field
fields []*ast.Field
header ast.Header
headers []ast.Header
function *ast.Function
functions []*ast.Function
enumItem *ast.EnumItem
enumItems []*ast.EnumItem
definition ast.Definition
definitions []ast.Definition
typeAnnotations []*ast.Annotation
constantValue ast.ConstantValue
constantValues []ast.ConstantValue
constantMapItems []ast.ConstantMapItem
}
%token <str> IDENTIFIER
%token <str> LITERAL
%token <i64> INTCONSTANT
%token <dub> DUBCONSTANT
// Reserved keywords
%token NAMESPACE INCLUDE
%token VOID BOOL BYTE I8 I16 I32 I64 DOUBLE STRING BINARY MAP LIST SET
%token ONEWAY TYPEDEF STRUCT UNION EXCEPTION EXTENDS THROWS SERVICE ENUM CONST
%token REQUIRED OPTIONAL TRUE FALSE
%type <line> lineno
%type <prog> program
%type <fieldType> type
%type <baseTypeID> base_type_name
%type <fieldRequired> field_required
%type <structType> struct_type
%type <field> field
%type <fields> fields
%type <header> header
%type <headers> headers
%type <function> function
%type <functions> functions
%type <enumItem> enum_item
%type <enumItems> enum_items
%type <definition> definition
%type <definitions> definitions
%type <constantValue> const_value
%type <constantValues> const_list_items
%type <constantMapItems> const_map_items
%type <typeAnnotations> type_annotation_list type_annotations
%%
program
: headers definitions
{
$$ = &ast.Program{Headers: $1, Definitions: $2}
yylex.(*lexer).program = $$
return 0
}
;
/***************************************************************************
Headers
***************************************************************************/
headers
: /* no headers */ { $$ = nil }
| headers header { $$ = append($1, $2) }
;
header
: lineno INCLUDE LITERAL
{
$$ = &ast.Include{
Path: $3,
Line: $1,
}
}
| lineno INCLUDE IDENTIFIER LITERAL
{
$$ = &ast.Include{
Name: $3,
Path: $4,
Line: $1,
}
}
| lineno NAMESPACE '*' IDENTIFIER
{
$$ = &ast.Namespace{
Scope: "*",
Name: $4,
Line: $1,
}
}
| lineno NAMESPACE IDENTIFIER IDENTIFIER
{
$$ = &ast.Namespace{
Scope: $3,
Name: $4,
Line: $1,
}
}
;
/***************************************************************************
Definitions
***************************************************************************/
definitions
: /* nothing */ { $$ = nil }
| definitions definition optional_sep { $$ = append($1, $2) }
;
definition
/* constants */
: lineno CONST type IDENTIFIER '=' const_value
{
$$ = &ast.Constant{
Name: $4,
Type: $3,
Value: $6,
Line: $1,
}
}
/* types */
| lineno TYPEDEF type IDENTIFIER type_annotations
{
$$ = &ast.Typedef{
Name: $4,
Type: $3,
Annotations: $5,
Line: $1,
}
}
| lineno ENUM IDENTIFIER '{' enum_items '}' type_annotations
{
$$ = &ast.Enum{
Name: $3,
Items: $5,
Annotations: $7,
Line: $1,
}
}
| lineno struct_type IDENTIFIER '{' fields '}' type_annotations
{
$$ = &ast.Struct{
Name: $3,
Type: $2,
Fields: $5,
Annotations: $7,
Line: $1,
}
}
/* services */
| lineno SERVICE IDENTIFIER '{' functions '}' type_annotations
{
$$ = &ast.Service{
Name: $3,
Functions: $5,
Annotations: $7,
Line: $1,
}
}
| lineno SERVICE IDENTIFIER EXTENDS lineno IDENTIFIER '{' functions '}'
type_annotations
{
parent := &ast.ServiceReference{
Name: $6,
Line: $5,
}
$$ = &ast.Service{
Name: $3,
Functions: $8,
Parent: parent,
Annotations: $10,
Line: $1,
}
}
;
struct_type
: STRUCT { $$ = ast.StructType }
| UNION { $$ = ast.UnionType }
| EXCEPTION { $$ = ast.ExceptionType }
;
enum_items
: /* nothing */ { $$ = nil }
| enum_items enum_item optional_sep { $$ = append($1, $2) }
;
enum_item
: lineno IDENTIFIER type_annotations
{ $$ = &ast.EnumItem{Name: $2, Annotations: $3, Line: $1} }
| lineno IDENTIFIER '=' INTCONSTANT type_annotations
{
value := int($4)
$$ = &ast.EnumItem{
Name: $2,
Value: &value,
Annotations: $5,
Line: $1,
}
}
;
fields
: /* nothing */ { $$ = nil }
| fields field optional_sep { $$ = append($1, $2) }
;
field
: lineno INTCONSTANT ':' field_required type IDENTIFIER type_annotations
{
$$ = &ast.Field{
ID: int($2),
Name: $6,
Type: $5,
Requiredness: $4,
Annotations: $7,
Line: $1,
}
}
| lineno INTCONSTANT ':' field_required type IDENTIFIER '=' const_value
type_annotations
{
$$ = &ast.Field{
ID: int($2),
Name: $6,
Type: $5,
Requiredness: $4,
Default: $8,
Annotations: $9,
Line: $1,
}
}
;
field_required
: REQUIRED { $$ = ast.Required }
| OPTIONAL { $$ = ast.Optional }
| /* na */ { $$ = ast.Unspecified }
;
functions
: /* nothing */ { $$ = nil }
| functions function optional_sep { $$ = append($1, $2) }
;
function
: oneway function_type lineno IDENTIFIER '(' fields ')' throws
type_annotations
{
$$ = &ast.Function{
Name: $4,
Parameters: $6,
ReturnType: $<fieldType>2,
Exceptions: $<fields>8,
OneWay: $<bul>1,
Annotations: $9,
Line: $3,
}
}
;
oneway
: ONEWAY { $<bul>$ = true }
| /* nothing */ { $<bul>$ = false }
;
function_type
: VOID { $<fieldType>$ = nil }
| type { $<fieldType>$ = $1 }
;
throws
: /* nothing */ { $<fields>$ = nil }
| THROWS '(' fields ')' { $<fields>$ = $3 }
;
/***************************************************************************
Types
***************************************************************************/
type
: base_type_name type_annotations
{ $$ = ast.BaseType{ID: $1, Annotations: $2} }
/* container types */
| MAP '<' type ',' type '>' type_annotations
{ $$ = ast.MapType{KeyType: $3, ValueType: $5, Annotations: $7} }
| LIST '<' type '>' type_annotations
{ $$ = ast.ListType{ValueType: $3, Annotations: $5} }
| SET '<' type '>' type_annotations
{ $$ = ast.SetType{ValueType: $3, Annotations: $5} }
| lineno IDENTIFIER
{ $$ = ast.TypeReference{Name: $2, Line: $1 } }
;
base_type_name
: BOOL { $$ = ast.BoolTypeID }
| BYTE { $$ = ast.I8TypeID }
| I8 { $$ = ast.I8TypeID }
| I16 { $$ = ast.I16TypeID }
| I32 { $$ = ast.I32TypeID }
| I64 { $$ = ast.I64TypeID }
| DOUBLE { $$ = ast.DoubleTypeID }
| STRING { $$ = ast.StringTypeID }
| BINARY { $$ = ast.BinaryTypeID }
;
/***************************************************************************
Constant values
***************************************************************************/
const_value
: INTCONSTANT { $$ = ast.ConstantInteger($1) }
| DUBCONSTANT { $$ = ast.ConstantDouble($1) }
| TRUE { $$ = ast.ConstantBoolean(true) }
| FALSE { $$ = ast.ConstantBoolean(false) }
| LITERAL { $$ = ast.ConstantString($1) }
| lineno IDENTIFIER
{ $$ = ast.ConstantReference{Name: $2, Line: $1} }
| '[' const_list_items ']' { $$ = ast.ConstantList{Items: $2} }
| '{' const_map_items '}' { $$ = ast.ConstantMap{Items: $2} }
;
const_list_items
: /* nothing */ { $$ = nil }
| const_list_items const_value optional_sep
{ $$ = append($1, $2) }
;
const_map_items
: /* nothing */ { $$ = nil }
| const_map_items const_value ':' const_value optional_sep
{ $$ = append($1, ast.ConstantMapItem{Key: $2, Value: $4}) }
;
/***************************************************************************
Type annotations
***************************************************************************/
type_annotations
: /* nothing */ { $$ = nil }
| '(' type_annotation_list ')' { $$ = $2 }
;
type_annotation_list
: /* nothing */ { $$ = nil }
| type_annotation_list lineno IDENTIFIER '=' LITERAL optional_sep
{ $$ = append($1, &ast.Annotation{Name: $3, Value: $5, Line: $2}) }
| type_annotation_list lineno IDENTIFIER optional_sep
{ $$ = append($1, &ast.Annotation{Name: $3, Line: $2}) }
;
/***************************************************************************
Other
***************************************************************************/
/* Grammar rules that need to record a line number at a specific token should
include this somewhere. For example,
foo : bar lineno baz { x := $2 }
$2 in the above example contains the line number right after 'bar' but before
'baz'. This way, if 'baz' spans mulitple lines, we still get the line number
for where the rule started rather than where it ends.
*/
lineno
: /* nothing */ { $$ = yylex.(*lexer).line }
;
optional_sep
: ','
| ';'
| /* nothing */
;
// vim:set ft=yacc: