This repository has been archived by the owner on Mar 22, 2023. It is now read-only.
forked from mpenet/jet
-
Notifications
You must be signed in to change notification settings - Fork 4
/
servlet.clj
299 lines (261 loc) · 9.35 KB
/
servlet.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
(ns qbits.jet.servlet
"Compatibility functions for turning a ring handler into a Java servlet."
(:require
[clojure.core.async :as async]
[clojure.java.io :as io]
[clojure.string :as string]
[qbits.jet.util :as util])
(:import
(java.io
File
InputStream
FileInputStream
OutputStream
OutputStreamWriter)
(javax.servlet
AsyncContext
AsyncListener)
(org.eclipse.jetty.server Request Response)
(javax.servlet.http HttpServletResponse)))
(defn chan?
[x]
(instance? clojure.core.async.impl.channels.ManyToManyChannel x))
(defn- get-headers
"Creates a name/value map of all the request headers."
[^Request request]
(reduce
(fn [headers ^String name]
(assoc headers
(.toLowerCase name)
(->> (.getHeaders request name)
(enumeration-seq)
(string/join ","))))
{}
(enumeration-seq (.getHeaderNames request))))
(defn- get-content-length
"Returns the content length, or nil if there is no content."
[^Request request]
(let [length (.getContentLength request)]
(if (>= length 0) length)))
(defn- get-client-cert
"Returns the SSL client certificate of the request, if one exists."
[^Request request]
(first (.getAttribute request "javax.servlet.request.X509Certificate")))
(defn build-request-map
"Create the request map from the HttpServletRequest object."
[^Request request]
(let [request-headers (get-headers request)]
{:servlet-request request
:server-port (.getServerPort request)
:server-name (.getServerName request)
:remote-addr (.getRemoteAddr request)
:uri (.getRequestURI request)
:query-string (.getQueryString request)
:scheme (keyword (.getScheme request))
:request-method (keyword (.toLowerCase (.getMethod request)))
:headers request-headers
:trailers-fn (when (util/trailers-supported? (.getProtocol request) request-headers)
(fn retrieve-trailers []
;; trailers will only be available after body has been consumed
(some-> request .getTrailers util/http-fields->map)))
:content-type (.getContentType request)
:content-length (get-content-length request)
:character-encoding (.getCharacterEncoding request)
:ssl-client-cert (get-client-cert request)
:ctrl (async/chan)
:body (.getInputStream request)}))
(defn- set-status+headers!
"Update a HttpServletResponse with a map of headers."
[^HttpServletResponse servlet-response
request-map
status
headers]
(when status
(.setStatus servlet-response status))
(doseq [[key val-or-vals] headers]
(if (string? val-or-vals)
(.setHeader servlet-response key val-or-vals)
(doseq [val val-or-vals]
(.addHeader servlet-response key val))))
;; Some headers must be set through specific methods
(when-let [content-type (get headers "Content-Type")]
(.setContentType servlet-response content-type))
(when-let [content-type (get headers "Content-Type")]
(.setContentType servlet-response content-type)))
(defprotocol PBodyWritable
(write-body! [body servlet-response request-map]))
(defn set-response-body!
[servlet-response request-map body]
(write-body! body servlet-response request-map))
(defn flush-buffer!
[^Response servlet-response]
(.flushBuffer servlet-response))
(defn- response->output-stream
^OutputStreamWriter
[^Response servlet-response]
(-> servlet-response .getOutputStream))
(defprotocol OutputStreamWritable
(-write-stream! [x output-stream]))
(extend-protocol OutputStreamWritable
(Class/forName "[B") ; Byte array
(-write-stream! [b ^OutputStream os]
(.write os ^bytes b)
(.flush os))
String
(-write-stream! [s ^OutputStream os]
(.write os (.getBytes s))
(.flush os))
Number
(-write-stream! [n os]
(-write-stream! (str n) os))
InputStream
(-write-stream! [input-stream ^OutputStream os]
(io/copy input-stream os)
(.flush os))
clojure.lang.Fn
(-write-stream! [f ^OutputStream output-stream]
(f output-stream)
(.flush output-stream)))
(defn write-stream!
[stream x request-map]
(try
(-write-stream! x stream)
(catch Exception e
(let [ex (ex-info "Couldn't write to stream" {} e)]
(async/put! (:ctrl request-map) [::error ex])
(throw ex)))))
(extend-protocol PBodyWritable
(Class/forName "[B") ; Byte array
(write-body! [bytes servlet-response request-map]
(write-stream! (response->output-stream servlet-response) bytes request-map))
String
(write-body! [s servlet-response request-map]
(let [w (response->output-stream servlet-response)]
(write-stream! w s request-map)))
clojure.lang.ISeq
(write-body! [coll servlet-response request-map]
(let [w (response->output-stream servlet-response)]
(doseq [chunk coll]
(write-stream! w chunk request-map))))
InputStream
(write-body! [stream ^Response servlet-response request-map]
(write-stream! (response->output-stream servlet-response) stream request-map))
clojure.lang.Fn
(write-body! [f servlet-response request-map]
(f servlet-response))
File
(write-body! [file servlet-response request-map]
(with-open [stream (FileInputStream. file)]
(write-body! stream servlet-response request-map)))
clojure.core.async.impl.channels.ManyToManyChannel
(write-body! [ch servlet-response request-map]
(let [w (response->output-stream servlet-response)]
(async/go
(loop [state ::connected]
(let [x (async/<! ch)]
(if (and x (= state ::connected))
(recur
(try
(write-stream! w x request-map)
state
(catch Exception e
::disconnected)))
(when (= ::connected state)
(flush-buffer! servlet-response))))))))
nil
(write-body! [body servlet-response request-map])
Object
(write-body! [body _ _]
(throw (Exception. ^String (format "Unrecognized body: < %s > %s" (type body) body)))))
(defn ctrl-listener
[ctrl]
(reify AsyncListener
(onStartAsync [this event]
(comment do nothing))
(onError [this event]
(async/put! ctrl [::error (.getThrowable event)]))
(onTimeout [this event]
(async/put! ctrl [::timeout (.getThrowable event)]))
(onComplete [this event]
(async/close! ctrl))))
(defn async-listener
[ctrl ch]
(reify AsyncListener
(onStartAsync [this event]
(comment do nothing))
(onError [this event]
(async/put! ctrl [::error (.getThrowable event)])
(async/close! ch))
(onTimeout [this event]
(async/put! ctrl [::timeout (.getThrowable event)])
(async/close! ch))
(onComplete [this event]
(async/close! ch))))
(defn ^AsyncContext async-context
[{:as request-map
:keys [^Request servlet-request
ctrl]}
ch]
(when-not (.isAsyncStarted servlet-request)
(doto (.startAsync servlet-request)
;; Expect timing out to be handled by application code
(.setTimeout 0)
(.addListener (ctrl-listener ctrl))))
(doto (.getAsyncContext servlet-request)
(.addListener (async-listener ctrl ch))))
(defn set-body!
[servlet-response
{:keys [ctrl] :as request-map}
body]
(if (chan? body)
(let [ctx (async-context request-map body)]
(async/take! (set-response-body! servlet-response request-map body)
(fn [_]
(try
(.complete ctx)
(catch Exception ex
(when-not (async/put! ctrl [::error ex])
;; rethrow the exception only if it is not sent to ctrl chan
(throw ex)))))))
(do
(set-response-body! servlet-response request-map body)
(flush-buffer! servlet-response))))
(defn throw-invalid-response!
[x]
(throw (ex-info "Invalid response given." {:response x})))
(defprotocol PResponse
(-update-response [x servlet-response]))
(defn update-response
[x request-map]
(-update-response x request-map))
(extend-protocol PResponse
clojure.core.async.impl.channels.ManyToManyChannel
(-update-response [response-ch
request-map]
(let [ctx (async-context request-map response-ch)]
(async/take! response-ch
#(do
(try
(-update-response % request-map)
(catch Exception ex
(-> request-map :ctrl (async/put! [::error ex]))))
(when-not (chan? (:body %))
(try
(.complete ctx)
(catch Exception ex
(-> request-map :ctrl (async/put! [::error ex])))))))))
clojure.lang.IPersistentMap
(-update-response [response-map request-map]
(let [{:keys [status headers body trailers]} response-map
^Request servlet-request (:servlet-request request-map)
servlet-response (.getServletResponse servlet-request)]
(when (and trailers (instance? Response servlet-response))
(.setTrailers ^Response servlet-response (util/trailers-ch->supplier trailers)))
(set-status+headers! servlet-response request-map status headers)
(set-body! servlet-response request-map body)))
Object
(-update-response [x _]
(throw-invalid-response! x))
nil
(-update-response [x _]
(throw-invalid-response! x)))