Can't query entity using :db/id attribute

[nahuel]

Example:

(let [db                (d/create-conn {})
      {:keys [tempids]} (d/transact! db [{:db/id -1
                                          :name "Mazinger"}])
      new-id            (get tempids -1)]
  (println :entity  (-> @db (d/entity new-id) d/touch))
  (println :by-id   (d/q `[:find ?e
                           :where [?e :db/id ~new-id]]   @db))
  (println :by-name (d/q `[:find ?e
                           :where [?e :name "Mazinger"]] @db)))

;; Output:
:entity {:name Mazinger, :db/id 1}
:by-id #{}  ;; <-- why?
:by-name #{[1]}

Entity is not returned when querying using :db/id. Is this a limitation by design or a bug?

[tonsky]

@nahuel,

:db/id is not a real attribute. It is used to create “map” forms of an entity at insert stage. When you write

(d/transact! db [{:db/id -1 :name "Mazinger"}]

it means, essentially, this: take all key-value pairs from this map, convert them to [:db/add eid attr value] form where attr=key from map, value=value from map, and eid (entity id) is a special key :db/id from map. It’s just a convention. Results from entity calls support this convention too, as they have to represent datoms as maps.

But inside DataScript everything is stored as flat datoms of form [e a v], no maps. If your entity has 10 attributes, there’ll be 10 distinct datoms. Maps are just a convenient view of these internals.

Queries are written in pattern-match style over actual flat datoms, so you cannot use :db/id as it is not an actual datom attribute. When matching over entity id, just use first position, not last one:

(d/q `[:find ?name
       :where [~new-id :name ?name]] @db)

BTW it’s not recommended to use actual values inside query. For parametrized queries, use addtional :in agruments:

(d/q '[:find ?name
       :in $ ?e
       :where [?e :name ?name]] @db new-id)

[nahuel]

Now it's crystal clear, many thanks for the detailed response!