-
Notifications
You must be signed in to change notification settings - Fork 16
/
Game.elm
307 lines (214 loc) · 6.69 KB
/
Game.elm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
module Game exposing
( Cell
, GameStatus(..)
, Model(..)
, Msg(..)
, Player(..)
, StatusMessage(..)
, Turn(..)
, currentStatus
, currentStatusMessage
, gameboard
, init
, nameToString
, pieceToString
, playerToString
, remainingPieces
, update
)
import Dict
import Game.Board as Board
exposing
( Board
, BoardStatus(..)
)
import Game.Core exposing (Cellname(..), Gamepiece)
import Helpers exposing (andThen, map, noCmds)
import List.Nonempty as Listn
import Process
import Random exposing (Generator)
import Shared exposing (Model)
import Task
import Time
-- DOMAIN
type Player
= Human
| Computer
type alias ActivePlayer =
Player
type alias Winner =
Player
type alias Cell =
{ name : Cellname
, status : Maybe Gamepiece
}
type alias ChosenPiece =
Gamepiece
type Turn
= ChoosingPiece
| ChoosingCellToPlay ChosenPiece
type GameStatus
= InPlay ActivePlayer Turn
| Won Winner
| Draw
type StatusMessage
= NoMessage
| SomePiecePlayedWhenNotPlayersTurn
type Model
= Model { board : Board, status : GameStatus, statusMessage : StatusMessage }
-- INIT
initStatus : GameStatus
initStatus =
InPlay Human ChoosingPiece
initStatusMessage : StatusMessage
initStatusMessage =
NoMessage
init : Model
init =
Model { board = Board.init, status = initStatus, statusMessage = initStatusMessage }
-- Msg
type Msg
= HumanSelectedPiece Gamepiece
| HumanSelectedCell Cellname
| RestartWanted
| ComputerSelectedCell Cellname
| ComputerSelectedPiece Gamepiece
-- UPDATE
update : Msg -> Model -> ( Model, Cmd Msg )
update msg (Model model) =
case ( msg, model.status ) of
( HumanSelectedPiece piece, InPlay Human ChoosingPiece ) ->
Model model
|> noCmds
|> map (nextPlayerStartsPlaying Human piece)
|> andThen (computerChooses ComputerSelectedCell Board.openCells)
( HumanSelectedPiece _, _ ) ->
Model { model | statusMessage = SomePiecePlayedWhenNotPlayersTurn }
|> noCmds
( ComputerSelectedCell name, InPlay Computer (ChoosingCellToPlay piece) ) ->
Model model
|> noCmds
|> map (playerTryPlay name piece)
|> (\( maybeModel, c ) ->
case maybeModel of
Just m ->
andThen (checkForWin Computer) ( m, c )
Nothing ->
Model model |> noCmds
)
( ComputerSelectedPiece piece, InPlay Computer ChoosingPiece ) ->
Model { model | statusMessage = NoMessage }
|> noCmds
|> map (nextPlayerStartsPlaying Computer piece)
( HumanSelectedCell name, InPlay Human (ChoosingCellToPlay piece) ) ->
Model { model | statusMessage = NoMessage }
|> noCmds
|> map (playerTryPlay name piece)
|> (\( maybeModel, c ) ->
case maybeModel of
Just m ->
andThen (checkForWin Human) ( m, c )
Nothing ->
Model model |> noCmds
)
( RestartWanted, _ ) ->
init |> noCmds
_ ->
Model model |> noCmds
nextPlayerStartsPlaying : ActivePlayer -> Gamepiece -> Model -> Model
nextPlayerStartsPlaying player piece (Model model) =
Model { model | status = InPlay (switch player) (ChoosingCellToPlay piece) }
msgGenerator : (a -> Msg) -> Generator a -> (Int -> Msg)
msgGenerator msgConstructor generator =
\num ->
Random.initialSeed num
|> Random.step generator
|> (\( value, _ ) -> msgConstructor value)
computerChooses : (a -> Msg) -> (Board -> List a) -> Model -> ( Model, Cmd Msg )
computerChooses msgConstructor boardfunc (Model model) =
let
generator : Listn.Nonempty a -> Cmd Msg
generator items =
items
|> Listn.sample
|> msgGenerator msgConstructor
|> delay 3
in
boardfunc model.board
|> Listn.fromList
|> Maybe.map generator
|> Maybe.withDefault Cmd.none
|> (\cmds -> ( Model model, cmds ))
playerTryPlay : Cellname -> Gamepiece -> Model -> Maybe Model
playerTryPlay name piece (Model model) =
let
newBoard =
Board.update name piece model.board
in
if newBoard == model.board then
Nothing
else
Just (Model { model | board = newBoard })
checkForWin : ActivePlayer -> Model -> ( Model, Cmd Msg )
checkForWin player (Model ({ board } as model)) =
case ( player, Board.status board ) of
( Computer, CanContinue ) ->
Model model
|> noCmds
|> map (playerStartsChoosing Computer)
|> andThen (computerChooses ComputerSelectedPiece Board.unPlayedPieces)
( Human, CanContinue ) ->
Model model
|> noCmds
|> map (playerStartsChoosing Human)
( _, MatchFound ) ->
Model { model | status = Won player }
|> noCmds
( _, Full ) ->
Model { model | status = Draw } |> noCmds
playerStartsChoosing : Player -> Model -> Model
playerStartsChoosing player (Model model) =
Model { model | status = InPlay player ChoosingPiece }
-- Cmd Msg
type alias Seconds =
Int
delay : Seconds -> (Int -> Msg) -> Cmd Msg
delay time generator =
Process.sleep (toFloat <| time * 1000)
|> Task.andThen (\_ -> Time.now)
|> Task.perform (Time.posixToMillis >> generator)
-- UTILITY
switch : ActivePlayer -> ActivePlayer
switch player =
if player == Human then
Computer
else
Human
gameboard : Model -> (Cellname -> Cell)
gameboard (Model model) =
\name ->
Board.playedPieces model.board
|> Dict.get (Board.nameToString name)
|> Cell name
remainingPieces : Model -> List Gamepiece
remainingPieces (Model model) =
Board.unPlayedPieces model.board
currentStatus : Model -> GameStatus
currentStatus (Model model) =
model.status
currentStatusMessage : Model -> StatusMessage
currentStatusMessage (Model model) =
model.statusMessage
playerToString : Player -> String
playerToString player =
case player of
Human ->
"Human"
Computer ->
"Computer"
nameToString : Cellname -> String
nameToString =
Board.nameToString
pieceToString : Gamepiece -> String
pieceToString =
Board.pieceToString