-
Notifications
You must be signed in to change notification settings - Fork 2
/
ldap-server.ycp
249 lines (215 loc) · 6.73 KB
/
ldap-server.ycp
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
/**
* File: clients/ldap-server.ycp
* Package: Configuration of ldap-server
* Summary: Main file
* Authors: Andreas Bauer <abauer@suse.de>
*
* $Id$
*
* Main file for ldap-server configuration. Uses all other files.
*/
{
/***
* <h3>Configuration of ldap-server</h3>
*/
textdomain "ldap-server";
/* The main () */
y2milestone ("----------------------------------------");
y2milestone ("LdapServer module started");
import "Progress";
import "Report";
import "Summary";
import "RichText";
import "CommandLine";
include "ldap-server/wizards.ycp";
define boolean serviceHandler (map<string, string> options ) {
string command = CommandLine::UniqueOption( options,
["enable", "disable" ] );
if( command == nil ) return false;
LdapServer::WriteServiceEnabled( command == "enable" );
return true;
}
define boolean getDatabaseListHandler (map options) {
list<map<string, string> > dbList = LdapServer::ReadDatabaseList();
string s = "";
foreach( map<string,string> db, dbList,
{
s = s + db["suffix"]:"" + " (" + db["type"]:"" + ") " + "<br>";
}
);
CommandLine::Print (RichText::Rich2Plain("<br>"+s));
return false;
}
define boolean addDatabaseHandler (map options ) {
boolean ret = false;
map<string, string> db = $[];
// map<string, any> edb = LdapServer::ReadDatabase();
// y2milestone("DBs: %1", edb);
//
//
if (options["basedn"]:nil != nil )
{
db["suffix"] = options["basedn"]:"";
}
else
{
CommandLine::Print (_("No base DN provided\n"));
return false;
}
db["type"] = options["type"]:"hdb";
if (options["rootdn"]:nil != nil)
{
db["rootdn"] = options["rootdn"]:"";
}
if (options["password"]:nil != nil)
{
db["rootpw_clear"] = options["password"]:"";
}
db["pwenctype"] = options["enctype"]:"SSHA";
if (options["dbdir"]:nil != nil)
{
db["directory"] = options["dbdir"]:"";
}
if(LdapServer::ReadServiceEnabled() == false)
{
Report::Error(_("Database cannot be created when the service is not enabled"));
return false;
}
// y2milestone("db-options : %1", db);
//
ret = LdapServer::AddDatabase(0,db, true, true);
if(!ret)
{
CommandLine::Print (_("Error while adding the database"));
map<string, string> err = LdapServer::ReadError();
Report::Error(err["msg"]:"" + "<br>" + err["details"]:"");
return false;
}
return true;
}
define boolean getSchemaListHandler (map options ) {
string s = "";
integer i = 0;
foreach(string v, LdapServer::ReadSchemaList (),
{
if ( v != "schema" ) // skip the baseentry (hardcoded schema)
s = s + " "+ v +"<br>";
});
CommandLine::Print (RichText::Rich2Plain("<br>"+s));
return false; // do not call Write...
}
define boolean addSchemaHandler (map options ) {
if (options["file"]:"" != "")
{
string file = options["file"]:"";
if ( regexpmatch( file, ".*\.schema$" ) )
{
if (! LdapServer::AddSchemaToSchemaList(file) ) {
map<string, string> err = LdapServer::ReadError();
Report::Error(err["msg"]:"" + "<br>" + err["details"]:"");
return false;
}
}
else if (! LdapServer::AddLdifToSchemaList(file) )
{
map<string, string> err = LdapServer::ReadError();
Report::Error(err["msg"]:"" + "<br>" + err["details"]:"");
return false;
}
return true;
}
return false;
}
map cmdline_description = $[
"id" : "ldap-server",
/* Command line help text for the Xldap-server module */
"help" : _("Configuration of LDAP server"),
"guihandler" : LdapServerSequence,
"initialize" : LdapServer::Read,
"finish" : LdapServer::Write,
"actions" : $[
"service" : $[
"handler" : serviceHandler,
"help" : _("Enable/Disable the service")
],
"addDatabase" : $[
"handler" : addDatabaseHandler,
"help" : _("Add a new database"),
],
"getDatabaseList" : $[
"handler" : getDatabaseListHandler,
"help" : _("Show a list of currently available databases"),
],
"getSchemaList": $[
"handler" : getSchemaListHandler,
"help" : _("Show a list of currently configured schemas"),
],
"addSchema": $[
"handler" : addSchemaHandler,
"help" : _("Add a schema to the list"),
],
],
"options" : $[
"enable" : $[ "help" : _("Enable the service") ],
"disable" : $[ "help" : _("Disable the service") ],
"type" : $[
"help" : _("Database type (\"hdb\" or \"bdb\")"),
"type" : "string"
],
"basedn" : $[
"help" : _("Base DN for the database"),
"type" : "string"
],
"rootdn" : $[
"help" : _("DN for the administrator login"),
"type" : "string"
],
"password" : $[
"help" : _("Administrator password"),
"type" : "string"
],
"enctype" : $[
"help" : "SSHA, SHA, SMD5, CRYPT, PLAIN",
"type" : "string"
],
"dbdir" : $[
"help" : _("Directory for the database"),
"type" : "string"
],
"file" : $[
"help" : _("File"),
"type" : "string"
],
"pos" : $[
"help" : _("Position"),
"type" : "string"
]
],
"mappings" : $[
"service" :[ "enable", "disable" ],
"addDatabase" : [ "basedn", "rootdn", "password", "enctype", "dbdir", "type" ],
"getDatabaseList" : [],
"getSchemaList" : [],
"addSchema": [ "file" ]
]
];
/* is this proposal or not? */
boolean propose = false;
list args = WFM::Args();
if(size(args) > 0) {
if(is(WFM::Args(0), path) && WFM::Args(0) == .propose) {
y2milestone("Using PROPOSE mode");
propose = true;
}
}
/* main ui function */
any ret = nil;
if(propose) ret = InstProposalSequence();
else ret = CommandLine::Run(cmdline_description);
y2debug("ret=%1", ret);
/* Finish */
y2milestone("LdapServer module finished");
y2milestone("----------------------------------------");
return ret;
/* EOF */
}