-
Notifications
You must be signed in to change notification settings - Fork 33
/
pgw_s5s8.erl
1385 lines (1174 loc) · 54.1 KB
/
pgw_s5s8.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%% Copyright 2015, Travelping GmbH <info@travelping.com>
%% This program is free software; you can redistribute it and/or
%% modify it under the terms of the GNU General Public License
%% as published by the Free Software Foundation; either version
%% 2 of the License, or (at your option) any later version.
-module(pgw_s5s8).
-behaviour(gtp_api).
-compile([{parse_transform, do},
{parse_transform, cut}]).
-export([validate_options/1, init/2, request_spec/3,
handle_pdu/4, handle_sx_report/3,
handle_request/5, handle_response/5,
handle_event/4, terminate/3]).
%% shared API's
-export([init_session/3, init_session_from_gtp_req/4]).
-include_lib("kernel/include/logger.hrl").
-include_lib("gtplib/include/gtp_packet.hrl").
-include_lib("pfcplib/include/pfcp_packet.hrl").
-include_lib("diameter/include/diameter_gen_base_rfc6733.hrl").
-include_lib("ergw_aaa/include/diameter_3gpp_ts29_212.hrl").
-include_lib("ergw_aaa/include/ergw_aaa_session.hrl").
-include("include/ergw.hrl").
-import(ergw_aaa_session, [to_session/1]).
-define(GTP_v1_Interface, ggsn_gn).
-define(T3, 10 * 1000).
-define(N3, 5).
%%====================================================================
%% API
%%====================================================================
-define('Cause', {v2_cause, 0}).
-define('Recovery', {v2_recovery, 0}).
-define('IMSI', {v2_international_mobile_subscriber_identity, 0}).
-define('MSISDN', {v2_msisdn, 0}).
-define('PDN Address Allocation', {v2_pdn_address_allocation, 0}).
-define('RAT Type', {v2_rat_type, 0}).
-define('Sender F-TEID for Control Plane', {v2_fully_qualified_tunnel_endpoint_identifier, 0}).
-define('Access Point Name', {v2_access_point_name, 0}).
-define('Bearer Contexts to be created', {v2_bearer_context, 0}).
-define('Bearer Contexts to be modified', {v2_bearer_context, 0}).
-define('Protocol Configuration Options', {v2_protocol_configuration_options, 0}).
-define('ME Identity', {v2_mobile_equipment_identity, 0}).
-define('APN-AMBR', {v2_aggregate_maximum_bit_rate, 0}).
-define('Bearer Level QoS', {v2_bearer_level_quality_of_service, 0}).
-define('EPS Bearer ID', {v2_eps_bearer_id, 0}).
-define('SGW-U node name', {v2_fully_qualified_domain_name, 0}).
-define('Secondary RAT Usage Data Report', {v2_secondary_rat_usage_data_report, 0}).
-define('S5/S8-U SGW', 4).
-define('S5/S8-U PGW', 5).
-define('S5/S8-C SGW', 6).
-define('S5/S8-C PGW', 7).
-define(ABORT_CTX_REQUEST(Context, Request, Type, Cause),
begin
AbortReply = response(Type, Context, [#v2_cause{v2_cause = Cause}], Request),
throw(?CTX_ERR(?FATAL, AbortReply, Context))
end).
-define(CAUSE_OK(Cause), (Cause =:= request_accepted orelse
Cause =:= request_accepted_partially orelse
Cause =:= new_pdp_type_due_to_network_preference orelse
Cause =:= new_pdp_type_due_to_single_address_bearer_only)).
request_spec(v1, Type, Cause) ->
?GTP_v1_Interface:request_spec(v1, Type, Cause);
request_spec(v2, _Type, Cause)
when Cause /= undefined andalso not ?CAUSE_OK(Cause) ->
[];
request_spec(v2, create_session_request, _) ->
[{?'RAT Type', mandatory},
{?'Sender F-TEID for Control Plane', mandatory},
{?'Access Point Name', mandatory},
{?'APN-AMBR' , mandatory},
{?'Bearer Contexts to be created', mandatory}];
request_spec(v2, delete_session_request, _) ->
[];
request_spec(v2, modify_bearer_request, _) ->
[];
request_spec(v2, modify_bearer_command, _) ->
[{?'APN-AMBR' , mandatory},
{?'Bearer Contexts to be modified', mandatory}];
request_spec(v2, resume_notification, _) ->
[{?'IMSI', mandatory}];
request_spec(v2, _, _) ->
[].
validate_options(Options) ->
?LOG(debug, "GGSN S5/S8 Options: ~p", [Options]),
gtp_context:validate_options(fun validate_option/2, Options, []).
validate_option(Opt, Value) ->
gtp_context:validate_option(Opt, Value).
init(_Opts, Data) ->
{ok, Session} = ergw_aaa_session_sup:new_session(self(), to_session([])),
SessionOpts = ergw_aaa_session:get(Session),
OCPcfg = maps:get('Offline-Charging-Profile', SessionOpts, #{}),
PCC = #pcc_ctx{offline_charging_profile = OCPcfg},
{ok, run, Data#{'Version' => v2, 'Session' => Session, pcc => PCC}}.
handle_event(Type, Content, State, #{'Version' := v1} = Data) ->
?GTP_v1_Interface:handle_event(Type, Content, State, Data);
handle_event(enter, _OldState, _State, _Data) ->
keep_state_and_data;
handle_event({call, From}, delete_context, run, Data) ->
delete_context(From, administrative, Data);
handle_event({call, From}, delete_context, shutdown, _Data) ->
{keep_state_and_data, [{reply, From, {ok, ok}}]};
handle_event({call, _From}, delete_context, _State, _Data) ->
{keep_state_and_data, [postpone]};
handle_event({call, From}, terminate_context, _State, Data) ->
close_pdn_context(normal, Data),
{next_state, shutdown, Data, [{reply, From, ok}]};
handle_event({call, From}, {path_restart, Path}, _State,
#{context := #context{path = Path}} = Data) ->
close_pdn_context(normal, Data),
{next_state, shutdown, Data, [{reply, From, ok}]};
handle_event({call, From}, {path_restart, _Path}, _State, _Data) ->
{keep_state_and_data, [{reply, From, ok}]};
handle_event(cast, {defered_usage_report, URRActions, UsageReport}, _State,
#{pfcp := PCtx, 'Session' := Session}) ->
Now = erlang:monotonic_time(),
case proplists:get_value(offline, URRActions) of
{ChargeEv, OldS} ->
{_Online, Offline, _} =
ergw_gsn_lib:usage_report_to_charging_events(UsageReport, ChargeEv, PCtx),
ergw_gsn_lib:process_offline_charging_events(ChargeEv, Offline, Now, OldS, Session);
_ ->
ok
end,
keep_state_and_data;
handle_event(cast, delete_context, run, Data) ->
delete_context(undefined, administrative, Data);
handle_event(cast, delete_context, _State, _Data) ->
keep_state_and_data;
handle_event(cast, {packet_in, _GtpPort, _IP, _Port, _Msg}, _State, _Data) ->
?LOG(warning, "packet_in not handled (yet): ~p", [_Msg]),
keep_state_and_data;
handle_event(info, {'DOWN', _MonitorRef, Type, Pid, _Info}, _State,
#{pfcp := #pfcp_ctx{node = Pid}} = Data)
when Type == process; Type == pfcp ->
close_pdn_context(upf_failure, Data),
{next_state, shutdown, Data};
handle_event(info, #aaa_request{procedure = {_, 'ASR'}} = Request, run, Data) ->
ergw_aaa_session:response(Request, ok, #{}, #{}),
delete_context(undefined, administrative, Data);
handle_event(info, #aaa_request{procedure = {_, 'ASR'}} = Request, _State, _Data) ->
ergw_aaa_session:response(Request, ok, #{}, #{}),
keep_state_and_data;
handle_event(info, #aaa_request{procedure = {gx, 'RAR'},
events = Events} = Request,
run,
#{context := Context, pfcp := PCtx0,
'Session' := Session, pcc := PCC0} = Data) ->
%%% 1. update PCC
%%% a) calculate PCC rules to be removed
%%% b) calculate PCC rules to be installed
%%% 2. figure out which Rating-Groups are new or which ones have to be removed
%%% based on updated PCC rules
%%% 3. remove PCC rules and unsused Rating-Group URRs from UPF
%%% 4. on Gy:
%%% - report removed URRs/RGs
%%% - request credits for new URRs/RGs
%%% 5. apply granted quotas to PCC rules, remove PCC rules without quotas
%%% 6. install new PCC rules which have granted quota
%%% 7. report remove and not installed (lack of quota) PCC rules on Gx
Now = erlang:monotonic_time(),
ReqOps = #{now => Now},
RuleBase = ergw_charging:rulebase(),
%%% step 1a:
{PCC1, _} =
ergw_gsn_lib:gx_events_to_pcc_ctx(Events, remove, RuleBase, PCC0),
%%% step 1b:
{PCC2, PCCErrors2} =
ergw_gsn_lib:gx_events_to_pcc_ctx(Events, install, RuleBase, PCC1),
%%% step 2
%%% step 3:
{PCtx1, UsageReport} =
ergw_gsn_lib:modify_sgi_session(PCC1, [], #{}, Context, PCtx0),
%%% step 4:
ChargeEv = {online, 'RAR'}, %% made up value, not use anywhere...
{Online, Offline, Monitor} =
ergw_gsn_lib:usage_report_to_charging_events(UsageReport, ChargeEv, PCtx1),
ergw_gsn_lib:process_accounting_monitor_events(ChargeEv, Monitor, Now, Session),
GyReqServices = ergw_gsn_lib:gy_credit_request(Online, PCC0, PCC2),
{ok, _, GyEvs} =
ergw_gsn_lib:process_online_charging_events(ChargeEv, GyReqServices, Session, ReqOps),
ergw_gsn_lib:process_offline_charging_events(ChargeEv, Offline, Now, Session),
%%% step 5:
{PCC4, PCCErrors4} = ergw_gsn_lib:gy_events_to_pcc_ctx(Now, GyEvs, PCC2),
%%% step 6:
{PCtx, _} =
ergw_gsn_lib:modify_sgi_session(PCC4, [], #{}, Context, PCtx1),
%%% step 7:
%% TODO Charging-Rule-Report for successfully installed/removed rules
GxReport = ergw_gsn_lib:pcc_events_to_charging_rule_report(PCCErrors2 ++ PCCErrors4),
ergw_aaa_session:response(Request, ok, GxReport, #{}),
{keep_state, Data#{pfcp := PCtx, pcc := PCC4}};
handle_event(info, #aaa_request{procedure = {gy, 'RAR'},
events = Events} = Request,
run, Data) ->
ergw_aaa_session:response(Request, ok, #{}, #{}),
Now = erlang:monotonic_time(),
%% Triggered CCR.....
ChargingKeys =
case proplists:get_value(report_rating_group, Events) of
RatingGroups when is_list(RatingGroups) ->
[{online, RG} || RG <- RatingGroups];
_ ->
undefined
end,
triggered_charging_event(interim, Now, ChargingKeys, Data),
keep_state_and_data;
handle_event(info, #aaa_request{procedure = {_, 'RAR'}} = Request, _State, _Data) ->
ergw_aaa_session:response(Request, {error, unknown_session}, #{}, #{}),
keep_state_and_data;
handle_event(info, {pfcp_timer, #{validity_time := ChargingKeys}}, _State, Data) ->
Now = erlang:monotonic_time(),
triggered_charging_event(validity_time, Now, ChargingKeys, Data),
keep_state_and_data;
handle_event(info, _Info, _State, _Data) ->
keep_state_and_data;
handle_event({timeout, context_idle}, stop_session, _state, Data) ->
delete_context(undefined, normal, Data);
handle_event(internal, {session, stop, _Session}, run, Data) ->
delete_context(undefined, normal, Data);
handle_event(internal, {session, stop, _Session}, _, _) ->
keep_state_and_data;
handle_event(internal, {session, {update_credits, _} = CreditEv, _}, _State,
#{context := Context, pfcp := PCtx0, pcc := PCC0} = Data) ->
Now = erlang:monotonic_time(),
{PCC, _PCCErrors} = ergw_gsn_lib:gy_events_to_pcc_ctx(Now, [CreditEv], PCC0),
{PCtx, _} =
ergw_gsn_lib:modify_sgi_session(PCC, [], #{}, Context, PCtx0),
{keep_state, Data#{pfcp := PCtx, pcc := PCC}};
handle_event(internal, {session, Ev, _}, _State, _Data) ->
?LOG(error, "unhandled session event: ~p", [Ev]),
keep_state_and_data;
handle_event(cast, Ev, _State, _Data)
when is_tuple(Ev), element(1, Ev) =:= '$' ->
%% late async events, just ignore them...
?LOG(debug, "late event: ~p", [Ev]),
keep_state_and_data.
handle_pdu(ReqKey, #gtp{ie = PDU} = Msg, _State,
#{context := Context, pfcp := PCtx} = Data) ->
?LOG(debug, "GTP-U PGW: ~p, ~p", [ReqKey, gtp_c_lib:fmt_gtp(Msg)]),
ergw_gsn_lib:ip_pdu(PDU, Context, PCtx),
{keep_state, Data}.
handle_sx_report(#pfcp{type = session_report_request,
ie = #{report_type := #report_type{erir = 1}}},
_State, Data) ->
close_pdn_context(normal, Data),
{shutdown, Data};
%% User Plane Inactivity Timer expired
handle_sx_report(#pfcp{type = session_report_request,
ie = #{report_type := #report_type{upir = 1}}},
_State, Data) ->
close_pdn_context(normal, Data),
{shutdown, Data};
handle_sx_report(Report, State, Data) ->
?GTP_v1_Interface:handle_sx_report(Report, State, Data).
defered_usage_report(Server, URRActions, Report) ->
gen_statem:cast(Server, {defered_usage_report, URRActions, Report}).
%% API Message Matrix:
%%
%% SGSN/MME/ TWAN/ePDG to PGW (S4/S11, S5/S8, S2a, S2b)
%%
%% Create Session Request/Response
%% Delete Session Request/Response
%%
%% SGSN/MME/ePDG to PGW (S4/S11, S5/S8, S2b)
%%
%% Modify Bearer Request/Response
%%
%% SGSN/MME to PGW (S4/S11, S5/S8)
%%
%% Change Notification Request/Response
%% Resume Notification/Acknowledge
handle_request(ReqKey, #gtp{version = v1} = Msg, Resent, State, Data) ->
?GTP_v1_Interface:handle_request(ReqKey, Msg, Resent, State, Data#{'Version' => v1});
handle_request(ReqKey, #gtp{version = v2} = Msg, Resent, State, #{'Version' := v1} = Data) ->
handle_request(ReqKey, Msg, Resent, State, Data#{'Version' => v2});
handle_request(_ReqKey, _Msg, true, _State, _Data) ->
%% resent request
keep_state_and_data;
handle_request(ReqKey,
#gtp{type = create_session_request,
ie = #{?'Sender F-TEID for Control Plane' := FqCntlTEID,
?'Access Point Name' := #v2_access_point_name{apn = APN},
?'Bearer Contexts to be created' :=
#v2_bearer_context{
group = #{
?'EPS Bearer ID' := EBI,
{v2_fully_qualified_tunnel_endpoint_identifier, 2} :=
%% S5/S8 SGW GTP-U Interface
#v2_fully_qualified_tunnel_endpoint_identifier{interface_type = ?'S5/S8-U SGW'} =
FqDataTEID
}}
} = IEs} = Request,
_Resent, _State,
#{context := Context0, aaa_opts := AAAopts, node_selection := NodeSelect,
'Session' := Session, pcc := PCC0} = Data) ->
APN_FQDN = ergw_node_selection:apn_to_fqdn(APN),
Services = [{"x-3gpp-upf", "x-sxb"}],
SGWuNode =
case IEs of
#{?'SGW-U node name' := #v2_fully_qualified_domain_name{fqdn = SGWuFQDN}} ->
SGWuFQDN;
_ -> []
end,
Candidates = ergw_node_selection:topology_select(APN_FQDN, SGWuNode, Services, NodeSelect),
SxConnectId = ergw_sx_node:request_connect(Candidates, NodeSelect, 1000),
Context1 = update_context_tunnel_ids(FqCntlTEID, FqDataTEID, Context0),
Context2 = update_context_from_gtp_req(Request, Context1),
ContextPreAuth = gtp_path:bind(Request, false, Context2),
gtp_context:terminate_colliding_context(ContextPreAuth),
PAA = maps:get(?'PDN Address Allocation', IEs, undefined),
DAF = proplists:get_bool('DAF', gtp_v2_c:get_indication_flags(IEs)),
SessionOpts0 = init_session(IEs, ContextPreAuth, AAAopts),
SessionOpts1 = init_session_from_gtp_req(IEs, AAAopts, ContextPreAuth, SessionOpts0),
%% SessionOpts = init_session_qos(ReqQoSProfile, SessionOpts1),
ergw_sx_node:wait_connect(SxConnectId),
{UPinfo0, ContextUP} = ergw_gsn_lib:select_upf(Candidates, ContextPreAuth),
SessionOpts = ergw_gsn_lib:init_session_ip_opts(UPinfo0, ContextUP, SessionOpts1),
{ok, ActiveSessionOpts0, AuthSEvs} =
authenticate(ContextUP, Session, SessionOpts, Request),
{PendingPCtx, NodeCaps, APNOpts, ContextVRF} =
ergw_gsn_lib:reselect_upf(Candidates, ActiveSessionOpts0, ContextUP, UPinfo0),
{Result, ActiveSessionOpts1, ContextPending1} =
allocate_ips(APNOpts, ActiveSessionOpts0, PAA, DAF, ContextVRF),
{ContextPending, ActiveSessionOpts} =
add_apn_timeout(APNOpts, ActiveSessionOpts1, ContextPending1),
ergw_aaa_session:set(Session, ActiveSessionOpts),
Now = erlang:monotonic_time(),
SOpts = #{now => Now},
GxOpts = #{'Event-Trigger' => ?'DIAMETER_GX_EVENT-TRIGGER_UE_IP_ADDRESS_ALLOCATE',
'Bearer-Operation' => ?'DIAMETER_GX_BEARER-OPERATION_ESTABLISHMENT'},
{ok, _, GxEvents} =
ccr_initial(ContextPending, Session, gx, GxOpts, SOpts, Request),
RuleBase = ergw_charging:rulebase(),
{PCC1, PCCErrors1} =
ergw_gsn_lib:gx_events_to_pcc_ctx(GxEvents, '_', RuleBase, PCC0),
case ergw_gsn_lib:pcc_ctx_has_rules(PCC1) of
false ->
?ABORT_CTX_REQUEST(ContextPending, Request, create_session_response,
user_authentication_failed);
true ->
ok
end,
%% TBD............
CreditsAdd = ergw_gsn_lib:pcc_ctx_to_credit_request(PCC1),
GyReqServices = #{credits => CreditsAdd},
{ok, GySessionOpts, GyEvs} =
ccr_initial(ContextPending, Session, gy, GyReqServices, SOpts, Request),
?LOG(debug, "GySessionOpts: ~p", [GySessionOpts]),
?LOG(debug, "Initial GyEvs: ~p", [GyEvs]),
ergw_aaa_session:invoke(Session, #{}, start, SOpts),
{_, _, RfSEvs} = ergw_aaa_session:invoke(Session, #{}, {rf, 'Initial'}, SOpts),
{PCC2, PCCErrors2} = ergw_gsn_lib:gy_events_to_pcc_ctx(Now, GyEvs, PCC1),
PCC3 = ergw_gsn_lib:session_events_to_pcc_ctx(AuthSEvs, PCC2),
PCC4 = ergw_gsn_lib:session_events_to_pcc_ctx(RfSEvs, PCC3),
{Context, PCtx} =
ergw_gsn_lib:create_sgi_session(PendingPCtx, NodeCaps, PCC4, ContextPending),
gtp_context:remote_context_register_new(Context),
GxReport = ergw_gsn_lib:pcc_events_to_charging_rule_report(PCCErrors1 ++ PCCErrors2),
if map_size(GxReport) /= 0 ->
ergw_aaa_session:invoke(Session, GxReport,
{gx, 'CCR-Update'}, SOpts#{async => true});
true ->
ok
end,
ResponseIEs = create_session_response(Result, ActiveSessionOpts, IEs, EBI, Context),
Response = response(create_session_response, Context, ResponseIEs, Request),
gtp_context:send_response(ReqKey, Request, Response),
Actions = context_idle_action([], Context),
{keep_state, Data#{context => Context, pfcp => PCtx, pcc => PCC4}, Actions};
handle_request(ReqKey,
#gtp{type = modify_bearer_request,
ie = #{?'Bearer Contexts to be modified' :=
#v2_bearer_context{
group = #{
?'EPS Bearer ID' := EBI,
{v2_fully_qualified_tunnel_endpoint_identifier, 1} :=
%% S5/S8 SGW GTP-U Interface
#v2_fully_qualified_tunnel_endpoint_identifier{interface_type = ?'S5/S8-U SGW'} =
FqDataTEID
}}
} = IEs} = Request,
_Resent, _State,
#{context := OldContext, pfcp := PCtx, 'Session' := Session} = Data0) ->
process_secondary_rat_usage_data_reports(IEs, OldContext, Session),
FqCntlTEID = maps:get(?'Sender F-TEID for Control Plane', IEs, undefined),
Context0 = update_context_tunnel_ids(FqCntlTEID, FqDataTEID, OldContext),
Context1 = update_context_from_gtp_req(Request, Context0),
Context = gtp_path:bind(Request, false, Context1),
URRActions = update_session_from_gtp_req(IEs, Session, Context),
Data1 = if Context /= OldContext ->
gtp_context:remote_context_update(OldContext, Context),
apply_context_change(Context, OldContext, URRActions, Data0);
true ->
trigger_defered_usage_report(URRActions, PCtx),
Data0
end,
ResponseIEs0 =
if FqCntlTEID /= undefined ->
%% take the presens of the FQ-TEID element as SGW change indication
%%
%% 3GPP TS 29.274, Sect. 7.2.7 Modify Bearer Request says that we should
%% consider the content as well, but in practice that is not stable enough
%% in the presense of middle boxes between the SGW and the PGW
%%
[EBI, %% Linked EPS Bearer ID
#v2_apn_restriction{restriction_type_value = 0},
context_charging_id(Context) |
[#v2_msisdn{msisdn = Context#context.msisdn} || Context#context.msisdn /= undefined]];
true ->
[]
end,
ResponseIEs = [#v2_cause{v2_cause = request_accepted},
#v2_bearer_context{
group=[#v2_cause{v2_cause = request_accepted},
context_charging_id(Context),
EBI]} |
ResponseIEs0],
Response = response(modify_bearer_response, Context, ResponseIEs, Request),
gtp_context:send_response(ReqKey, Request, Response),
Actions = context_idle_action([], Context),
{keep_state, Data1, Actions};
handle_request(ReqKey,
#gtp{type = modify_bearer_request, ie = IEs} = Request,
_Resent, _State,
#{context := OldContext, pfcp := PCtx,
'Session' := Session} = Data) ->
process_secondary_rat_usage_data_reports(IEs, OldContext, Session),
Context = update_context_from_gtp_req(Request, OldContext),
URRActions = update_session_from_gtp_req(IEs, Session, Context),
trigger_defered_usage_report(URRActions, PCtx),
ResponseIEs = [#v2_cause{v2_cause = request_accepted}],
Response = response(modify_bearer_response, Context, ResponseIEs, Request),
gtp_context:send_response(ReqKey, Request, Response),
Actions = context_idle_action([], Context),
{keep_state, Data#{context => Context}, Actions};
handle_request(#request{gtp_port = GtpPort, ip = SrcIP, port = SrcPort} = ReqKey,
#gtp{type = modify_bearer_command,
seq_no = SeqNo,
ie = #{?'APN-AMBR' := AMBR,
?'Bearer Contexts to be modified' :=
#v2_bearer_context{
group = #{?'EPS Bearer ID' := EBI} = Bearer}} = IEs},
_Resent, _State,
#{context := Context, pfcp := PCtx, 'Session' := Session}) ->
URRActions = update_session_from_gtp_req(IEs, Session, Context),
trigger_defered_usage_report(URRActions, PCtx),
Type = update_bearer_request,
RequestIEs0 = [AMBR,
#v2_bearer_context{
group = copy_ies_to_response(Bearer, [EBI], [?'Bearer Level QoS'])}],
RequestIEs = gtp_v2_c:build_recovery(Type, Context, false, RequestIEs0),
Msg = msg(Context, Type, RequestIEs),
send_request(GtpPort, SrcIP, SrcPort, ?T3, ?N3, Msg#gtp{seq_no = SeqNo}, ReqKey),
Actions = context_idle_action([], Context),
{keep_state_and_data, Actions};
handle_request(ReqKey,
#gtp{type = change_notification_request, ie = IEs} = Request,
_Resent, _State,
#{context := OldContext, pfcp := PCtx,
'Session' := Session} = Data) ->
process_secondary_rat_usage_data_reports(IEs, OldContext, Session),
Context = update_context_from_gtp_req(Request, OldContext),
URRActions = update_session_from_gtp_req(IEs, Session, Context),
trigger_defered_usage_report(URRActions, PCtx),
ResponseIEs0 = [#v2_cause{v2_cause = request_accepted}],
ResponseIEs = copy_ies_to_response(IEs, ResponseIEs0, [?'IMSI', ?'ME Identity']),
Response = response(change_notification_response, Context, ResponseIEs, Request),
gtp_context:send_response(ReqKey, Request, Response),
Actions = context_idle_action([], Context),
{keep_state, Data#{context => Context}, Actions};
handle_request(ReqKey,
#gtp{type = suspend_notification} = Request,
_Resent, _State, #{context := Context} = Data) ->
%% don't do anything special for now
ResponseIEs = [#v2_cause{v2_cause = request_accepted}],
Response = response(suspend_acknowledge, Context, ResponseIEs, Request),
gtp_context:send_response(ReqKey, Request, Response),
Actions = context_idle_action([], Context),
{keep_state, Data#{context => Context}, Actions};
handle_request(ReqKey,
#gtp{type = resume_notification} = Request,
_Resent, _State, #{context := Context} = Data) ->
%% don't do anything special for now
ResponseIEs = [#v2_cause{v2_cause = request_accepted}],
Response = response(resume_acknowledge, Context, ResponseIEs, Request),
gtp_context:send_response(ReqKey, Request, Response),
Actions = context_idle_action([], Context),
{keep_state, Data#{context => Context}, Actions};
handle_request(ReqKey,
#gtp{type = delete_session_request, ie = IEs} = Request,
_Resent, _State, #{context := Context, 'Session' := Session} = Data0) ->
FqTEI = maps:get(?'Sender F-TEID for Control Plane', IEs, undefined),
Result =
do([error_m ||
match_context(?'S5/S8-C SGW', Context, FqTEI),
return({request_accepted, Data0})
]),
case Result of
{ok, {ReplyIEs, Data}} ->
process_secondary_rat_usage_data_reports(IEs, Context, Session),
close_pdn_context(normal, Data),
Response = response(delete_session_response, Context, ReplyIEs),
gtp_context:send_response(ReqKey, Request, Response),
{next_state, shutdown, Data};
{error, ReplyIEs} ->
Response = response(delete_session_response, Context, ReplyIEs),
gtp_context:send_response(ReqKey, Request, Response),
keep_state_and_data
end;
handle_request(ReqKey, _Msg, _Resent, _State, _Data) ->
gtp_context:request_finished(ReqKey),
keep_state_and_data.
handle_response(ReqInfo, #gtp{version = v1} = Msg, Request, State, Data) ->
?GTP_v1_Interface:handle_response(ReqInfo, Msg, Request, State, Data);
handle_response(CommandReqKey,
#gtp{type = update_bearer_response,
ie = #{?'Cause' := #v2_cause{v2_cause = Cause},
?'Bearer Contexts to be modified' :=
#v2_bearer_context{
group = #{?'Cause' := #v2_cause{v2_cause = BearerCause}}
}} = IEs} = Response,
_Request, run,
#{context := Context0, pfcp := PCtx,
'Session' := Session} = Data0) ->
gtp_context:request_finished(CommandReqKey),
Context = gtp_path:bind(Response, false, Context0),
Data = Data0#{context => Context},
if Cause =:= request_accepted andalso BearerCause =:= request_accepted ->
URRActions = update_session_from_gtp_req(IEs, Session, Context),
trigger_defered_usage_report(URRActions, PCtx),
{keep_state, Data};
true ->
?LOG(error, "Update Bearer Request failed with ~p/~p",
[Cause, BearerCause]),
delete_context(undefined, link_broken, Data)
end;
handle_response(_, timeout, #gtp{type = update_bearer_request}, run, Data) ->
?LOG(error, "Update Bearer Request failed with timeout"),
delete_context(undefined, link_broken, Data);
handle_response({From, TermCause}, timeout, #gtp{type = delete_bearer_request},
_State, Data) ->
close_pdn_context(TermCause, Data),
if is_tuple(From) -> gen_statem:reply(From, {error, timeout});
true -> ok
end,
{next_state, shutdown, Data};
handle_response({From, TermCause},
#gtp{type = delete_bearer_response,
ie = #{?'Cause' := #v2_cause{v2_cause = RespCause}} = IEs} = Response,
_Request, _State,
#{context := Context0, 'Session' := Session} = Data) ->
Context = gtp_path:bind(Response, false, Context0),
process_secondary_rat_usage_data_reports(IEs, Context, Session),
close_pdn_context(TermCause, Data),
if is_tuple(From) -> gen_statem:reply(From, {ok, RespCause});
true -> ok
end,
{next_state, shutdown, Data#{context := Context}};
handle_response(_CommandReqKey, _Response, _Request, State, _Data)
when State =/= run ->
keep_state_and_data.
terminate(_Reason, _State, #{context := Context}) ->
ergw_gsn_lib:release_context_ips(Context),
ok.
%%%===================================================================
%%% Helper functions
%%%===================================================================
ip2prefix({IP, Prefix}) ->
<<Prefix:8, (ergw_inet:ip2bin(IP))/binary>>.
response(Cmd, #context{remote_control_teid = #fq_teid{teid = TEID}}, Response) ->
{Cmd, TEID, Response}.
response(Cmd, Context, IEs0, #gtp{ie = ReqIEs}) ->
IEs = gtp_v2_c:build_recovery(Cmd, Context, is_map_key(?'Recovery', ReqIEs), IEs0),
response(Cmd, Context, IEs).
session_failure_to_gtp_cause(_) ->
system_failure.
authenticate(Context, Session, SessionOpts, Request) ->
?LOG(debug, "SessionOpts: ~p", [SessionOpts]),
case ergw_aaa_session:invoke(Session, SessionOpts, authenticate, [inc_session_id]) of
{ok, _, _} = Result ->
Result;
Other ->
?LOG(debug, "AuthResult: ~p", [Other]),
?ABORT_CTX_REQUEST(Context, Request, create_session_response,
user_authentication_failed)
end.
ccr_initial(Context, Session, API, SessionOpts, ReqOpts, Request) ->
case ergw_aaa_session:invoke(Session, SessionOpts, {API, 'CCR-Initial'}, ReqOpts) of
{ok, _, _} = Result ->
Result;
{Fail, _, _} ->
?ABORT_CTX_REQUEST(Context, Request, create_session_response,
session_failure_to_gtp_cause(Fail))
end.
match_context(_Type, _Context, undefined) ->
error_m:return(ok);
match_context(Type,
#context{
remote_control_teid =
#fq_teid{
ip = RemoteCntlIP,
teid = RemoteCntlTEI
}} = Context,
#v2_fully_qualified_tunnel_endpoint_identifier{
instance = 0,
interface_type = Type,
key = RemoteCntlTEI,
ipv4 = RemoteCntlIP4,
ipv6 = RemoteCntlIP6} = IE) ->
case ergw_inet:ip2bin(RemoteCntlIP) of
RemoteCntlIP4 ->
error_m:return(ok);
RemoteCntlIP6 ->
error_m:return(ok);
_ ->
?LOG(error, "match_context: IP address mismatch, ~p, ~p, ~p",
[Type, Context, IE]),
error_m:fail([#v2_cause{v2_cause = invalid_peer}])
end;
match_context(Type, Context, IE) ->
?LOG(error, "match_context: context not found, ~p, ~p, ~p",
[Type, Context, IE]),
error_m:fail([#v2_cause{v2_cause = invalid_peer}]).
pdn_alloc(#v2_pdn_address_allocation{type = non_ip}) ->
{'Non-IP', undefined, undefined};
pdn_alloc(#v2_pdn_address_allocation{type = ipv4v6,
address = << IP6PrefixLen:8, IP6Prefix:16/binary, IP4:4/binary>>}) ->
{'IPv4v6', ergw_inet:bin2ip(IP4), {ergw_inet:bin2ip(IP6Prefix), IP6PrefixLen}};
pdn_alloc(#v2_pdn_address_allocation{type = ipv4,
address = << IP4:4/binary>>}) ->
{'IPv4', ergw_inet:bin2ip(IP4), undefined};
pdn_alloc(#v2_pdn_address_allocation{type = ipv6,
address = << IP6PrefixLen:8, IP6Prefix:16/binary>>}) ->
{'IPv6', undefined, {ergw_inet:bin2ip(IP6Prefix), IP6PrefixLen}}.
encode_paa(IPv4, undefined) when IPv4 /= undefined ->
encode_paa(ipv4, ergw_inet:ip2bin(ergw_ip_pool:addr(IPv4)), <<>>);
encode_paa(undefined, IPv6) when IPv6 /= undefined ->
encode_paa(ipv6, <<>>, ip2prefix(ergw_ip_pool:ip(IPv6)));
encode_paa(IPv4, IPv6) when IPv4 /= undefined, IPv6 /= undefined ->
encode_paa(ipv4v6, ergw_inet:ip2bin(ergw_ip_pool:addr(IPv4)),
ip2prefix(ergw_ip_pool:ip(IPv6))).
encode_paa(Type, IPv4, IPv6) ->
#v2_pdn_address_allocation{type = Type, address = <<IPv6/binary, IPv4/binary>>}.
close_pdn_context(Reason, #{context := Context, pfcp := PCtx, 'Session' := Session}) ->
URRs = ergw_gsn_lib:delete_sgi_session(Reason, Context, PCtx),
%% ===========================================================================
TermCause =
if Reason =:= upf_failure;
Reason =:= link_broken ->
?'DIAMETER_BASE_TERMINATION-CAUSE_LINK_BROKEN';
Reason =:= administrative ->
?'DIAMETER_BASE_TERMINATION-CAUSE_ADMINISTRATIVE';
true ->
?'DIAMETER_BASE_TERMINATION-CAUSE_LOGOUT'
end,
%% TODO: Monitors, AAA over SGi
%% 1. CCR on Gx to get PCC rules
Now = erlang:monotonic_time(),
ReqOpts = #{now => Now, async => true},
case ergw_aaa_session:invoke(Session, #{}, {gx, 'CCR-Terminate'}, ReqOpts#{async => false}) of
{ok, _GxSessionOpts, _} ->
?LOG(debug, "GxSessionOpts: ~p", [_GxSessionOpts]);
GxOther ->
?LOG(warning, "Gx terminate failed with: ~p", [GxOther])
end,
ChargeEv = {terminate, TermCause},
{Online, Offline, Monitor} = ergw_gsn_lib:usage_report_to_charging_events(URRs, ChargeEv, PCtx),
ergw_gsn_lib:process_accounting_monitor_events(ChargeEv, Monitor, Now, Session),
GyReqServices = ergw_gsn_lib:gy_credit_report(Online),
ergw_gsn_lib:process_online_charging_events(ChargeEv, GyReqServices, Session, ReqOpts),
ergw_gsn_lib:process_offline_charging_events(ChargeEv, Offline, Now, Session),
%% ===========================================================================
ok.
query_usage_report(ChargingKeys, Context, PCtx)
when is_list(ChargingKeys) ->
ergw_gsn_lib:query_usage_report(ChargingKeys, Context, PCtx);
query_usage_report(_, Context, PCtx) ->
ergw_gsn_lib:query_usage_report(Context, PCtx).
triggered_charging_event(ChargeEv, Now, Request,
#{context := Context, pfcp := PCtx,
'Session' := Session, pcc := PCC}) ->
try
ReqOpts = #{now => Now, async => true},
{_, UsageReport} =
query_usage_report(Request, Context, PCtx),
{Online, Offline, Monitor} =
ergw_gsn_lib:usage_report_to_charging_events(UsageReport, ChargeEv, PCtx),
ergw_gsn_lib:process_accounting_monitor_events(ChargeEv, Monitor, Now, Session),
GyReqServices = ergw_gsn_lib:gy_credit_request(Online, PCC),
ergw_gsn_lib:process_online_charging_events(ChargeEv, GyReqServices, Session, ReqOpts),
ergw_gsn_lib:process_offline_charging_events(ChargeEv, Offline, Now, Session)
catch
throw:#ctx_err{} = CtxErr ->
?LOG(error, "Triggered Charging Event failed with ~p", [CtxErr])
end,
ok.
defered_usage_report_fun(Owner, URRActions, PCtx) ->
try
{_, Report} = ergw_gsn_lib:query_usage_report(offline, undefined, PCtx),
defered_usage_report(Owner, URRActions, Report)
catch
throw:#ctx_err{} = CtxErr ->
?LOG(error, "Defered Usage Report failed with ~p", [CtxErr])
end.
trigger_defered_usage_report([], _PCtx) ->
ok;
trigger_defered_usage_report(URRActions, PCtx) ->
Self = self(),
proc_lib:spawn(fun() -> defered_usage_report_fun(Self, URRActions, PCtx) end),
ok.
defer_usage_report(URRActions, UsageReport) ->
defered_usage_report(self(), URRActions, UsageReport).
apply_context_change(NewContext0, OldContext, URRActions,
#{pfcp := PCtx0, pcc := PCC} = Data) ->
ModifyOpts =
case {NewContext0, OldContext} of
{#context{version = v2}, #context{version = v2}} ->
#{send_end_marker => true};
_ ->
#{}
end,
NewContext = gtp_path:bind(false, NewContext0),
{PCtx, UsageReport} =
ergw_gsn_lib:modify_sgi_session(PCC, URRActions,
ModifyOpts, NewContext, PCtx0),
gtp_path:unbind(OldContext),
defer_usage_report(URRActions, UsageReport),
Data#{context => NewContext, pfcp => PCtx}.
%% 'Idle-Timeout' received from ergw_aaa Session takes precedence over configured one
add_apn_timeout(Opts, Session, Context) ->
SessionWithTimeout = maps:merge(maps:with(['Idle-Timeout'],Opts), Session),
Timeout = maps:get('Idle-Timeout', SessionWithTimeout),
ContextWithTimeout = Context#context{'Idle-Timeout' = Timeout},
{ContextWithTimeout, SessionWithTimeout}.
map_attr('APN', #{?'Access Point Name' := #v2_access_point_name{apn = APN}}) ->
unicode:characters_to_binary(lists:join($., APN));
map_attr('IMSI', #{?'IMSI' := #v2_international_mobile_subscriber_identity{imsi = IMSI}}) ->
IMSI;
map_attr('IMEI', #{?'ME Identity' := #v2_mobile_equipment_identity{mei = IMEI}}) ->
IMEI;
map_attr('MSISDN', #{?'MSISDN' := #v2_msisdn{msisdn = MSISDN}}) ->
MSISDN;
map_attr(Value, _) when is_binary(Value); is_list(Value) ->
Value;
map_attr(Value, _) when is_atom(Value) ->
atom_to_binary(Value, utf8);
map_attr(Value, _) ->
io_lib:format("~w", [Value]).
map_username(_IEs, Username, _) when is_binary(Username) ->
Username;
map_username(_IEs, [], Acc) ->
iolist_to_binary(lists:reverse(Acc));
map_username(IEs, [H | Rest], Acc) ->
Part = map_attr(H, IEs),
map_username(IEs, Rest, [Part | Acc]).
init_session(IEs,
#context{control_port = #gtp_port{ip = LocalIP},
charging_identifier = ChargingId},
#{'Username' := #{default := Username},
'Password' := #{default := Password}}) ->
MappedUsername = map_username(IEs, Username, []),
{MCC, MNC} = ergw:get_plmn_id(),
Opts =
case LocalIP of
{_,_,_,_,_,_,_,_} ->
#{'3GPP-GGSN-IPv6-Address' => LocalIP};
_ ->
#{'3GPP-GGSN-Address' => LocalIP}
end,
Opts#{'Username' => MappedUsername,
'Password' => Password,
'Service-Type' => 'Framed-User',
'Framed-Protocol' => 'GPRS-PDP-Context',
'3GPP-GGSN-MCC-MNC' => <<MCC/binary, MNC/binary>>,
'3GPP-Charging-Id' => ChargingId
}.
copy_ppp_to_session({pap, 'PAP-Authentication-Request', _Id, Username, Password}, Session0) ->
Session = Session0#{'Username' => Username, 'Password' => Password},
maps:without(['CHAP-Challenge', 'CHAP_Password'], Session);
copy_ppp_to_session({chap, 'CHAP-Challenge', _Id, Value, _Name}, Session) ->
Session#{'CHAP_Challenge' => Value};
copy_ppp_to_session({chap, 'CHAP-Response', _Id, Value, Name}, Session0) ->
Session = Session0#{'CHAP_Password' => Value, 'Username' => Name},
maps:without(['Password'], Session);
copy_ppp_to_session(_, Session) ->
Session.
non_empty_ip(_, {0,0,0,0}, Opts) ->
Opts;
non_empty_ip(_, {{0,0,0,0,0,0,0,0}, _}, Opts) ->
Opts;
non_empty_ip(Key, IP, Opts) ->
maps:put(Key, IP, Opts).
copy_to_session(_, #v2_protocol_configuration_options{config = {0, Options}},
#{'Username' := #{from_protocol_opts := true}}, _, Session) ->
lists:foldr(fun copy_ppp_to_session/2, Session, Options);
copy_to_session(_, #v2_access_point_name{apn = APN}, _AAAopts, _, Session) ->
{NI, _OI} = ergw_node_selection:split_apn(APN),
Session#{'Called-Station-Id' =>
iolist_to_binary(lists:join($., NI))};
copy_to_session(_, #v2_msisdn{msisdn = MSISDN}, _AAAopts, _, Session) ->
Session#{'Calling-Station-Id' => MSISDN, '3GPP-MSISDN' => MSISDN};
copy_to_session(_, #v2_international_mobile_subscriber_identity{imsi = IMSI}, _AAAopts, _, Session) ->
case itu_e212:split_imsi(IMSI) of
{MCC, MNC, _} ->
Session#{'3GPP-IMSI' => IMSI,
'3GPP-IMSI-MCC-MNC' => <<MCC/binary, MNC/binary>>};
_ ->
Session#{'3GPP-IMSI' => IMSI}
end;
copy_to_session(_, #v2_pdn_address_allocation{type = ipv4,
address = IP4}, _AAAopts, _, Session) ->
IP4addr = ergw_inet:bin2ip(IP4),
S0 = Session#{'3GPP-PDP-Type' => 'IPv4'},
S1 = non_empty_ip('Framed-IP-Address', IP4addr, S0),
_S = non_empty_ip('Requested-IP-Address', IP4addr, S1);
copy_to_session(_, #v2_pdn_address_allocation{type = ipv6,
address = <<IP6PrefixLen:8,
IP6Prefix:16/binary>>},
_AAAopts, _, Session) ->
IP6addr = {ergw_inet:bin2ip(IP6Prefix), IP6PrefixLen},
S0 = Session#{'3GPP-PDP-Type' => 'IPv6'},
S1 = non_empty_ip('Framed-IPv6-Prefix', IP6addr, S0),
_S = non_empty_ip('Requested-IPv6-Prefix', IP6addr, S1);
copy_to_session(_, #v2_pdn_address_allocation{type = ipv4v6,
address = <<IP6PrefixLen:8,
IP6Prefix:16/binary,
IP4:4/binary>>},
_AAAopts, _, Session) ->
IP4addr = ergw_inet:bin2ip(IP4),
IP6addr = {ergw_inet:bin2ip(IP6Prefix), IP6PrefixLen},
S0 = Session#{'3GPP-PDP-Type' => 'IPv4v6'},
S1 = non_empty_ip('Framed-IP-Address', IP4addr, S0),
S2 = non_empty_ip('Requested-IP-Address', IP4addr, S1),
S3 = non_empty_ip('Framed-IPv6-Prefix', IP6addr, S2),
_S = non_empty_ip('Requested-IPv6-Prefix', IP6addr, S3);
copy_to_session(_, #v2_pdn_address_allocation{type = non_ip}, _AAAopts, _, Session) ->
Session#{'3GPP-PDP-Type' => 'Non-IP'};
%% 3GPP TS 29.274, Rel 15, Table 7.2.1-1, Note 1:
%% The conditional PDN Type IE is redundant on the S4/S11 and S5/S8 interfaces
%% (as the PAA IE contains exactly the same field). The receiver may ignore it.
%%