-
Notifications
You must be signed in to change notification settings - Fork 0
/
platform.ld
188 lines (172 loc) · 7.92 KB
/
platform.ld
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
/*
* Modify the ROM and RAM base and sz (size) variables below to
* suit your systems memory layout.
*
* base indicates at what address a memory begins
* sz indicates the size of that memory
*
* Values can be specified in decimal, hexadecimal, or as units such
* as 1K or 1M.
*
* Space for the stack may also be reserved here. The heap will then
* consume all remaining RAM between the end of the .bss section and
* the lowest address reserved for the stack.
*
* Since there are no controls in place to ensure the stack does not
* grow into the heap, the user is responsible for reserving sufficient
* stack space to prevent it overwriting the upper areas of the heap.
*/
_rom_base = 0;
_rom_sz = 1M;
_ram_base = 0x00100000;
_ram_sz = 1M;
_stack_sz = 4K;
/*
* Dont modify below this line (unless you know what youre doing),
* except to add user interrupt vectors.
*/
STARTUP(crt0.o)
OUTPUT_ARCH(m68k)
__rom_end = (_rom_base + _rom_sz);
__ram_end = (_ram_base + _ram_sz);
__evt_org = _rom_base;
__text_org = _rom_base + 0x400;
__text_sz = _rom_sz - 0x400;
__data_org = _ram_base;
__data_sz = _ram_sz;
/* Make sure stack size is a multiple of 16, and at least the amount the user
* thought they were getting. */
_stack_sz += 15;
_stack_sz &= ~0xF;
MEMORY {
evt (r!ax) : ORIGIN = __evt_org, LENGTH = 0x400
text (rx!w) : ORIGIN = __text_org, LENGTH = __text_sz
data (rwx!a) : ORIGIN = __data_org, LENGTH = __data_sz
iomem (rw!a) : ORIGIN = 0x00600000, LENGTH = 2M
}
SECTIONS {
.evt : {
/* Reset vector */
LONG(__ram_end); /* Initial SSP */
LONG(ABSOLUTE(_start)); /* Initial PC */
/* Exception vector table */
LONG(DEFINED(BusError) ? ABSOLUTE(BusError) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(AddressError) ? ABSOLUTE(AddressError) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(IllegalInstruction) ? ABSOLUTE(IllegalInstruction) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(ZeroDivide) ? ABSOLUTE(ZeroDivide) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(CHKInstruction) ? ABSOLUTE(CHKInstruction) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAPVInstruction) ? ABSOLUTE(TRAPVInstruction) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(PrivilegeViolation) ? ABSOLUTE(PrivilegeViolation) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(Trace) ? ABSOLUTE(Trace) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(Line1010Emulator) ? ABSOLUTE(Line1010Emulator) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(Line1111Emulator) ? ABSOLUTE(Line1111Emulator) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(HardwareBreakpoint) ? ABSOLUTE(HardwareBreakpoint) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(CoprocessorProtocolViolation) ? ABSOLUTE(CoprocessorProtocolViolation) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(FormatError) ? ABSOLUTE(FormatError) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(UninitializedInterruptVector) ? ABSOLUTE(UninitializedInterruptVector) : ABSOLUTE(__DefaultInterrupt));
LONG(0); /* Unassigned, reserved */
LONG(0); /* Unassigned, reserved */
LONG(0); /* Unassigned, reserved */
LONG(0); /* Unassigned, reserved */
LONG(0); /* Unassigned, reserved */
LONG(0); /* Unassigned, reserved */
LONG(0); /* Unassigned, reserved */
LONG(0); /* Unassigned, reserved */
LONG(DEFINED(SpuriousInterrupt) ? ABSOLUTE(SpuriousInterrupt) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(IRQ1) ? ABSOLUTE(IRQ1) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(IRQ2) ? ABSOLUTE(IRQ2) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(IRQ3) ? ABSOLUTE(IRQ3) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(IRQ4) ? ABSOLUTE(IRQ4) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(IRQ5) ? ABSOLUTE(IRQ5) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(IRQ6) ? ABSOLUTE(IRQ6) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(IRQ7) ? ABSOLUTE(IRQ7) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP0) ? ABSOLUTE(TRAP0) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP1) ? ABSOLUTE(TRAP1) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP2) ? ABSOLUTE(TRAP2) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP3) ? ABSOLUTE(TRAP3) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP4) ? ABSOLUTE(TRAP4) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP5) ? ABSOLUTE(TRAP5) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP6) ? ABSOLUTE(TRAP6) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP7) ? ABSOLUTE(TRAP7) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP8) ? ABSOLUTE(TRAP8) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP9) ? ABSOLUTE(TRAP9) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP10) ? ABSOLUTE(TRAP10) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP11) ? ABSOLUTE(TRAP11) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP12) ? ABSOLUTE(TRAP12) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP13) ? ABSOLUTE(TRAP13) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP14) ? ABSOLUTE(TRAP14) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(TRAP15) ? ABSOLUTE(TRAP15) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(FPBranchOrSetUnorderedCondition) ? ABSOLUTE(FPBranchOrSetUnorderedCondition) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(FPInexactResult) ? ABSOLUTE(FPInexactResult) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(FPZeroDivide) ? ABSOLUTE(FPZeroDivide) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(FPUnderflow) ? ABSOLUTE(FPUnderflow) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(FPOperandError) ? ABSOLUTE(FPOperandError) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(FPOverflow) ? ABSOLUTE(FPOverflow) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(FPSignallingNAN) ? ABSOLUTE(FPSignallingNAN) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(FPUnimplementedDataType) ? ABSOLUTE(FPUnimplementedDataType) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(MMUConfigurationError) ? ABSOLUTE(MMUConfigurationError) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(MMUIllegalOperation) ? ABSOLUTE(MMUIllegalOperation) : ABSOLUTE(__DefaultInterrupt));
LONG(DEFINED(MMUAccessLevelViolation) ? ABSOLUTE(MMUAccessLevelViolation) : ABSOLUTE(__DefaultInterrupt));
LONG(0); /* Unassigned, reserved */
LONG(0); /* Unassigned, reserved */
LONG(0); /* Unassigned, reserved */
LONG(0); /* Unassigned, reserved */
LONG(0); /* Unassigned, reserved */
/*
*
* User Interrupt Vectors
*
* Vector # Address
* Hex Dec Hex Dec
* 40-FF 64-255 100-3FC 256-1020
*
* To calculate the offset within the .evt section to place your vector, use
* the following calculation (assuming vector number = 0x50):
*
* 0x50 * 4 = 0x140
*
* You could then place your vector at that position in the vector table as
* follows:
*
* . = 0x140;
* LONG(ABSOLUTE(NameOfHandlerFunction));
*/
} > evt
.text : {
_text_start = .;
*(.text .text.*)
. = ALIGN(0x10);
_text_end = .;
} > text
.rodata : AT(_text_end) {
_rodata_start = .;
*(.rodata .rodata.*)
. = ALIGN(0x10);
_rodata_end = .;
} > text
.data : AT(_rodata_end) {
_data_start = .;
*(.data .data.*)
. = ALIGN(0x10);
_data_end = .;
} > data
.iomem (NOLOAD) : {
} > iomem
.bss : {
_bss_start = .;
*(.bss .bss.*)
*(COMMON)
. = ALIGN(0x10);
_bss_end = .;
} > data
.heap : {
_heap_start = .;
. += (_ram_sz - _stack_sz - SIZEOF(.bss) - SIZEOF(.data));
_heap_end = .;
} > data
.stack : {
_stack_start = .;
. += _stack_sz;
_stack_end = .;
} > data
}