publish.gradle

apply plugin: "maven-publish"
apply plugin: "signing"

ext.projectName = "idempotence4j"
ext.projectDescription = "Lightweight library for handling idempotent actions"
ext.projectScmUrl = "https://github.com/transferwise/${projectName}"
ext.projectScmConnection = "scm:git:git://github.com/transferwise/${projectName}.git"

java {
	withSourcesJar()
	withJavadocJar()
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java

            pom {
                name = projectName
                description = projectDescription
                url = projectScmUrl
                packaging = "jar"
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0, Copyright 2020 TransferWise Ltd'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'pturovsk'
                        name = 'Petro Turovskyy'
                        email = "petro.turovskyy@transferwise.com"
                        organization = "Transferwise Ltd"
                        organizationUrl = "https://github.com/transferwise"
                    }
                }
                scm {
                    connection = projectScmConnection
                    developerConnection = projectScmConnection
                    url = projectScmUrl
                }
            }
        }
    }

    signing {
		def signingKey = System.env.OSS_SIGNING_KEY as String
		def signingPassword = System.env.OSS_SIGNING_PASSWORD as String

		if (signingKey && signingPassword) {
			useInMemoryPgpKeys(signingKey, signingPassword)
            sign publishing.publications.mavenJava
		}
	}

	repositories {
		maven {
			url System.env.MAVEN_URL as String
			credentials {
				username = System.env.MAVEN_USER as String
				password = System.env.MAVEN_PASSWORD as String
			}
		}
        mavenLocal()
	}
}