-
Notifications
You must be signed in to change notification settings - Fork 1
/
cmdw.s
1853 lines (1680 loc) · 36.8 KB
/
cmdw.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;*---------------------------------------------------------------------------
; :Program. cmdw.s
; :Contents. command w - write
; :Author. Bert Jahn
; :Version $Id: cmdw.s 1.28 2020/03/14 14:10:59 wepl Exp wepl $
; :History. 18.03.01 separated from wwarp.asm
; 20.10.01 verify supports multiple syncs now
; 21.10.01 multiple syncs added
; 31.10.01 bug in post gap data fixed, drive inhibit added
; 26.04.02 writelen can be calculated on HD floppy drive
; 01.11.02 TF_SLEQ added
; 02.11.02 rework for new sync-search
; 01.12.02 sybil started
; 18.12.02 raw write fixed
; 01.01.04 more descriptive verify error messages (Codetapper)
; 11.02.04 adapted for MULTISYNC
; 01.07.04 sybil handling fixed
; 08.04.05 _unpacktrack fixed for special handling
; 23.04.08 Open/CloseDevice removed
; :Requires. OS V37+, MC68020+
; :Copyright. ©1998-2008 Bert Jahn, All Rights Reserved
; :Language. 68020 Assembler
; :Translator. Barfly V2.9
; :To Do.
;---------------------------------------------------------------------------*
_cmd_write bsr _cmdw_init
tst.l d0
beq _rts
;main
move.l #CMDF_IN|CMDF_TRKDATA,d0 ;flags
lea _cmdw_tracktable,a1 ;cbtt
lea _cmdw_tracks,a2 ;cbt
bsr _cmdwork
bra _cmdw_finit
_cmdw_init
;inhibit drive
move.l (gl_rd_unit,GL),d0
lsl.w #8,d0
add.l #"DF0:",d0
clr.l -(a7)
move.l d0,-(a7)
move.l a7,d1
moveq #-1,d2
move.l (gl_dosbase,GL),a6
jsr (_LVOInhibit,a6)
addq.l #8,a7
;init SYBIL
tst.l (gl_rd_sybil,GL)
beq .nosybil
bsr _sybil_init
tst.l d0
bne .nosybil
bsr _cmdw_sybilerr
moveq #0,d0
rts
.nosybil
moveq #-1,d0
rts
_cmdw_finit
bsr _sybil_finit
_cmdw_sybilerr
;deinhibit drive
move.l (gl_rd_unit,GL),d0
lsl.w #8,d0
add.l #"DF0:",d0
clr.l -(a7)
move.l d0,-(a7)
move.l a7,d1
moveq #0,d2
move.l (gl_dosbase,GL),a6
jsr (_LVOInhibit,a6)
addq.l #8,a7
rts
;copy tabarg to tabout so that the trackdata for all tracks
;to write will read
_cmdw_tracktable
lea (gl_tabarg,GL),a0
lea (gl_tabread,GL),a1
bsr _copytt
moveq #-1,d0
rts
_cmdw_tracks cmp.w #TT_RAW,(gl_trk+wth_type,GL)
beq _cmdw_raw
_cmdw_custom
bsr _gettt
move.l a0,a2 ;A2 = format
;get length, print info
move.l (wwf_name,a2),-(a7)
move.w (gl_trk+wth_num,GL),-(a7)
clr.w -(a7)
lea (_wtrack),a0
move.l a7,a1
bsr _PrintArgs
addq.l #8,a7
;dos standard has special routine
cmp.w #TT_STD,(gl_trk+wth_type,GL)
beq .std
cmp.w #TT_STDF,(gl_trk+wth_type,GL)
beq .std
;density control
tst.l (wwf_density,a2)
beq .nodens
tst.b (gl_sybil_init,GL)
bne .densok0
lea (_densrequired),a0
bsr _Print
bra .failed
.densok0 tst.w (wwf_index,a2)
bne .densbad0
btst #WWFB_INDEX,(wwf_flags+1,a2)
beq .nodens
.densbad0 lea (_densindex),a0
bsr _Print
bra .failed
.nodens
;calculate drive capabilties
move.w (gl_trk+wth_num,GL),d0
move.w (wwf_writelen,a2),d1
move.l (gl_io,GL),a0
bsr _calcdrive
tst.l d0
beq .failed
;density control: calculate gaplen/drivelen/writelen
;RPM: 300/min = 5/s > 0.2s
;Dens: 2us/bit = 16us/byte
move.l (wwf_density,a2),d0
beq .nodens2
move.l d0,a6
;calc gaplen
;ln,gap = length in bytes
;dn = density in ns/bit
;(gap+l0)*d0 + l1*d1 + ... = 0.2s
;gap = (0.2s - ... - l1*d1 -l0*d0) / d0
move.l #200000000,d2 ;ns
moveq #0,d7 ;custom mfm length
move.w (2,a6),d1 ;d0
.densloop move.w (a6)+,d0
add.w d0,d7
mulu.w (a6)+,d0
lsl.l #3,d0
sub.l d0,d2
tst.w (a6)
bne .densloop
cmp.w (wwf_writelen,a2),d7
beq .densok1
lea (_densbadlen),a0
bsr _Print
bra .failed
.densok1 divu.w d1,d2 ;div first density
ext.l d2
lsl.l #3,d7 ;bytes -> bits
add.l d2,d7
move.l d7,(gl_drivelen,GL)
add.l #WRITEDRVTOL*8+15,d7
lsr.l #4,d7 ;bits -> words
add.l d7,d7 ;words -> bytes
move.l d7,(gl_writelen,GL)
.nodens2
; the implementation of index writes is not optimized, because it
; would not be necessary that writelen+index < drivelen, but with
; the current formats its fine. for a general solution writelen
; must be modified for index
;check rawlen
moveq #0,d0
move.w (wwf_writelen,a2),d0
add.w (wwf_index,a2),d0
addq.l #2,d0 ;security
lsl.l #3,d0
cmp.l (gl_drivelen,GL),d0
bhs _cmdw_longtrk
;encode mfm-data
move.w (gl_trk+wth_num,GL),d0 ;track number
ext.l d0
moveq #0,d6
move.w (wwf_index,a2),d6 ;D6 = custom start
move.l d6,d7
beq .noidx
add.w (wwf_writelen,a2),d7 ;D7 = custom end
bra .seta0
.noidx add.l (gl_writelen,GL),d7
subq.l #2,d7
move.l d7,d6
sub.w (wwf_writelen,a2),d6
.seta0 move.l (gl_chipbuf,GL),a0 ;destination buffer
move.l #$a0a0a0a0,(-2,a0,d6.l) ;for postcheck start
move.l #$e0e0e0e0,(-2,a0,d7.l) ;for postcheck end
add.l d6,a0
move.l d6,(gl_pregap,GL) ;for density writes
lea (gl_tmpbuf,GL),a1 ;source data to encode
move.l (wwf_encode,a2),d1
beq _cmdw_encoder_na
movem.l d2-d7/a2-a6,-(a7)
jsr (d1.l)
movem.l (a7)+,_MOVEMREGS
tst.l d0
beq _cmdw_encoder_fail
cmp.w (wwf_writelen,a2),d0
bne _cmdw_encoder_badlen
;dump encoded mfm
moveq #1,d0
sub.l (gl_rd_dbg,GL),d0
bcc .nodbg
lea _mfmencode,a0
bsr _Print
move.l (gl_chipbuf,GL),a0
move.l (gl_writelen,GL),d0
moveq #0,d1
bsr _DumpMemory
.nodbg
;check encoded data end
move.l (gl_chipbuf,GL),a1 ;destination buffer
move.l a1,a0
add.l (gl_writelen,GL),a0
add.l d7,a1
cmp.w #$e0e0,(a1)
bne _cmdw_encoder_badend
cmp.b #$e0,-(a1)
beq _cmdw_encoder_badend
move.w #$5555,d0
btst #0,(a1)+
bne .1
ror.w #1,d0
.1 move.w d0,(a1)+
cmp.l a0,a1
blo .1
;check encoded data start
move.l (gl_chipbuf,GL),a1 ;destination buffer
add.l d6,a1
cmp.b #$a0,(a1)
beq _cmdw_encoder_badstrt
cmp.w #$a0a0,(-2,a1)
bne _cmdw_encoder_badstrt
move.l #$55555555,d0
tst.b (a1)
bpl .2
ror.l #1,d0
.2 move.l a1,d1
sub.l (gl_chipbuf,GL),d1
ble _cmdw_encoder_fail
lsr.l #1,d1
bcc .3
move.b d0,-(a1)
.3 lsr.l #1,d1
bcc .4
move.w d0,-(a1)
bra .4
.5 move.l d0,-(a1)
.4 dbf d1,.5
;check for invalid mfm-data
tst.l (gl_rd_dbg,GL)
beq .nodbgmfm
move.l (gl_chipbuf,GL),a1 ;destination buffer
move.l (gl_writelen,GL),d0
lsl.l #3,d0 ;bytes
subq.l #2,d0
;first 2 bits
bfextu (a1){d0:2},d1
cmp.w #%11,d1
beq .many11
subq.l #1,d0
;first 3 bits
bfextu (a1){d0:2},d1
cmp.w #%11,d1
beq .many11
subq.l #1,d0
;loop
.chk bfextu (a1){d0:2},d1
cmp.w #%11,d1
beq .many11
bfextu (a1){d0:4},d1
beq .many0000
.chkin subq.l #1,d0
bpl .chk
bra .nodbgmfm
.many11 lea _dbgmfm11,a0
bra .many
.many0000 lea _dbgmfm0000,a0
.many movem.l d0/a1,-(a7)
bsr _Print
move.l (a7),d0
bsr _printbitlen
lea _dbgmfm,a0
move.l (a7),d0
sub.l #16,d0
lsr.l #3,d0
move.l (gl_chipbuf,GL),a1
add.l d0,a1
move.l (a1),-(a7)
move.l d0,-(a7)
move.l a7,a1
bsr _PrintArgs
addq.l #8,a7
bsr _CheckBreak
tst.l d0
bne .chkbrk
movem.l (a7)+,d0/a1
bra .chkin
.chkbrk add.l #8,a7
.failed moveq #0,d0
rts
.nodbgmfm
IFEQ 1
move.l (gl_chipbuf,GL),a0
move.l #$400,d0
moveq #0,d1
bsr _DumpMemory
move.l (gl_fastbuf,GL),a0
move.l #$400,d0
moveq #0,d1
bsr _DumpMemory
lea (gl_tmpbuf,GL),a0
move.l #$400,d0
moveq #0,d1
bsr _DumpMemory
lea (gl_verbuf,GL),a0
move.l #$400,d0
moveq #0,d1
bsr _DumpMemory
ENDC
;write and flush track
moveq #0,d0
btst #WWFB_INDEX,(wwf_flags+1,a2)
beq .noindex
moveq #IOTDF_INDEXSYNC,d0
.noindex move.l (wwf_density,a2),a0
bsr _cmdw_writeraw
tst.l d0
bne _cmdw_werr
;verify?
tst.l (gl_rd_nover,GL)
bne .suc
;clear trackbuffer
move.l (gl_io,GL),a1
move.w #ETD_CLEAR,(IO_COMMAND,a1)
move.l (gl_execbase,GL),a6
jsr (_LVODoIO,a6)
move.l (gl_io,GL),a1
move.b (IO_ERROR,a1),d0
bne _cmdw_werr
;read track
move.l (gl_io,GL),a1
move.l (gl_chipbuf,GL),(IO_DATA,a1)
moveq #0,d0
move.w (gl_trk+wth_num,GL),d0
move.l d0,(IO_OFFSET,a1)
bsr _tdenable81
move.l (gl_writelen,GL),d5
add.l d5,d5
cmp.l #MAXTDLEN,d5
bls .lenok
move.l #MAXTDLEN,d5 ;D5 = readlen
.lenok move.l d5,(IO_LENGTH,a1)
move.w #ETD_RAWREAD,(IO_COMMAND,a1)
moveq #IOF_QUICK,d0
btst #WWFB_INDEX,(wwf_flags+1,a2)
beq .noindex2
moveq #IOTDF_INDEXSYNC,d0
.noindex2 move.b d0,(IO_FLAGS,a1)
clr.b (IO_ERROR,a1)
move.l (IO_DEVICE,a1),a6
jsr (DEV_BEGINIO,a6)
move.l (gl_io,GL),a1
move.l (gl_execbase,GL),a6
jsr (_LVOWaitIO,a6)
move.l (gl_io,GL),a1
bsr _tddisable81
move.b (IO_ERROR,a1),d0
bne _cmdw_rerr
;copy mfm data to fast mem for better performance
move.l d5,d0
bsr _copy_c2f
IFEQ 1
move.l (gl_chipbuf,GL),a0
move.l #$400,d0
moveq #0,d1
bsr _DumpMemory
move.l (gl_fastbuf,GL),a0
move.l #$400,d0
moveq #0,d1
bsr _DumpMemory
lea (gl_tmpbuf,GL),a0
move.l #$400,d0
moveq #0,d1
bsr _DumpMemory
lea (gl_verbuf,GL),a0
move.l #$400,d0
moveq #0,d1
bsr _DumpMemory
ENDC
;decode
sf d4 ;sync found?
move.l (wwf_sync,a2),a3 ;A3 = sync table
moveq #1,d3 ;sync count
btst #WWFB_MULTISYNC,(wwf_flags+1,a2)
beq .syncloop
move.w (a3)+,d3
.syncloop moveq #-1,d2 ;offset
.decode addq.l #1,d2
move.l d2,d0
move.l d5,d1
lsl.l #3,d1 ;mfm length in bits
move.l (gl_fastbuf,GL),a0 ;buffer
move.l a3,a1 ;sync
bsr _searchsync
tst.l d0
bpl .decode1
add.w #2*SYNCLEN,a3
subq.w #1,d3
bne .syncloop
tst.b d4
beq _cmdw_verrsync
bra _cmdw_verrdec
.decode1 st d4 ;sync found
move.l d0,d2 ;offset
move.l d5,d0
lsl.l #3,d0 ;mfm length in bits
move.w (gl_trk+wth_num,GL),d1 ;track number
ext.l d1
move.l (gl_fastbuf,GL),a0 ;mfm buffer
lea (gl_verbuf,GL),a1 ;decoded buffer
movem.l d2-d7/a2-a6,-(a7)
jsr ([wwf_decode,a2])
movem.l (a7)+,_MOVEMREGS
tst.l d0
beq .decode
;compare
IFEQ 1
lea (gl_tmpbuf,GL),a0
moveq #0,d0
move.w (wwf_datalen,a2),d0
moveq #0,d1
bsr _DumpMemory
lea (gl_verbuf,GL),a0
moveq #0,d0
move.w (wwf_datalen,a2),d0
moveq #0,d1
bsr _DumpMemory
ENDC
lea (gl_tmpbuf,GL),a0
lea (gl_verbuf,GL),a1
move.w (wwf_speclen,a2),d0
add.w (wwf_datalen,a2),d0
move.b d0,d1
lsr.w #2,d0
subq.w #1,d0
.cmp cmp.l (a0)+,(a1)+
dbne d0,.cmp
bne _cmdw_verrcmp
and.w #3,d1
beq .suc
subq.w #1,d1
.cmp1 cmp.b (a0)+,(a1)+
dbne d1,.cmp1
bne _cmdw_verrcmp
.suc moveq #-1,d0
rts
;write track
.std move.l (gl_io,GL),a1
lea (gl_tmpbuf,GL),a0
move.l a0,(IO_DATA,a1)
moveq #0,d0
move.w (gl_trk+wth_num,GL),d0
move.l d0,d1
mulu #$1600,d1
move.l d1,(IO_OFFSET,a1)
bsr _tdenable81
move.l #$1600,(IO_LENGTH,a1)
move.w #ETD_FORMAT,(IO_COMMAND,a1)
cmp.l #DD_SECS,(gl_io+8+dg_TotalSectors,GL)
beq .nohd
move.w #ETD_WRITE,(IO_COMMAND,a1)
.nohd clr.b (IO_ERROR,a1)
move.l (gl_execbase,GL),a6
jsr (_LVODoIO,a6)
move.l (gl_io,GL),a1
bsr _tddisable81
move.l (gl_io,GL),a1
move.b (IO_ERROR,a1),d0
bne _cmdw_werr
;flush
move.l (gl_io,GL),a1
move.w #ETD_UPDATE,(IO_COMMAND,a1)
jsr (_LVODoIO,a6)
move.l (gl_io,GL),a1
move.b (IO_ERROR,a1),d0
bne _cmdw_werr
;verify?
tst.l (gl_rd_nover,GL)
bne .suc
;clear trackbuffer
move.l (gl_io,GL),a1
move.w #ETD_CLEAR,(IO_COMMAND,a1)
jsr (_LVODoIO,a6)
move.l (gl_io,GL),a1
move.b (IO_ERROR,a1),d0
bne _cmdw_werr
;read track
move.l (gl_io,GL),a1
move.l (gl_fastbuf,GL),(IO_DATA,a1)
moveq #0,d0
move.w (gl_trk+wth_num,GL),d0
move.l d0,d1
mulu #$1600,d1
move.l d1,(IO_OFFSET,a1)
bsr _tdenable81
move.l #$1600,(IO_LENGTH,a1)
move.w #ETD_READ,(IO_COMMAND,a1)
jsr (_LVODoIO,a6)
move.l (gl_io,GL),a1
bsr _tddisable81
move.l (gl_io,GL),a1
move.b (IO_ERROR,a1),d0
bne _cmdw_rerr
;compare
lea (gl_tmpbuf,GL),a0
move.l (gl_fastbuf,GL),a1
move.w #$1600/4-1,d0
.cmps cmp.l (a0)+,(a1)+
dbne d0,.cmps
beq .suc
;verify error
bra _cmdw_verrcmp
;----------------------------------------
PRESECGAP = 4 ; bits before write length prepended for security and drive speed tolerance
PREMAXGAP = 256 ; maximum data length before data to write, to make sure that the data to
; write will not start too late after the index sync
POSTSECGAP = 4 ; bits after write length appended for security
_cmdw_raw
;calculate drive capabilties
move.w (gl_trk+wth_num,GL),d0
move.l (gl_trk+wth_wlen,GL),d1
bne .calgo
move.l (gl_trk+wth_len,GL),d1
addq.l #7,d1
lsr.l #3,d1
btst #TFB_RAWSINGLE,(gl_trk+wth_flags+1,a2)
bne .calgo
move.l #DEFWRITELEN,d1
.calgo move.l (gl_io,GL),a0
bsr _calcdrive
tst.l d0
bne .calcok
moveq #0,d0
rts
.calcok
;info
lea (_writetrk),a0
lea (gl_trk+wth_num,GL),a1
bsr _PrintArgs
;set raw write len
;length specified
move.l (gl_trk+wth_wlen,GL),d7
addq.l #1,d7
bclr #0,d7 ;round up to word length
lsl.l #3,d7 ;d7 = data write length in bits
beq .nowlen
move.l d7,d0
add.l #PRESECGAP+POSTSECGAP,d0
cmp.l (gl_drivelen,GL),d0
bhi _cmdw_longtrk
bra .wlenok
;if not specified use either drivelen or tracklen, whatever is shorter
.nowlen move.l (gl_drivelen,GL),d7
sub.l #PRESECGAP+POSTSECGAP,d7 ;security
cmp.l (gl_trk+wth_len,GL),d7
blo .wlenround
move.l (gl_trk+wth_len,GL),d7
.wlenround and.b #$f0,d7
.wlenok
;info
move.l d7,d0
bsr _printbitlen
lea (_writebytes),a0
bsr _Print
bsr _FlushOutput
;check if sync is set
lea (gl_trk+wth_sync,GL),a0
bsr _getsynclen
tst.l d0
beq _cmdw_nosyncset
;search and count syncs
bsr _getsyncsearchlen
move.l d0,d3 ;d3 = bitlength buffer
moveq #0,d0
move.w (gl_trk+wth_syncnum,GL),d0 ;syncno
move.l d3,d1 ;buflen
lea (gl_tmpbuf,GL),a0 ;buffer
lea (gl_trk+wth_sync,GL),a1 ;sync
bsr _countsync
tst.l d1
beq _cmdw_nosync
move.l d0,d6 ;D6 = bit offset sync
bmi _cmdw_lesssync
tst.w (gl_trk+wth_syncnum,GL)
bne .onesync
cmp.w #1,d1
beq .onesync
lea (_moresync),a0
move.l d1,-(a7)
move.l a7,a1
bsr _PrintArgs
addq.l #4,a7
bsr _FlushOutput
.onesync
;check for enough data after sync
move.l (gl_trklen,GL),d2
sub.l d6,d2
cmp.l d7,d2
blo _cmdw_lesstrkdata
;build data to write
move.l (gl_writelen,GL),d5
lsl.l #3,d5
sub.l d7,d5
sub.l #POSTSECGAP,d5 ;D5 = pre fill length
cmp.l #PREMAXGAP,d5
bls .pregapok
move.l #PREMAXGAP,d5
.pregapok
;copy data
lea (gl_tmpbuf,GL),a0
move.l (gl_chipbuf,GL),a1
moveq #32,d4 ;D4 = 32
move.l d5,d2
move.l d7,d0
move.l d6,d3
.copy bfextu (a0){d3:32},d1
bfins d1,(a1){d2:32}
add.l d4,d3
add.l d4,d2
sub.l d4,d0
bcc .copy
;post gap
move.l #$55555555,d0
move.l d5,d1
add.l d7,d1
subq.l #1,d1
bftst (a1){d1:1} ;last bit of data to write
bne .p1
ror.l #1,d0
.p1 addq.l #1,d1 ;first bit to write
move.l (gl_writelen,GL),d2
lsl.l #3,d2
sub.l d1,d2 ;amount of bits to write
bra .p6
.p5 bfins d0,(a1){d1:32}
add.l d4,d1
sub.l d4,d2
.p6 cmp.l d4,d2
bhi .p5
bfins d0,(a1){d1:d2}
;pre gap
move.l #$55555555,d0
bftst (a1){d5:1} ;first bit of data to write
beq .p2
ror.l #1,d0
.p2 move.l d5,d2
bra .p4
.p3 sub.l d4,d2
bfins d0,(a1){d2:32}
.p4 cmp.l d4,d2
bhi .p3
bfins d0,(a1){0:d2}
;write and flush track
moveq #IOTDF_INDEXSYNC,d0
sub.l a0,a0 ;density
bsr _cmdw_writeraw
tst.l d0
bne _cmdw_werr
;verify?
tst.l (gl_rd_nover,GL)
bne .suc
;clear trackbuffer
move.l (gl_io,GL),a1
move.w #ETD_CLEAR,(IO_COMMAND,a1)
jsr (_LVODoIO,a6)
move.l (gl_io,GL),a1
move.b (IO_ERROR,a1),d0
bne _cmdw_werr
;read track
move.l (gl_io,GL),a1
move.l (gl_chipbuf,GL),(IO_DATA,a1)
moveq #0,d0
move.w (gl_trk+wth_num,GL),d0
move.l d0,(IO_OFFSET,a1)
move.l (gl_writelen,GL),d5
add.l d5,d5
cmp.l #MAXTDLEN,d5
bls .lenok
move.l #MAXTDLEN,d5 ;D5 = readlen
.lenok move.l d5,(IO_LENGTH,a1)
move.w #ETD_RAWREAD,(IO_COMMAND,a1)
move.w (gl_trk+wth_num,GL),d0
bsr _tdenable81
jsr (_LVODoIO,a6)
move.l (gl_io,GL),a1
bsr _tddisable81
move.b (IO_ERROR,a1),d0
bne _cmdw_rerr
;copy mfm data to fast mem for better performance
move.l d5,d0
bsr _copy_c2f
;search sync
moveq #1,d0 ;syncno
move.l (gl_writelen,GL),d1
lsl.l #3,d1 ;buflen
move.l (gl_fastbuf,GL),a0
lea (gl_trk+wth_sync,GL),a1
bsr _countsync
move.l d0,d3 ;D3 = bit offset first sync
move.l d1,d5 ;D5 = sync count
beq _cmdw_verrsync
cmp.w #1,d5
beq .vonesync
lea (_moreverifysync),a0
move.l d5,-(a7)
move.l a7,a1
bsr _PrintArgs
addq.l #4,a7
bsr _FlushOutput
.vonesync
;compare beginning from start
.compare lea (gl_tmpbuf,GL),a0
move.l (gl_fastbuf,GL),a1
move.l d7,d2 ;bit length to write/compare
moveq #32,d4 ;D4 = 32
.cmp bfextu (a0){d6:32},d0
bfextu (a1){d3:32},d1
cmp.l d0,d1
bne .verr
sub.l d4,d2
addq.l #4,a0
addq.l #4,a1
cmp.l d4,d2
bhs .cmp
tst.l d2
beq .suc
bfextu (a0){d6:d2},d0
bfextu (a1){d3:d2},d1
ror.l d2,d0 ;for correct error position
ror.l d2,d1
cmp.l d0,d1
bne .verr
.suc
;info
lea (_writesuc),a0
bsr _Print
moveq #-1,d0
rts
.verr subq.l #1,d5 ;syncs left?
beq .verr0
move.l d3,d0
addq.l #1,d0 ;offset
move.l (gl_writelen,GL),d1 ;buflen
lsl.l #3,d1
move.l (gl_fastbuf,GL),a0
lea (gl_trk+wth_sync,GL),a1
bsr _searchsync
move.l d0,d3
bra .compare
.verr0 move.l d7,d5
sub.l d2,d5 ;d5 = offset start
moveq #0,d2
moveq #0,d3
subq.l #1,d5
.verr1 addq.l #1,d5
addx.l d0,d0
addx.l d2,d2
addx.l d1,d1
addx.l d3,d3
cmp.w d2,d3
beq .verr1
;compare beginning from end
lea (gl_tmpbuf,GL),a0
move.l (gl_fastbuf,GL),a1
add.l d7,d6
add.l d7,d3
.cmp2 subq.l #4,a0
subq.l #4,a1
bfextu (a0){d6:32},d0
bfextu (a1){d3:32},d1
cmp.l d0,d1
bne .verr2
sub.l d4,d7
cmp.l d4,d7
bhs .cmp2
bfextu (a0){d6:d7},d0
bfextu (a1){d3:d7},d1
.verr2 moveq #0,d2
moveq #0,d3
.verr3 sub.l #1,d7
roxr.l #1,d0
addx.l d2,d2
roxr.l #1,d1
addx.l d3,d3
cmp.w d2,d3
beq .verr3
move.l d5,d0
move.l d7,d1
bra _cmdw_verroff
;----------------------------------------
_cmdw_werr lea (_writedisk),a0
bsr _PrintErrorTD
moveq #0,d0
rts
_cmdw_rerr lea (_readdisk),a0
bsr _PrintErrorTD
moveq #0,d0
rts
_cmdw_nosync lea (_nosync),a0
_cmdw_error bsr _Print
moveq #0,d0
rts
_cmdw_encoder_na
lea _encoder_na,a0
bra _cmdw_error
_cmdw_encoder_badlen
lea _encoder_badlen,a0
bra _cmdw_error
_cmdw_encoder_badend
lea _encoder_badend,a0
bra _cmdw_error
_cmdw_encoder_badstrt
lea _encoder_badstrt,a0
bra _cmdw_error
_cmdw_encoder_fail
lea _encoder_fail,a0
bra _cmdw_error
_cmdw_lesssync lea (_lesssync),a0
bra _cmdw_error
_cmdw_nosyncset lea (_nosyncset),a0
bra _cmdw_error
_cmdw_corrupt lea (_corrupt),a0
bra _cmdw_error
_cmdw_verrsync lea (_verifyerrsync),a0
bra _cmdw_error
_cmdw_verrdec lea (_verifyerrdec),a0
bra _cmdw_error
_cmdw_verrcmp lea (_verifyerrcmp),a0
bra _cmdw_error
; D0 = first offset in bits
; D1 = last offset in bits
_cmdw_verroff movem.l d0-d1,-(a7)
lea (_verifyerroff1),a0
bsr _Print
move.l (a7)+,d0
bsr _printbitlen
lea (_verifyerroff2),a0
bsr _Print
move.l (a7)+,d0
bsr _printbitlen
lea (_verifyerroff3),a0
bsr _Print
moveq #0,d0
rts
_cmdw_longtrk lsr.l #3,d0
move.l d0,-(a7)
move.l a7,a1
lea (_longtrk),a0
bsr _PrintArgs
addq.l #4,a7
move.l (gl_drivelen,GL),d0
bsr _printbitlen
bsr _PrintLn
moveq #0,d0
rts
_cmdw_lesstrkdata
lea (_lesstrkdata1),a0
bsr _Print
move.l d2,d0
bsr _printbitlen
lea (_lesstrkdata2),a0
bsr _Print
move.l d7,d0
bsr _printbitlen
lea (_lesstrkdata3),a0
bsr _Print
moveq #0,d0
rts
;----------------------------------------
; unpack track data, and copy to gl_tmpbuf
; IN: _fastbuf track data
; OUT: D0 = ULONG length in bits, or 0 on failure
; gl_tmpbuf unpacked track data
_unpacktrack movem.l d2-d7,-(a7)
cmp.w #TT_RAW,(gl_trk+wth_type,GL)
beq .raw
bsr _gettt
moveq #0,d0
move.w (wwf_speclen,a0),d0 ;D0 = speclen
move.w (wwf_datalen,a0),d2 ;D2 = datalen
move.l d0,d4
add.w d2,d4 ;D4 = speclen + datalen
move.l (gl_trk+wth_len,GL),d7 ;in bits
lsr.l #1,d7
bcs .fail
lsr.l #1,d7
bcs .fail
lsr.l #1,d7
bcs .fail
sub.l d0,d7 ;D7 = length
bcs .fail
move.l (gl_fastbuf,GL),a0 ;A0 = fastbuf
lea (gl_tmpbuf,GL),a1 ;A1 = tmpbuf
;copy special
bra .copyspecin
.copyspec move.b (a0)+,(a1)+
.copyspecin dbf d0,.copyspec
move.w (gl_trk+wth_flags,GL),d0
btst #TFB_LEQ,d0
bne .leq
btst #TFB_SLINC,d0
bne .slinc
btst #TFB_SLEQ,d0
bne .sleq
cmp.w d2,d7
bne .fail
addq.l #3,d7 ;round up
lsr.w #2,d7
beq .ok ;if datalen=0
subq.w #1,d7