-
Notifications
You must be signed in to change notification settings - Fork 0
/
k8s-calico.tf
182 lines (157 loc) · 6.17 KB
/
k8s-calico.tf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
# Infrastructure for Yandex Cloud Managed Service for Kubernetes cluster with Calico network policy management.
#
# Set the configuration of the Managed Service for Kubernetes cluster.
locals {
folder_id = "" # Set your cloud folder ID.
k8s_version = "" # Set the Kubernetes version.
zone_a_v4_cidr_blocks = "10.1.0.0/16" # Set the CIDR block for subnet.
sa_name = "" # Set the service account name
}
resource "yandex_vpc_network" "k8s-network" {
description = "Network for the Managed Service for Kubernetes cluster"
name = "k8s-network"
}
resource "yandex_vpc_subnet" "subnet-a" {
description = "Subnet in ru-central1-a availability zone"
name = "subnet-a"
zone = "ru-central1-a"
network_id = yandex_vpc_network.k8s-network.id
v4_cidr_blocks = [local.zone_a_v4_cidr_blocks]
}
resource "yandex_vpc_security_group" "k8s-main-sg" {
description = "Security group for the Managed Service for Kubernetes cluster"
name = "k8s-main-sg"
network_id = yandex_vpc_network.k8s-network.id
}
resource "yandex_vpc_security_group_rule" "loadbalancer" {
description = "The rule allows availability checks from the load balancer's range of addresses"
direction = "ingress"
security_group_binding = yandex_vpc_security_group.k8s-main-sg.id
protocol = "TCP"
predefined_target = "loadbalancer_healthchecks" # The load balancer's address range.
from_port = 0
to_port = 65535
}
resource "yandex_vpc_security_group_rule" "node-interaction" {
description = "The rule allows the master-node and node-node interaction within the security group"
direction = "ingress"
security_group_binding = yandex_vpc_security_group.k8s-main-sg.id
protocol = "ANY"
predefined_target = "self_security_group"
from_port = 0
to_port = 65535
}
resource "yandex_vpc_security_group_rule" "pod-service-interaction" {
description = "The rule allows the pod-pod and service-service interaction"
direction = "ingress"
security_group_binding = yandex_vpc_security_group.k8s-main-sg.id
protocol = "ANY"
v4_cidr_blocks = [local.zone_a_v4_cidr_blocks]
from_port = 0
to_port = 65535
}
resource "yandex_vpc_security_group_rule" "ICMP-debug" {
description = "The rule allows receipt of debugging ICMP packets from internal subnets"
direction = "ingress"
security_group_binding = yandex_vpc_security_group.k8s-main-sg.id
protocol = "ICMP"
v4_cidr_blocks = [local.zone_a_v4_cidr_blocks]
}
resource "yandex_vpc_security_group_rule" "port-6443" {
description = "The rule allows connection to Kubernetes API on 6443 port from the Internet"
direction = "ingress"
security_group_binding = yandex_vpc_security_group.k8s-main-sg.id
protocol = "TCP"
v4_cidr_blocks = ["0.0.0.0/0"]
port = 6443
}
resource "yandex_vpc_security_group_rule" "port-443" {
description = "The rule allows connection to Kubernetes API on 443 port from the Internet"
direction = "ingress"
security_group_binding = yandex_vpc_security_group.k8s-main-sg.id
protocol = "TCP"
v4_cidr_blocks = ["0.0.0.0/0"]
port = 443
}
resource "yandex_vpc_security_group_rule" "outgoing-traffic" {
description = "The rule allows all outgoing traffic"
direction = "egress"
security_group_binding = yandex_vpc_security_group.k8s-main-sg.id
protocol = "ANY"
v4_cidr_blocks = ["0.0.0.0/0"]
from_port = 0
to_port = 65535
}
resource "yandex_iam_service_account" "k8s-sa" {
description = "Service account for the Managed Service for Kubernetes cluster and node group"
name = local.sa_name
}
# Assign "editor" role to service account.
resource "yandex_resourcemanager_folder_iam_binding" "editor" {
folder_id = local.folder_id
role = "editor"
members = [
"serviceAccount:${yandex_iam_service_account.k8s-sa.id}"
]
}
# Assign "container-registry.images.puller" role to service account.
resource "yandex_resourcemanager_folder_iam_binding" "images-puller" {
folder_id = local.folder_id
role = "container-registry.images.puller"
members = [
"serviceAccount:${yandex_iam_service_account.k8s-sa.id}"
]
}
resource "yandex_kubernetes_cluster" "k8s-cluster" {
description = "Managed Service for Kubernetes cluster"
name = "k8s-cluster"
network_id = yandex_vpc_network.k8s-network.id
master {
version = local.k8s_version
master_location {
zone = yandex_vpc_subnet.subnet-a.zone
subnet_id = yandex_vpc_subnet.subnet-a.id
}
public_ip = true
security_group_ids = [yandex_vpc_security_group.k8s-main-sg.id]
}
service_account_id = yandex_iam_service_account.k8s-sa.id # Cluster service account ID.
node_service_account_id = yandex_iam_service_account.k8s-sa.id # Node group service account ID.
network_policy_provider = "CALICO"
depends_on = [
yandex_resourcemanager_folder_iam_binding.editor,
yandex_resourcemanager_folder_iam_binding.images-puller
]
}
resource "yandex_kubernetes_node_group" "k8s-node-group" {
description = "Node group for the Managed Service for Kubernetes cluster"
name = "k8s-node-group"
cluster_id = yandex_kubernetes_cluster.k8s-cluster.id
version = local.k8s_version
scale_policy {
fixed_scale {
size = 1 # Number of hosts
}
}
allocation_policy {
location {
zone = yandex_vpc_subnet.subnet-a.zone
}
}
instance_template {
platform_id = "standard-v2" # Intel Cascade Lake
network_interface {
nat = true
subnet_ids = [yandex_vpc_subnet.subnet-a.id]
security_group_ids = [yandex_vpc_security_group.k8s-main-sg.id]
}
resources {
memory = 4 # GB
cores = 4 # Number of CPU cores
}
boot_disk {
type = "network-hdd"
size = 64 # GB
}
}
}