-
Notifications
You must be signed in to change notification settings - Fork 0
/
prog_faster.pl
174 lines (135 loc) · 4.69 KB
/
prog_faster.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
#!/usr/bin/perl
# Smallest overpseudoprime to base 2 (A141232) with n distinct prime factors.
# https://oeis.org/A353409
# Known terms:
# 2047, 13421773, 14073748835533
# Upper-bounds:
# a(5) <= 1376414970248942474729
# a(6) <= 48663264978548104646392577273
# a(7) <= 294413417279041274238472403168164964689
# a(8) <= 98117433931341406381352476618801951316878459720486433149
# a(9) <= 1252977736815195675988249271013258909221812482895905512953752551821
# New terms confirmed (03 September 2022):
# a(5) = 1376414970248942474729
# a(6) = 48663264978548104646392577273
# a(7) = 294413417279041274238472403168164964689
use 5.020;
use warnings;
use ntheory qw(:all);
use experimental qw(signatures);
use Memoize qw(memoize);
use Math::GMPz;
memoize('inverse_znorder_primes');
sub divceil ($x,$y) { # ceil(x/y)
my $q = divint($x,$y);
($q*$y == $x) ? $q : ($q+1);
}
sub inverse_znorder_primes($base, $lambda) {
my %seen;
grep { znorder($base, $_) == $lambda } grep { !$seen{$_}++ } factor(subint(powint($base, $lambda), 1));
}
sub squarefree_fermat_overpseudoprimes_in_range ($A, $B, $k, $base, $callback) {
$A = vecmax($A, pn_primorial($k));
sub ($m, $lambda, $p, $k, $u = undef, $v = undef) {
if ($k == 1) {
if ($lambda <= 135) {
foreach my $p (inverse_znorder_primes($base, $lambda)) {
next if $p < $u;
next if $p > $v;
if (($m*$p - 1)%$lambda == 0) {
$callback->($m*$p);
}
}
return;
}
if (prime_count_lower($v)-prime_count_lower($u) < divint($v-$u, $lambda)) {
forprimes {
if (($m*$_ - 1)%$lambda == 0 and powmod($base, $lambda, $_) == 1 and znorder($base, $_) == $lambda) {
$callback->($m*$_);
}
} $u, $v;
return;
}
for(my $w = $lambda * divceil($u-1, $lambda); $w <= $v; $w += $lambda) {
if (is_prime($w+1) and powmod($base, $lambda, $w+1) == 1) {
my $p = $w+1;
if (($m*$p - 1)%$lambda == 0 and znorder($base, $p) == $lambda) {
$callback->($m*$p);
}
}
}
return;
}
my $s = rootint($B/$m, $k);
if ($lambda > 1 and $lambda <= 135) {
for my $q (inverse_znorder_primes($base, $lambda)) {
next if ($q < $p);
next if ($q > $s);
my $t = $m*$q;
my $u = divceil($A, $t);
my $v = $B/$t;
if ($u <= $v) {
my $r = next_prime($q);
__SUB__->($t, $lambda, $r, $k-1, (($k==2 && $r>$u) ? $r : $u), $v);
}
}
return;
}
if ($lambda > 1) {
for(my $w = $lambda * divceil($p-1, $lambda); $w <= $s; $w += $lambda) {
if (is_prime($w+1) and powmod($base, $lambda, $w+1) == 1) {
my $p = $w+1;
$lambda == znorder($base, $p) or next;
$base % $p == 0 and next;
my $t = $m*$p;
my $u = divceil($A, $t);
my $v = $B/$t;
if ($u <= $v) {
my $r = next_prime($p);
__SUB__->($t, $lambda, $r, $k-1, (($k==2 && $r>$u) ? $r : $u), $v);
}
}
}
return;
}
for (my $r; $p <= $s; $p = $r) {
$r = next_prime($p);
$base % $p == 0 and next;
my $L = znorder($base, $p);
$L == $lambda or $lambda == 1 or next;
gcd($L, $m) == 1 or next;
my $t = $m*$p;
my $u = divceil($A, $t);
my $v = $B/$t;
if ($u <= $v) {
__SUB__->($t, $L, $r, $k - 1, (($k==2 && $r>$u) ? $r : $u), $v);
}
}
}->(Math::GMPz->new(1), 1, 2, $k);
}
sub a($n) {
my $x = pn_primorial($n);
my $y = 2*$x;
$x = Math::GMPz->new("$x");
$y = Math::GMPz->new("$y");
for (;;) {
my @arr;
squarefree_fermat_overpseudoprimes_in_range($x, $y, $n, 2, sub($v) { push @arr, $v });
if (@arr) {
@arr = sort {$a <=> $b} @arr;
return $arr[0];
}
$x = $y+1;
$y = 2*$x;
}
}
foreach my $n (8) {
say "a($n) = ", a($n);
}
__END__
a(2) = 2047
a(3) = 13421773
a(4) = 14073748835533
a(5) = 1376414970248942474729
a(6) = 48663264978548104646392577273
a(7) = 294413417279041274238472403168164964689