build.gradle

plugins {
  id 'com.typelead.eta' version '0.6.0' apply false
  id 'org.jetbrains.intellij' version '0.3.1' apply false
  id "org.jetbrains.kotlin.jvm" version "1.2.50" apply false
}

apply plugin: 'eta-base'

eta {
  version = '0.8.6b2'
  etlasVersion = '1.5.1.0'
  preInstallDependencies = true
}


group 'com.typelead'
version = file('version.txt').text.trim()

ext {
  javaVersion = '1.8'
}


subprojects {

  apply plugin: 'java'

  repositories {
    mavenCentral()
  }

  sourceCompatibility = 1.8
}

[project(':jps-shared'), project(':plugin')].each { p ->
  p.apply plugin: 'org.jetbrains.intellij'
  p.intellij {
    version = '2018.1.5'
    pluginName = 'IntelliJ-Eta'
    // Makes it easy to support multiple intellij versions.
    // If we want to set this to true, we should find a way to cross build
    // against multiple intellij versions.
    updateSinceUntilBuild = false
    // 'properties' and 'Groovy' are needed due to the 'gradle' dependency
    plugins = ['properties', 'Groovy', 'gradle']
  }
}