/
graphql.cljc
263 lines (223 loc) · 9.04 KB
/
graphql.cljc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
(ns com.wsscode.pathom.connect.graphql
(:require [camel-snake-kebab.core :as csk]
[clojure.spec.alpha :as s]
[clojure.string :as str]
[com.wsscode.pathom.core :as p]
[com.wsscode.pathom.connect :as pc]
[com.wsscode.pathom.graphql :as pg]))
(s/def ::ident-map (s/map-of string? (s/tuple string? string?)))
(def schema-query
[{:__schema
[{:queryType
[:name
:kind
{:fields
[:name
{:args [:name :defaultValue {:type [:kind :name]}]}
{:type [:kind :name {:ofType [:kind :name]}]}]}]}
{:types
[:name
:kind
{:interfaces [:name :kind]}
{:fields
[:name
{:args [:name :defaultValue {:type [:kind :name]}]}
{:type [:kind :name {:ofType 3}]}]}]}]}])
(defn camel-case [s]
(csk/->camelCase s))
(defn kebab-case [s]
(csk/->kebab-case s))
(defn kebab-key [s]
(keyword (kebab-case (name s))))
(defn index-key [s] (name (kebab-key s)))
(defn prefixed-key [prefix p s] (keyword (str prefix "." p) (index-key s)))
(defn type-key [prefix s] (prefixed-key prefix "types" s))
(defn interface-key [prefix s] (prefixed-key prefix "interfaces" s))
(defn type->field-entry [prefix {:keys [kind name ofType]}]
(case kind
"NON_NULL" (recur prefix ofType)
"LIST" (recur prefix ofType)
"OBJECT" {(type-key prefix name) {}}
"INTERFACE" {(interface-key prefix name) {}}
{}))
(defn index-type-key [prefix {:keys [name kind]}]
(let [key-fun (case kind
"OBJECT" type-key
"INTERFACE" interface-key)]
(key-fun prefix name)))
(defn entity-field-key [prefix entity field]
(keyword (str prefix "." (index-key entity)) (index-key field)))
(defn index-type [prefix {:keys [fields name interfaces] :as input}]
{#{(index-type-key prefix input)}
(-> {}
; fields
(into (map #(vector (entity-field-key prefix name (:name %))
(type->field-entry prefix (:type %)))) fields)
; interfaces
(into (map #(vector (interface-key prefix (:name %)) {}) interfaces)))})
(defn ident-root? [{::keys [ident-map]} {:keys [args]}]
(and (= 1 (count args))
(get ident-map (-> args first :name))))
(defn ident-root [{::keys [prefix ident-map]} {:keys [args] :as query-root}]
(if-let [[entity field] (get ident-map (-> args first :name))]
(if (= 1 (count args))
(assoc query-root ::entity-field (entity-field-key prefix entity field)))))
(defn index-schema-io [{::keys [prefix schema] :as input}]
(let [schema (:__schema schema)]
(-> {}
(into (comp (filter (comp #{"OBJECT" "INTERFACE"} :kind))
(map (partial index-type prefix)))
(:types schema))
(assoc #{} (into {} (map #(vector (keyword prefix (index-key (:name %)))
(type->field-entry prefix (:type %))))
(->> schema :queryType :fields
(remove (partial ident-root? input)))))
(as-> <>
(reduce (fn [idx {:keys [type]
::keys [entity-field]}]
(update idx #{entity-field} pc/merge-io {(type-key prefix (:name type)) {}}))
<>
(->> schema :queryType :fields
(keep (partial ident-root input))))))))
(defn args-translate [{::keys [prefix ident-map]} args]
(or
(if-let [[entity field] (get ident-map (-> args first :name))]
(if (= 1 (count args))
#{(keyword (entity-field-key prefix entity field))}))
#{}))
(defn index-schema-oif [{::keys [prefix schema resolver]
::pc/keys [index-io]
:as input}]
(let [schema (:__schema schema)
fields (-> schema :queryType :fields)
idents (keep (partial ident-root input) fields)
roots (remove (partial ident-root? input) fields)]
(-> {}
(into (map #(vector (keyword prefix (index-key (:name %)))
{(args-translate input (:args %)) #{resolver}}))
roots)
(into (mapcat (fn [{::keys [entity-field]
:keys [type]}]
(let [fields (-> (get index-io #{(type-key prefix (:name type))})
keys)]
(mapv (fn [field]
[field {#{entity-field} #{resolver}}])
fields))))
idents))))
(defn index-autocomplete-ignore [{::keys [prefix schema]}]
(let [schema (:__schema schema)]
(-> #{}
(into (comp (filter (comp #{"OBJECT" "INTERFACE"} :kind))
(map (partial index-type-key prefix)))
(:types schema)))))
(defn index-idents [{::keys [prefix ident-map]}]
(into #{} (map #(apply entity-field-key prefix %))
(vals ident-map)))
(defn index-graphql-idents [{::keys [prefix schema]
::pc/keys [index-io]
:as input}]
(let [schema (:__schema schema)
fields (-> schema :queryType :fields)
idents (keep (partial ident-root input) fields)]
(-> {}
(into (mapcat (fn [{:keys [type args name]
::keys [entity-field]}]
(let [fields (-> (get index-io #{(type-key prefix (:name type))})
keys)]
(mapv (fn [field]
[field {::entity-field entity-field
::ident-key (keyword (kebab-case name)
(kebab-case (-> args first :name)))}])
fields))))
idents))))
(defn index-schema [{::keys [resolver] :as input}]
(let [index-io (index-schema-io input)
input (assoc input ::pc/index-io index-io)]
{::pc/index-resolvers
{resolver {::pc/sym resolver
::pc/cache? false}}
::pc/index-io
index-io
::pc/index-oir
(index-schema-oif input)
::pc/autocomplete-ignore
(index-autocomplete-ignore input)
::pc/idents
(index-idents input)
::field->ident
(index-graphql-idents input)}))
(s/fdef index-schema
:args (s/cat :input (s/keys :req [::resolver ::schema ::prefix] :opt [::ident-map]))
:ret (s/merge ::pc/indexes
(s/keys :req [::pc/autocomplete-ignore ::field->ident])))
;;;; resolver
(defn camel-key [s]
(if (vector? s)
s
(keyword (camel-case (name s)))))
(defn gql-ident-reader [{:keys [ast]
:as env}]
(if (vector? (:key ast))
(let [e (p/entity env)]
(let [json (get e (keyword (pg/ident->alias (:key ast))))]
(p/join json env)))
::p/continue))
(defn index-graphql-errors [errors] (group-by :query-path errors))
(defn error-stamper [{::keys [errors base-path]
::p/keys [path errors*]}]
(let [path' (mapv #(cond
(p/ident? %)
(camel-key (namespace (first %)))
(keyword? %)
(camel-key %)
:else %)
path)]
(if-let [local-errors (get errors path')]
(do
(if errors*
(swap! errors* assoc (into base-path (remove p/ident? path)) (first local-errors)))
::error)
::p/continue)))
(defn alias-for-line [query line]
(try
(if-let [[_ alias] (-> (str/split-lines query)
(nth (dec line))
(->> (re-find #"^\s*([^:]+): \w+")))]
alias)
(catch #?(:clj Throwable :cljs :default) _ nil)))
(def parser-item
(p/parser {::p/plugins [(p/env-plugin {::p/reader [error-stamper
(p/map-reader* {::p/map-key-transform camel-key})
gql-ident-reader]})]}))
(defn query->graphql
"Like the pg/query-graphql, but adds name convertion so clj names like :first-name turns in firstName."
[query]
(pg/query->graphql query {::pg/js-name (comp camel-case name)}))
(defn ast->graphql [{:keys [ast]
::pc/keys [indexes]}
ent]
(let [{::keys [field->ident]} indexes
{:keys [key]} ast
q [(p/ast->query ast)]]
(if-let [{::keys [entity-field ident-key]} (get field->ident key)]
(let [ident-key' [ident-key (get ent entity-field)]]
[{ident-key' q}])
q)))
(defn build-query [{::p/keys [parent-query]
::keys [prefix]
:as env}
ent]
(->> parent-query p/query->ast
(p/filter-ast #(str/starts-with? (or (namespace (:dispatch-key %)) "") prefix))
:children
(remove #(contains? ent (:key %)))
(remove (comp vector? :key))
(map #(ast->graphql (assoc env :ast %) ent))
(reduce p/merge-queries)))
(defn pull-idents [data]
(reduce-kv (fn [x k v]
(if (vector? k)
(into x v)
(assoc x k v)))
{}
data))