forked from modelica/ModelicaStandardLibrary
-
Notifications
You must be signed in to change notification settings - Fork 0
/
JointUPS.mo
525 lines (509 loc) · 22.1 KB
/
JointUPS.mo
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
within Modelica.Mechanics.MultiBody.Joints.Assemblies;
model JointUPS
"Universal - prismatic - spherical joint aggregation (no constraints, no potential states)"
import Modelica.Mechanics.MultiBody.Types;
extends Interfaces.PartialTwoFramesDoubleSize;
Modelica.Mechanics.MultiBody.Interfaces.Frame_a frame_ia
"Coordinate system at origin of frame_a fixed at prismatic joint"
annotation (Placement(transformation(
origin={-80,100},
extent={{-8,-8},{8,8}},
rotation=270)));
Modelica.Mechanics.MultiBody.Interfaces.Frame_b frame_ib
"Coordinate system at origin of frame_b fixed at prismatic joint"
annotation (Placement(transformation(
origin={80,100},
extent={{-8,8},{8,-8}},
rotation=270)));
Modelica.Mechanics.Translational.Interfaces.Flange_a axis
"1-dim. translational flange that drives the prismatic joint"
annotation (Placement(transformation(extent={{45,95},{35,105}})));
Modelica.Mechanics.Translational.Interfaces.Flange_b bearing
"1-dim. translational flange of the drive bearing of the prismatic joint"
annotation (Placement(transformation(extent={{-35,95},{-45,105}})));
parameter Boolean animation=true "= true, if animation shall be enabled";
parameter Boolean showUniversalAxes=true
"= true, if universal joint shall be visualized with two cylinders, otherwise with a sphere (provided animation=true)";
parameter Modelica.Mechanics.MultiBody.Types.Axis n1_a={0,0,1}
"Axis 1 of universal joint resolved in frame_a (axis 2 is orthogonal to axis 1 and to line from universal to spherical joint)"
annotation (Evaluate=true);
parameter SI.Position nAxis_ia[3]={1,0,0}
"Axis vector along line from origin of frame_a to origin of frame_b, resolved in frame_ia"
annotation (Evaluate=true);
parameter SI.Position s_offset=0
"Relative distance offset (distance between frame_a and frame_b = s(t) + s_offset)";
parameter SI.Diameter sphereDiameter=world.defaultJointLength
"Diameter of spheres representing the spherical joints"
annotation (Dialog(tab="Animation", group="if animation = true", enable=animation));
input Types.Color sphereColor=Modelica.Mechanics.MultiBody.Types.Defaults.JointColor
"Color of spheres representing the spherical joints"
annotation (Dialog(colorSelector=true, tab="Animation", group="if animation = true", enable=animation));
parameter SI.Diameter axisDiameter=sphereDiameter/Types.Defaults.
JointRodDiameterFraction
"Diameter of cylinder on the connecting line from frame_a to frame_b"
annotation (Dialog(tab="Animation", group="if animation = true", enable=animation));
input Types.Color axisColor=Modelica.Mechanics.MultiBody.Types.Defaults.SensorColor
"Color of cylinder on the connecting line from frame_a to frame_b"
annotation (Dialog(colorSelector=true, tab="Animation", group="if animation = true", enable=animation));
input Types.SpecularCoefficient specularCoefficient = world.defaultSpecularCoefficient
"Reflection of ambient light (= 0: light is completely absorbed)"
annotation (Dialog(tab="Animation", group="if animation = true", enable=animation));
parameter SI.Distance cylinderLength=world.defaultJointLength
"Length of cylinders representing the two universal joint axes" annotation (
Dialog(tab="Animation", group="if animation = true and showUniversalAxes",
enable=animation and showUniversalAxes));
parameter SI.Distance cylinderDiameter=world.defaultJointWidth
"Diameter of cylinders representing the two universal joint axes"
annotation (Dialog(tab="Animation", group=
"if animation = true and showUniversalAxes",
enable=animation and showUniversalAxes));
input Types.Color cylinderColor=Modelica.Mechanics.MultiBody.Types.Defaults.JointColor
"Color of cylinders representing the two universal joint axes" annotation (
Dialog(colorSelector=true, tab="Animation", group="if animation = true and showUniversalAxes",
enable=animation and showUniversalAxes));
parameter Boolean checkTotalPower=false
"= true, if total power flowing into this component shall be determined (must be zero)"
annotation (Dialog(tab="Advanced"));
final parameter Real eAxis_ia[3](each final unit="1")=Modelica.Math.Vectors.normalizeWithAssert(nAxis_ia)
"Unit vector from origin of frame_a to origin of frame_b, resolved in frame_ia";
final parameter Real e2_ia[3](each final unit="1")=Modelica.Math.Vectors.normalizeWithAssert(
cross(n1_a, eAxis_ia))
"Unit vector in direction of second rotation axis of universal joint, resolved in frame_ia";
final parameter Real e3_ia[3](each final unit="1")=cross(eAxis_ia, e2_ia)
"Unit vector perpendicular to eAxis_ia and e2_ia, resolved in frame_ia";
SI.Position s
"Relative distance between frame_a and frame_b along axis nAxis = s + s_offset";
SI.Force f "= axis.f (driving force in the axis; = -bearing.f)";
SI.Length axisLength "Distance between frame_a and frame_b";
SI.Power totalPower
"Total power flowing into this element, if checkTotalPower=true (otherwise dummy)";
protected
SI.Force f_c_a[3] "frame_ia.f resolved in frame_a";
SI.Torque t_cd_a[3] "frame_ia.t + frame_ib.t resolved in frame_a";
SI.Force f_bd_a[3] "frame_b.f + frame_ib.f resolved in frame_a";
SI.Position rAxis_0[3]
"Position vector from origin of frame_a to origin of frame_b resolved in world frame";
SI.Position rAxis_a[3]
"Position vector from origin of frame_a to origin of frame_b resolved in frame_a";
Real eAxis_a[3](each final unit="1")
"Unit vector in direction of rAxis_a, resolved in frame_a";
Real e2_a[3](each final unit="1")
"Unit vector in direction of second rotation axis of universal joint, resolved in frame_a";
Real e3_a[3](each final unit="1")
"Unit vector perpendicular to eAxis_a and e2_a, resolved in frame_a";
Real n2_a[3](each final unit="1")
"Vector in direction of second rotation axis of universal joint, resolved in frame_a";
Real length2_n2_a(unit="1") "Square of length of vector n2_a";
Real length_n2_a(unit="1") "Length of vector n2_a";
Real der_rAxis_a_L[3](each unit="1/s") "= der(rAxis_a)/axisLength";
SI.AngularVelocity w_rel_ia1[3];
Frames.Orientation R_ia1_a;
Frames.Orientation R_ia2_a;
Frames.Orientation R_ia_a "Rotation from frame_a to frame_ia";
// Real T_ia_a[3, 3] "Transformation matrix from frame_a to frame_ia";
Visualizers.Advanced.Shape axisCylinder(
shapeType="cylinder",
color=axisColor,
specularCoefficient=specularCoefficient,
length=axisLength,
width=axisDiameter,
height=axisDiameter,
lengthDirection=eAxis_ia,
widthDirection=e2_ia,
r=frame_ia.r_0,
R=frame_ia.R) if world.enableAnimation and animation;
Visualizers.Advanced.Shape sphericalShape_b(
shapeType="sphere",
color=sphereColor,
specularCoefficient=specularCoefficient,
length=sphereDiameter,
width=sphereDiameter,
height=sphereDiameter,
lengthDirection={1,0,0},
widthDirection={0,1,0},
r_shape={-0.5,0,0}*sphereDiameter,
r=frame_b.r_0,
R=frame_b.R) if world.enableAnimation and animation;
Visualizers.Advanced.Shape sphericalShape_a(
shapeType="sphere",
color=sphereColor,
specularCoefficient=specularCoefficient,
length=sphereDiameter,
width=sphereDiameter,
height=sphereDiameter,
lengthDirection={1,0,0},
widthDirection={0,1,0},
r_shape={-0.5,0,0}*sphereDiameter,
r=frame_a.r_0,
R=frame_a.R) if world.enableAnimation and animation;
Visualizers.Advanced.Shape universalShape1(
shapeType="cylinder",
color=cylinderColor,
specularCoefficient=specularCoefficient,
length=cylinderLength,
width=cylinderDiameter,
height=cylinderDiameter,
lengthDirection=n1_a,
widthDirection={0,1,0},
r_shape=-n1_a*(cylinderLength/2),
r=frame_a.r_0,
R=frame_a.R) if world.enableAnimation and animation and showUniversalAxes;
Visualizers.Advanced.Shape universalShape2(
shapeType="cylinder",
color=cylinderColor,
specularCoefficient=specularCoefficient,
length=cylinderLength,
width=cylinderDiameter,
height=cylinderDiameter,
lengthDirection=e2_ia,
widthDirection={0,1,0},
r_shape=-e2_ia*(cylinderLength/2),
r=frame_ia.r_0,
R=frame_ia.R) if world.enableAnimation and animation and showUniversalAxes;
equation
Connections.branch(frame_a.R, frame_ia.R);
Connections.branch(frame_ia.R, frame_ib.R);
// Translational flanges
axisLength = s + s_offset;
bearing.s = 0;
axis.s = s;
axis.f = f;
// Position vector rAxis from frame_a to frame_b
rAxis_0 = frame_b.r_0 - frame_a.r_0;
rAxis_a = Frames.resolve2(frame_a.R, rAxis_0);
/* Determine relative Rotation R_rel_c from frame_a to frame_ia
and absolute rotation of frame_a.R.
*/
axisLength = sqrt(rAxis_0*rAxis_0);
assert(axisLength > 1.0e-15, "
Distance between frame_a and frame_b of a JointUPS joint
became zero. This is not allowed. If this occurs during
initialization, the initial conditions are probably wrong.");
eAxis_a = rAxis_a/axisLength;
n2_a = cross(n1_a, eAxis_a);
length2_n2_a = n2_a*n2_a;
assert(noEvent(length2_n2_a > 1e-10), "
A Modelica.Mechanics.MultiBody.Joints.Assemblies.JointUPS joint (consisting of
a universal, prismatic and spherical joint) is in the singular
configuration of the universal joint. This means that axis 1 of
the universal joint defined via parameter \"n1_a\" is parallel to vector
\"eAxis_ia\" that is directed from the origin of frame_a to the
origin of frame_b. You may try to use another \"n1_a\" vector.
");
length_n2_a = sqrt(length2_n2_a);
e2_a = n2_a/length_n2_a;
e3_a = cross(eAxis_a, e2_a);
/* The statements below are an efficient implementation of the
original equations:
T_ia_a = [eAxis_ia, e2_ia, e3_ia]*transpose([eAxis_a, e2_a, e3_a]);
R_ia_a = Frames.from_T(T_ia_a,
Frames.TransformationMatrices.angularVelocity2(T_ia_a, der(T_ia_a)));
To perform this, the rotation is split into two parts:
R_ia_a : Rotation object from frame_a to frame_ia
R_ia1_a: Rotation object from frame_a to frame_ia1
(frame that is fixed in frame_ia such that x-axis
is along the rod axis)
T = transpose([eAxis_a, e2_a, e3_a]; w = w_rel_ia1
R_ia2_a: Fixed rotation object from frame_ia1 to frame_ia
T = [eAxis_a, e2_ia, e3_ia]; w = zeros(3)
The difficult part is to compute w_rel_ia1:
w_rel_ia1 = [ e3_a*der(e2_a);
-e3_a*der(eAxis_a);
e2_a*der(eAxis_a)]
der(eAxis_a) is directly given, since eAxis_a is a function
of translational quantities only.
der(eAxis_a) = (der(rAxis_a) - eAxis_a*(eAxis_a*der(rAxis_a)))/axisLength
der(n2_a) = cross(n1_a, der(eAxis_a))
der(e2_a) = (der(n2_a) - e2_a*(e2_a*der(n2_a)))/length_n2_a
Inserting these equations in w_rel_ia1 results in:
e3_a*der(eAxis_a) = e3_a*der(rAxis_a)/axisLength // e3_a*eAxis_a = 0
e2_a*der(eAxis_a) = e2_a*der(rAxis_a)/axisLength // e2_a*eAxis_a = 0
e3_a*der(e2_a) = e3_a*der(n2_a)/length_n2_a // e3_a*e2_a = 0
= e3_a*cross(n1_a, der(eAxis_a))/length_n2_a
= e3_a*cross(n1_a, der(rAxis_a) - eAxis_a*(eAxis_a*der(rAxis_a)))/(length_n2_a*axisLength)
= e3_a*cross(n1_a, der(rAxis_a))/(length_n2_a*axisLength)
Furthermore, we have:
rAxis_a = resolve2(frame_a.R, rAxis_0);
der(rAxis_a) = resolve2(frame_a.R, der(rAxis_0)) - cross(frame_a.R.w, rAxis_a));
*/
der_rAxis_a_L = (Frames.resolve2(frame_a.R, der(rAxis_0)) - cross(frame_a.
R.w, rAxis_a))/axisLength;
w_rel_ia1 = {e3_a*cross(n1_a, der_rAxis_a_L)/length_n2_a,-e3_a*
der_rAxis_a_L,e2_a*der_rAxis_a_L};
R_ia1_a = Frames.from_T(transpose([eAxis_a, e2_a, e3_a]), w_rel_ia1);
R_ia2_a = Frames.from_T([eAxis_ia, e2_ia, e3_ia], zeros(3));
R_ia_a = Frames.absoluteRotation(R_ia1_a, R_ia2_a);
/*
T_ia_a = [eAxis_ia, e2_ia, e3_ia]*transpose([eAxis_a, e2_a, e3_a]);
R_ia_a = Frames.from_T(T_ia_a, Frames.TransformationMatrices.angularVelocity2
(T_ia_a, der(T_ia_a)));
*/
// Compute kinematic quantities of frame_ia and frame_ib
frame_ia.r_0 = frame_a.r_0;
frame_ib.r_0 = frame_b.r_0;
frame_ia.R = Frames.absoluteRotation(frame_a.R, R_ia_a);
frame_ib.R = frame_ia.R;
/* In the following formulas f_a, f_b, f_ia, f_ib, t_a, t_b, t_ia, t_ib are
the forces and torques at frame_a, frame_b, frame_ia, frame_ib respectively,
resolved in frame_a. eAxis, e2, e3 are the unit vectors resolved in frame_a.
Torque balance at the rod around the origin of frame_a:
0 = t_a + t_ia + t_ib + cross(rAxis, (f_b+f_ib))
with
rAxis = axisLength*eAxis
f_bd = f_b + f_ib
f_bd = f*eAxis + f_bd[2]*e2 + f_bd[3]*e3
follows:
0 = t_a + t_ia + axisLength*(f_bd[2]*e_z - f_bd[3]*e_y)
The projection of t_a with respect to universal joint axes vanishes:
e1*t_a = 0
e2*t_a = 0
Therefore:
0 = e1*(t_ia + t_ib) + axisLength*f_bd[2]*(e1*e3)
0 = e2*(t_ia + t_ib) - axisLength*f_bd[3]
or
f_bd = f*eAxis - e2*(e1*(t_ia+t_ib))/(axisLength*(e1*e3)) +
e3*(e2*(t_ia+t_ib))/axisLength
Force balance:
0 = f_a + f_bd + f_ia
*/
f_c_a = Frames.resolve1(R_ia_a, frame_ia.f);
t_cd_a = Frames.resolve1(R_ia_a, frame_ia.t + frame_ib.t);
f_bd_a = -eAxis_a*f - e2_a*((n1_a*t_cd_a)/(axisLength*(n1_a*e3_a))) +
e3_a*((e2_a*t_cd_a)/axisLength);
zeros(3) = frame_b.f + Frames.resolveRelative(frame_ib.f, frame_ib.R,
frame_b.R) - Frames.resolveRelative(f_bd_a, frame_a.R, frame_b.R);
zeros(3) = frame_b.t;
zeros(3) = frame_a.f + f_c_a + f_bd_a;
zeros(3) = frame_a.t + t_cd_a + cross(rAxis_a, f_bd_a);
// Measure power for test purposes
if checkTotalPower then
totalPower = frame_a.f*Frames.resolve2(frame_a.R, der(frame_a.r_0)) +
frame_b.f*Frames.resolve2(frame_b.R, der(frame_b.r_0)) + frame_ia.f*
Frames.resolve2(frame_ia.R, der(frame_ia.r_0)) + frame_ib.f*
Frames.resolve2(frame_ib.R, der(frame_ib.r_0)) + frame_a.t*
Frames.angularVelocity2(frame_a.R) + frame_b.t*
Frames.angularVelocity2(frame_b.R) + frame_ia.t*
Frames.angularVelocity2(frame_ia.R) + frame_ib.t*
Frames.angularVelocity2(frame_ib.R) + axis.f*der(axis.s) + bearing.f*
der(bearing.s);
else
totalPower = 0;
end if;
annotation (
Documentation(info="<html>
<p>
This component consists of a <strong>universal</strong> joint at frame_a,
a <strong>spherical</strong> joint at frame_b and a <strong>prismatic</strong> joint along the
line connecting the origin of frame_a and the origin of frame_b,
see the default animation in the following figure (the axes vectors
are not part of the default animation):
</p>
<div>
<img src=\"modelica://Modelica/Resources/Images/Mechanics/MultiBody/Joints/Assemblies/JointUPS.png\" alt=\"model Joints.Assemblies.JointUPS\">
</div>
<p>
This joint aggregation has no mass and no inertia and
introduces neither constraints nor potential state variables.
It is especially useful to build up more complicated force elements
where the mass and/or inertia of the force element shall be taken
into account.
</p>
<p>
The universal joint is defined in the following way:
</p>
<ul>
<li> The rotation <strong>axis</strong> of revolute joint <strong>1</strong> is along parameter
vector n1_a which is fixed in frame_a.</li>
<li> The rotation <strong>axis</strong> of revolute joint <strong>2</strong> is perpendicular to
axis 1 and to the line connecting the universal and the spherical joint.</li>
</ul>
<p>
The definition of axis 2 of the universal joint is performed according
to the most often occurring case for the sake of simplicity. Otherwise, the treatment is much more
complicated and the number of operations is considerably higher,
if axis 2 is not orthogonal to axis 1 and to the connecting rod.
</p>
<p>
Note, there is a <strong>singularity</strong> when axis 1 and the connecting line are parallel
to each other. Therefore, if possible n1_a should be selected in such a way that it
is perpendicular to nAxis_ia in the initial configuration (i.e., the
distance to the singularity is as large as possible).
</p>
<p>
An additional <strong>frame_ia</strong> is present. It is <strong>fixed</strong> on the line
connecting the universal and the spherical joint at the
origin of <strong>frame_a</strong>. The placement of frame_ia on this line
is implicitly defined by the universal joint (frame_a and frame_ia coincide
when the angles of the two revolute joints of the universal joint are zero)
and by parameter vector <strong>nAxis_ia</strong>, an axis vector directed
along the line from the origin of frame_a to the spherical joint,
resolved in frame_<strong>ia</strong>.
</p>
<p>
An additional <strong>frame_ib</strong> is present. It is <strong>fixed</strong> in the line
connecting the prismatic and the spherical joint at the
origin of <strong>frame_b</strong>.
It is always parallel to <strong>frame_ia</strong>.
</p>
<p>
Note, this joint aggregation can be used in cases where
in reality a rod with spherical joints at each end are present.
Such a system has an additional degree of freedom to rotate
the rod along its axis. In practice this rotation is usually
of no interest and is mathematically removed by replacing one
of the spherical joints by a universal joint.
</p>
<p>
The easiest way to define the parameters of this joint is by moving the
MultiBody system in a <strong>reference configuration</strong> where <strong>all frames</strong>
of all components are <strong>parallel</strong> to each other (alternatively,
at least frame_a, frame_ia and frame_ib of the JointUSP joint
should be parallel to each other when defining an instance of this
component).
</p>
</html>"),
Icon(coordinateSystem(
preserveAspectRatio=true,
extent={{-100,-100},{100,100}},
initialScale=0.2), graphics={
Ellipse(
extent={{100,-40},{20,40}},
startAngle=70,
endAngle=290,
lineColor={0,0,0},
fillColor={192,192,192},
fillPattern=FillPattern.Sphere,
closure=EllipseClosure.Radial),
Ellipse(
extent={{90,-30},{30,30}},
fillColor={255,255,255},
fillPattern=FillPattern.Solid,
startAngle=69,
endAngle=291,
lineColor={255,255,255},
closure=EllipseClosure.Radial),
Ellipse(
extent={{90,-30},{30,30}},
startAngle=70,
endAngle=290,
lineColor={0,0,0},
closure=EllipseClosure.None),
Ellipse(
extent={{46,14},{74,-14}},
fillPattern=FillPattern.Sphere,
fillColor={192,192,192}),
Ellipse(
extent={{-100,-40},{-20,40}},
startAngle=90,
endAngle=270,
lineColor={0,0,0},
fillColor={192,192,192},
fillPattern=FillPattern.Sphere,
closure=EllipseClosure.Radial),
Ellipse(
extent={{-90,-30},{-30,30}},
fillColor={255,255,255},
fillPattern=FillPattern.Solid,
startAngle=89,
endAngle=271,
lineColor={255,255,255},
closure=EllipseClosure.Radial),
Ellipse(
extent={{-90,-30},{-30,30}},
startAngle=90,
endAngle=270,
lineColor={0,0,0},
closure=EllipseClosure.None),
Line(
points={{-60,40},{-60,-40}},
thickness=0.5),
Ellipse(
extent={{-30,-20},{-90,20}},
fillPattern=FillPattern.Sphere,
fillColor={192,192,192},
startAngle=124,
endAngle=304),
Ellipse(
extent={{-40,-10},{-80,10}},
lineColor={255,255,255},
fillColor={255,255,255},
fillPattern=FillPattern.Solid,
startAngle=0,
endAngle=360),
Ellipse(
extent={{-40,-10},{-80,10}},
lineColor={95,95,95},
fillColor={255,255,255},
fillPattern=FillPattern.Solid,
startAngle=117,
endAngle=298,
closure=EllipseClosure.None),
Line(
points={{-42,18},{-78,-18}},
thickness=0.5),
Line(
points={{-60,40},{-60,-10}},
thickness=0.5),
Text(
extent={{-140,-45},{140,-70}},
textColor={0,0,255},
textString="%name"),
Rectangle(
extent={{-22,45},{40,-43}},
lineColor={255,255,255},
fillColor={255,255,255},
fillPattern=FillPattern.Solid),
Text(
extent={{-98,84},{-60,65}},
textColor={128,128,128},
textString="ia"),
Line(
points={{-40,0},{-40,90},{-80,90},{-80,97}},
color={95,95,95},
thickness=0.5),
Text(
extent={{61,86},{109,64}},
textColor={128,128,128},
textString="ib"),
Rectangle(
extent={{-35,-13},{-6,14}},
pattern=LinePattern.None,
fillColor={192,192,192},
fillPattern=FillPattern.Solid,
lineColor={0,0,255}),
Rectangle(
extent={{-35,14},{-6,18}},
pattern=LinePattern.None,
fillPattern=FillPattern.Solid,
lineColor={0,0,255}),
Rectangle(
extent={{-6,-7},{46,6}},
pattern=LinePattern.None,
fillColor={192,192,192},
fillPattern=FillPattern.Solid,
lineColor={0,0,255}),
Rectangle(
extent={{-6,6},{46,10}},
pattern=LinePattern.None,
fillPattern=FillPattern.Solid,
lineColor={0,0,255}),
Line(points={{-6,-13},{-6,18}}),
Line(
points={{60,0},{60,90},{80,90},{80,97}},
color={95,95,95},
thickness=0.5),
Line(
points={{60,90},{40,90},{40,95}},
color={95,95,95},
thickness=0.5),
Line(points={{-30,70},{10,70}}),
Polygon(
points={{30,70},{10,76},{10,63},{30,70}},
lineColor={128,128,128},
fillColor={128,128,128},
fillPattern=FillPattern.Solid),
Line(
points={{-40,90},{-40,90},{-40,95}},
color={95,95,95},
thickness=0.5)}));
end JointUPS;