data.tf

data "aws_region" "current" {}

# Task role assume policy
data "aws_iam_policy_document" "task_assume" {
  statement {
    effect  = "Allow"
    actions = ["sts:AssumeRole"]

    principals {
      type        = "Service"
      identifiers = ["ecs-tasks.amazonaws.com"]
    }
  }
}

# Task logging privileges
data "aws_iam_policy_document" "task_permissions" {
  dynamic "statement" {
    for_each = var.enable_logs ? [1] : []
    content {
      effect = "Allow"

      resources = [
        aws_cloudwatch_log_group.main[0].arn,
        "${aws_cloudwatch_log_group.main[0].arn}:*"
      ]

      actions = [
        "logs:CreateLogStream",
        "logs:PutLogEvents",
      ]
    }
  }

  dynamic "statement" {
    for_each = var.enable_logs ? [] : [1]

    content {
      effect    = "Allow"
      resources = var.log_groups_arn
      actions = [
        "logs:CreateLogStream",
        "logs:PutLogEvents"
      ]
    }
  }
}

# Task permissions to allow ECS Exec command
data "aws_iam_policy_document" "task_ecs_exec_policy" {
  count = var.enable_execute_command ? 1 : 0

  statement {
    effect = "Allow"

    resources = ["*"]

    actions = [
      "ssmmessages:CreateControlChannel",
      "ssmmessages:CreateDataChannel",
      "ssmmessages:OpenControlChannel",
      "ssmmessages:OpenDataChannel"
    ]
  }
}

# Task ecr privileges
data "aws_iam_policy_document" "task_execution_permissions" {
  statement {
    effect = "Allow"

    resources = [
      "*",
    ]

    actions = [
      "ecr:GetAuthorizationToken",
      "ecr:BatchCheckLayerAvailability",
      "ecr:GetDownloadUrlForLayer",
      "ecr:BatchGetImage",
      "logs:CreateLogStream",
      "logs:PutLogEvents",
    ]
  }
}

data "aws_kms_key" "secretsmanager_key" {
  count = var.create_repository_credentials_iam_policy ? 1 : 0

  key_id = var.repository_credentials_kms_key
}

data "aws_iam_policy_document" "read_repository_credentials" {
  count = var.create_repository_credentials_iam_policy ? 1 : 0

  statement {
    effect = "Allow"

    resources = [
      var.repository_credentials,
      data.aws_kms_key.secretsmanager_key[0].arn,
    ]

    actions = [
      "secretsmanager:GetSecretValue",
      "kms:Decrypt",
    ]
  }
}

data "aws_iam_policy_document" "get_environment_files" {
  count = length(var.task_container_environment_files) != 0 ? 1 : 0

  statement {
    effect = "Allow"

    resources = var.task_container_environment_files

    actions = [
      "s3:GetObject"
    ]
  }

  statement {
    effect = "Allow"

    resources = [for file in var.task_container_environment_files : split("/", file)[0]]

    actions = [
      "s3:GetBucketLocation"
    ]
  }
}

data "aws_ecs_task_definition" "task" {
  task_definition = aws_ecs_task_definition.task.family
}