/
main.asm
257 lines (199 loc) · 3.67 KB
/
main.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
;******************************************************************
;yawp
;3 channel pcm player for ZX Spectrum beeper
;by utz 09'2015
;******************************************************************
;IX - add counter 1
;IY - add counter 2
;HL' - add counter 3
;SP - base freq 1/2/3
;DE - sample pointer 1
;HL - sample pointer 2
;DE' - sample pointer 3
;B,C' - timer
;C used, value doesn't matter
org #8000
di
init
ei ;detect kempston
halt
in a,(#1f)
inc a
jr nz,_skip
ld (maskKempston),a
_skip
di
exx
push hl ;preserve HL' for return to BASIC
ld (oldSP),sp
ld hl,musicdata
ld (seqpntr),hl
;******************************************************************
rdseq
seqpntr equ $+1
ld sp,0
xor a
pop de ;pattern pointer to DE
or d
ld (seqpntr),sp
jr nz,rdptn0
;jp exit ;uncomment to disable looping
ld sp,loop
jr rdseq+3
;******************************************************************
rdptn0
ld (patpntr),de
rdptn
in a,(#1f) ;read joystick
maskKempston equ $+1
and #1f
ld c,a
in a,(#fe) ;read kbd
cpl
or c
and #1f
jp nz,exit
patpntr equ $+1 ;fetch pointer to pattern data
ld sp,0
pop de ;sample pointer 3/end + speed
or e
jr z,rdseq
ld c,e ;c=speed
ld e,0
ld h,e ;reset add counter 3
ld l,e
exx
pop hl ;base freq 1
ld (freq1),hl
pop hl
ld (freq2),hl
pop hl
ld (freq3),hl
pop de ;sample pointers 1,2
ld h,e
xor a
ld e,a
ld l,a
ld b,a
ld (patpntr),sp ;preserve data pointer
ld ix,0 ;reset add counters 1,2
ld iy,0
ld a,(de) ;preload sample pointer 1
play
;*******************************************************frame1
out (#fe),a ;11--28 ch3-3
rrca ;4
freq1 equ $+1
ld sp,0 ;10
out (#fe),a ;11--25 ch1-1
rrca ;4
add ix,sp ;15
out (#fe),a ;11--30 ch1-2
sbc a,a ;4 ;update sample pointer
add a,e
ld e,a
nop ;4 ;waste time for exx
ld a,(hl) ;7 ;reload sample pointer 2
out (#fe),a ;11--34 ch1-3
rrca ;4
exx ;4
out (#fe),a ;11--19 ch2-1
rrca ;4
nop ;4
out (#fe),a ;11--19 ch2-2
ld a,(de) ;7 ;reload sample pointer 3
out (#fe),a ;11--18 ch2-3
rrca ;4
exx ;4
out (#fe),a ;11--19 ch3-1
rrca ;4
nop ;4 ;waste time for dec b
ret c ;5 ;waste time
out (#fe),a ;11--24 ch3-2
ld sp,0 ;10 ;waste time for jp nz,play
ld a,(de) ;7 ;reload sample pointer 1
;216
;*******************************************************frame2
out (#fe),a ;11--28
rrca ;4
freq2 equ $+1
ld sp,0 ;10
out (#fe),a ;11--25
rrca ;4
add iy,sp ;15
out (#fe),a ;11--30
sbc a,a ;4
add a,l ;4
ld l,a ;4
ld a,(hl) ;7
nop ;4
out (#fe),a ;11--34
rrca ;4
exx ;4
out (#fe),a ;11--19
rrca ;4
nop ;4
out (#fe),a ;11--19
ld a,(de) ;7
out (#fe),a ;11--18
rrca ;4
exx ;4
out (#fe),a ;11--19
rrca ;4
dec b ;4 ;decrement timer
ret c ;5
out (#fe),a ;11--24
ld sp,0 ;10
ld a,(de) ;7
;*******************************************************frame3
out (#fe),a ;11--28
rrca ;4
freq3 equ $+1
ld sp,0 ;10
out (#fe),a ;11--25
rrca ;4
exx ;4
add hl,sp ;11
out (#fe),a ;11--30
sbc a,a ;4
add a,e ;4
ld e,a ;4
exx ;4
ld a,(hl) ;7
out (#fe),a ;11--34
rrca ;4
exx ;4
out (#fe),a ;11--19
rrca ;4
nop ;4
out (#fe),a ;11--19
ld a,(de) ;7
out (#fe),a ;11--18
rrca ;4
exx ;4
out (#fe),a ;11--19
rrca ;4
ret c ;5
dec b ;4 ;decrement timer
out (#fe),a ;11--24
ld a,(de) ;7
jp nz,play ;10
exx
dec c
exx
jp nz,play
jp rdptn
;*******************************************************
exit
oldSP equ $+1
ld sp,0
pop hl
exx
ei
ret
;******************************************************************
musicdata
include music.asm
org 256*(1+(HIGH($)))
samples
include samples.asm