Possible conflict with Optional in Type::Tiny

[jandrew]

I am seeing fails for classes using Types::Standard and Optional when Type::Tiny::XS (0.008) is installed. The following case passes when Type::Tiny::XS is not installed and fails for not enough arguments when it is. I don't know any XS so I'm not exactly sure what part is failing and what parts are not essential to the test case. I run Strawberry perl 5.14 on windows 64 but I am getting fails for linux on all versions of perl for modules I have posted to CPAN(updated) with Types::Standard qw( Optional ) for apparently the same reason (inferred).

#!perl
package MyTest;
use strict;
use warnings;
use Type::Utils 0.046 -all;
use Test::Most;
eval "use Type::Tiny::XS";
use Type::Library 0.046
    -base,
    -declare => qw(
        TestDictionary SuperClassesList NameSpace
    );
use Types::Standard 0.046 -types;

declare NameSpace,
    as Str,
    where{ $_ =~ /^[A-Za-z:]+$/ },
    message{ "-$_- does not match: " . qr/^[A-Za-z:]+$/ };

declare SuperClassesList,
    as ArrayRef[ ClassName ],
    where{ scalar( @$_ ) > 0 };

declare TestDictionary,
    as Dict[
        package => Optional[ NameSpace ],
        superclasses => Optional[ SuperClassesList ],
    ],;

ok        TestDictionary->( { package => 'My::Package' } ), 
                "Test TestDictionary";
done_testing();

The error message with ~::XS installed is;

Too few arguments for type constraint check functions at C:/strawberry/perl/site/lib/Type/Tiny.pm line 358.

[tobyink]

Declaring inline_as for the first two types allows you to work around the issue:

use strict;
use warnings;
use Test::Most;

{
    package MyTest;
    use Type::Utils 0.046 -all;
    use Type::Library 0.046
        -base,
        -declare => qw(TestDictionary SuperClassesList NameSpace);
    use Types::Standard 0.046 -types;

    declare NameSpace,
        as Str,
        where { $_ =~ /^[A-Za-z:]+$/ },
        inline_as { undef, "$_ =~ /^[A-Za-z:]+\$/" },
        message { "-$_- does not match: " . qr/^[A-Za-z:]+$/ };

    declare SuperClassesList,
        as ArrayRef[ ClassName ],
        inline_as { undef, "\@{$_} > 0" },
        where { scalar( @$_ ) > 0 };

    declare TestDictionary, as Dict[
        package      => Optional[ NameSpace ],
        superclasses => Optional[ SuperClassesList ],
    ];
}

ok(
    MyTest::TestDictionary->check( { package => 'My::Package' } ),
    "Test TestDictionary"
);

diag MyTest::TestDictionary->inline_check('$dict');

done_testing;

[tobyink]

Fixed in 0.010 (I hope).