-
Notifications
You must be signed in to change notification settings - Fork 5
/
ArrayHlp.pas
311 lines (265 loc) · 8.51 KB
/
ArrayHlp.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
unit ArrayHlp;
////////////////////////////////////////////////////////////////////////////////
//
// Author: Jaap Baak
// https://github.com/transportmodelling/Utils
//
////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////
interface
////////////////////////////////////////////////////////////////////////////////
Uses
SysUtils,Math,System.Generics.Collections;
Type
TIntArrayHelper = record helper for TArray<Integer>
private
Function GetLength: Integer; inline;
Procedure SetLength(Length: Integer); inline;
public
Constructor Create(const Values: array of Integer); overload;
Constructor Create(const Length: Integer; Value: Integer = 0); overload;
Function ToString(const Separator: Char = ','): String;
Procedure Initialize(Value: Integer);
Procedure Assign(const Values: array of Integer);
Procedure AssignTo(var Value0, Value1: Integer); overload;
Procedure AssignTo(var Value0, Value1, Value2: Integer); overload;
Procedure AssignTo(var Values: array of Integer); overload;
Procedure Append(const Values: array of Integer);
Function Contains(Value: Integer): Boolean;
Function MinValue: Integer;
Function MaxValue: Integer;
Function Total: Integer;
Procedure Sort;
public
Property Length: Integer read GetLength write SetLength;
end;
TFloat64ArrayHelper = record helper for TArray<Float64>
private
Function GetLength: Integer; inline;
Procedure SetLength(Length: Integer); inline;
public
Constructor Create(const Values: array of Float64); overload;
Constructor Create(const Length: Integer; Value: Float64 = 0.0); overload;
Function ToString(const Format: String; const Separator: Char = ','): String;
Procedure Initialize(Value: Float64);
Procedure Assign(const Values: array of Float64);
Procedure AssignTo(var Value0, Value1: Float64); overload;
Procedure AssignTo(var Value0, Value1, Value2: Float64); overload;
Procedure AssignTo(var Values: array of Float64); overload;
Procedure Append(const Values: array of Float64);
Function MinValue: Float64;
Function MaxValue: Float64;
Function Total: Float64;
public
Property Length: Integer read GetLength write SetLength;
end;
TStringArrayHelper = record helper for TArray<String>
private
Function GetLength: Integer; inline;
Procedure SetLength(Length: Integer); inline;
public
Constructor Create(const Values: array of String);
Procedure Assign(const Values: array of String);
Procedure Append(const Values: array of String);
public
Property Length: Integer read GetLength write SetLength;
end;
////////////////////////////////////////////////////////////////////////////////
implementation
////////////////////////////////////////////////////////////////////////////////
Constructor TIntArrayHelper.Create(const Values: array of Integer);
begin
Assign(Values)
end;
Constructor TIntArrayHelper.Create(const Length: Integer; Value: Integer = 0);
begin
System.SetLength(Self,Length);
for var Index := 0 to Length-1 do Self[Index] := Value;
end;
Function TIntArrayHelper.ToString(const Separator: Char = ','): String;
begin
if Self.Length > 0 then
begin
Result := Self[0].ToString;
for var Index := 1 to Length-1 do Result := Result + Separator + Self[Index].ToString;
end else
Result := '';
end;
Function TIntArrayHelper.GetLength: Integer;
begin
Result := System.Length(Self);
end;
Procedure TIntArrayHelper.SetLength(Length: Integer);
begin
System.SetLength(Self,Length);
end;
Procedure TIntArrayHelper.Initialize(Value: Integer);
begin
for var Index := 0 to Length-1 do Self[Index] := Value;
end;
Procedure TIntArrayHelper.Assign(const Values: array of Integer);
begin
Length := System.Length(Values);
for var Index := 0 to Length-1 do Self[Index] := Values[Index];
end;
Procedure TIntArrayHelper.AssignTo(var Value0, Value1: Integer);
begin
if Length = 2 then
begin
Value0 := Self[0];
Value1 := Self[1];
end else
raise Exception.Create('Invalid length');
end;
Procedure TIntArrayHelper.AssignTo(var Value0, Value1, Value2: Integer);
begin
if Length = 3 then
begin
Value0 := Self[0];
Value1 := Self[1];
Value2 := Self[2];
end else
raise Exception.Create('Invalid length');
end;
Procedure TIntArrayHelper.AssignTo(var Values: array of Integer);
begin
if Length = System.Length(Values) then
for var Index := 0 to Length-1 do Values[Index] := Self[Index]
else
raise Exception.Create('Invalid length');
end;
Procedure TIntArrayHelper.Append(const Values: array of Integer);
begin
var Offset := Length;
Length := Offset + System.Length(Values);
for var Index := Offset to Length-1 do Self[Index] := Values[Index-Offset];
end;
Function TIntArrayHelper.Contains(Value: Integer): Boolean;
begin
Result := false;
for var Index := 0 to Length-1 do
if Self[Index] = Value then Exit(true);
end;
Function TIntArrayHelper.MinValue: Integer;
begin
Result := MinIntValue(Self);
end;
Function TIntArrayHelper.MaxValue: Integer;
begin
Result := MaxIntValue(Self);
end;
Function TIntArrayHelper.Total: Integer;
begin
Result := 0;
for var Index := 0 to Length-1 do Result := Result + Self[Index];
end;
Procedure TIntArrayHelper.Sort;
begin
System.Generics.Collections.TArray.Sort<Integer>(Self);
end;
////////////////////////////////////////////////////////////////////////////////
Constructor TFloat64ArrayHelper.Create(const Values: array of Float64);
begin
Assign(Values)
end;
Constructor TFloat64ArrayHelper.Create(const Length: Integer; Value: Float64 = 0.0);
begin
System.SetLength(Self,Length);
for var Index := 0 to Length-1 do Self[Index] := Value;
end;
Function TFloat64ArrayHelper.ToString(const Format: String; const Separator: Char = ','): String;
begin
if Self.Length > 0 then
begin
Result := FormatFloat(Format,Self[0]);
for var Index := 1 to Length-1 do Result := Result + Separator + FormatFloat(Format,Self[Index]);
end else
Result := '';
end;
Function TFloat64ArrayHelper.GetLength: Integer;
begin
Result := System.Length(Self);
end;
Procedure TFloat64ArrayHelper.SetLength(Length: Integer);
begin
System.SetLength(Self,Length);
end;
Procedure TFloat64ArrayHelper.Initialize(Value: Float64);
begin
for var Index := 0 to Length-1 do Self[Index] := Value;
end;
Procedure TFloat64ArrayHelper.Assign(const Values: array of Float64);
begin
Length := System.Length(Values);
for var Index := 0 to Length-1 do Self[Index] := Values[Index];
end;
Procedure TFloat64ArrayHelper.AssignTo(var Value0, Value1: Float64);
begin
if Length = 2 then
begin
Value0 := Self[0];
Value1 := Self[1];
end else
raise Exception.Create('Invalid length');
end;
Procedure TFloat64ArrayHelper.AssignTo(var Value0, Value1, Value2: Float64);
begin
if Length = 3 then
begin
Value0 := Self[0];
Value1 := Self[1];
Value2 := Self[2];
end else
raise Exception.Create('Invalid length');
end;
Procedure TFloat64ArrayHelper.AssignTo(var Values: array of Float64);
begin
if Length = System.Length(Values) then
for var Index := 0 to Length-1 do Values[Index] := Self[Index]
else
raise Exception.Create('Invalid length');
end;
Procedure TFloat64ArrayHelper.Append(const Values: array of Float64);
begin
var Offset := Length;
Length := Offset + System.Length(Values);
for var Index := Offset to Length-1 do Self[Index] := Values[Index-Offset];
end;
Function TFloat64ArrayHelper.MinValue: Float64;
begin
Result := Math.MinValue(Self);
end;
Function TFloat64ArrayHelper.MaxValue: Float64;
begin
Result := Math.MaxValue(Self);
end;
Function TFloat64ArrayHelper.Total: Float64;
begin
Result := 0.0;
for var Index := 0 to Length-1 do Result := Result + Self[Index];
end;
////////////////////////////////////////////////////////////////////////////////
Constructor TStringArrayHelper.Create(const Values: array of String);
begin
Assign(Values)
end;
Function TStringArrayHelper.GetLength: Integer;
begin
Result := System.Length(Self);
end;
Procedure TStringArrayHelper.SetLength(Length: Integer);
begin
System.SetLength(Self,Length);
end;
Procedure TStringArrayHelper.Assign(const Values: array of String);
begin
Length := System.Length(Values);
for var Index := 0 to Length-1 do Self[Index] := Values[Index];
end;
Procedure TStringArrayHelper.Append(const Values: array of String);
begin
var Offset := Length;
Length := Offset + System.Length(Values);
for var Index := Offset to Length-1 do Self[Index] := Values[Index-Offset];
end;
end.