-
Notifications
You must be signed in to change notification settings - Fork 7
/
healing.clj
431 lines (376 loc) · 16.2 KB
/
healing.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
(ns com.yetanalytics.datasim.xapi.statement.healing
"Statement healing, i.e. the repair of Statements that are missing
required properties."
(:require [clojure.set :as cset]
[clojure.spec.alpha :as s]
[clojure.test.check.generators :as stest]
[clojure.walk :as w]
[xapi-schema.spec :as xs]
[com.yetanalytics.datasim.util.random :as random]
[com.yetanalytics.datasim.model :as model]
[com.yetanalytics.datasim.xapi.path :as xp]
[com.yetanalytics.datasim.xapi.profile :as profile]
[com.yetanalytics.datasim.xapi.profile.activity :as activity]
[com.yetanalytics.datasim.xapi.profile.verb :as verb]
[com.yetanalytics.datasim.xapi.profile.template :as template]))
;; Statement healing is currently limited to inserting missing required
;; properties; it does not fix properties that are not included but have
;; invalid values.
;; TODO: Either implement improved healing or apply warnings.
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Statement Completion
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(s/def ::type-iri-map
::profile/type-iri-map)
(s/def ::activity-map
::activity/activity-map)
(s/def ::verb-map
::verb/verb-map)
(s/def ::alignments
::model/alignments)
(s/def ::template
::template/template)
(s/def ::registration
uuid?)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Helpers
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defn- merge-nested
"Perform a nested merge of `m2` onto `m1`. Recurses on maps and replaces
all other values."
[m1 m2]
(merge-with
(fn [v1 v2] (if (and (map? v1) (map? v2)) (merge-nested v1 v2) v2))
m1
m2))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Verbs
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(def verb-id-gen (s/gen :verb/id))
(defn- generate-verb [rng _]
{"id" (stest/generate verb-id-gen 1 (random/rand-unbound-int rng))})
(s/fdef complete-verb
:args (s/cat :verb (s/nilable map?)
:inputs (s/keys :req-un [::verb-map ::alignments])
:rng ::random/rng)
:ret ::xs/verb)
(defn complete-verb
[{verb-id "id" :as verb} {:keys [verb-map weights]} rng]
(let [return-verb (fn [_] verb)
merge-verb (fn [v] (merge-nested v verb))
verb-weights (:verbs weights)]
(or
;; Verb found by ID
(some->> verb-id
verb-map
merge-verb)
;; Verb w/ ID not found, return as-is
(some->> verb-id
return-verb)
;; Verb w/o ID not found, generate ID
(some->> verb
(generate-verb rng)
merge-verb)
;; Choose random verb
(some->> verb-map
not-empty
(random/choose-map rng verb-weights))
;; Generate random verb as verb map is empty
(some->> {}
(generate-verb rng)))))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Activities
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(def activity-id-gen (s/gen :activity/id))
(defn- generate-activity [rng _]
{"id" (stest/generate activity-id-gen 1 (random/rand-unbound-int rng))
"objectType" "Activity"})
(s/fdef complete-activity
:args (s/cat :activity (s/nilable map?)
:inputs (s/keys :req-un [::activity-map ::alignments])
:rng ::random/rng)
:ret ::xs/activity)
(defn complete-activity
[{activity-id "id" {activity-type "type"} "definition" :as activity}
{:keys [activity-map weights]}
rng]
(let [return-activity (fn [_] activity)
merge-activity (fn [a] (merge-nested a activity))
activity-weights (get weights :activities)
act-type-weights (get weights :activity-types)]
(or
;; Get activity by ID
(some->> activity-id
(get (reduce merge {} (vals activity-map)))
merge-activity)
;; Get activity by type
(some->> activity-type
(get activity-map)
not-empty
(random/choose-map rng activity-weights)
merge-activity)
;; Activity w/ ID not found, return as-is
(some->> activity-id
return-activity)
;; Activity w/o ID not found, assoc generated
(some->> activity
(generate-activity rng)
merge-activity)
;; Choose random activity
(some->> activity-map
not-empty
(random/choose-map rng act-type-weights)
(random/choose-map rng activity-weights))
;; Generate random activity as activity map is empty
(some->> {}
(generate-activity rng)))))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Agents
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defn- get-ifi
[{:strs [mbox mbox_sha1sum openid account]}]
(or mbox mbox_sha1sum openid account))
(def agent-gen (s/gen ::xs/agent))
(def agent-account-gen (s/gen :agent/account))
(s/fdef complete-agent
:args (s/cat :agent map?
:rng ::random/rng)
:ret ::xs/agent)
(defn complete-agent [agent rng]
(let [ifi (get-ifi agent)
account (get agent "account")
agent* (assoc agent "objectType" "Agent")]
(cond
(nil? ifi)
(merge (stest/generate agent-gen 1 (random/rand-unbound-int rng)) agent*)
(and account
(or (not (contains? account "homePage"))
(not (contains? account "name"))))
(update agent*
"account"
(partial merge (stest/generate agent-account-gen
1
(random/rand-unbound-int rng))))
:else
agent*)))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Groups
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(def group-gen (s/gen ::xs/group))
(def group-account-gen (s/gen :group/account))
(s/fdef complete-group
:args (s/cat :group map?
:rng ::random/rng)
:ret ::xs/group)
(defn complete-group [group rng]
(let [ifi (get-ifi group)
account (get group "account")
members (not-empty (get group "member"))
group* (cond-> group
true (assoc "objectType" "Group")
members (assoc "member" (mapv #(complete-agent % rng)
members)))]
(cond
(and (nil? ifi) (nil? members))
(merge (stest/generate group-gen 1 (random/rand-unbound-int rng)) group*)
(and account
(or (not (contains? account "homePage"))
(not (contains? account "name"))))
(update group*
"account"
(partial merge (stest/generate group-account-gen
1
(random/rand-unbound-int rng))))
:else
group*)))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Actors (Agents and Groups)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(s/fdef complete-actor
:args (s/cat :actor map?
:rng ::random/rng)
:ret (s/or :agent ::xs/agent
:group ::xs/group))
;; TODO: WARNING if Template actually requires an authority (since it's
;; supposed to only be set by the LRS)
(defn complete-actor
[{:strs [objectType member] :as authority} rng]
(if (or (= "Group" objectType)
(some? member))
(complete-group authority rng)
(complete-agent authority rng)))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Context
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(s/fdef complete-context
:args (s/cat :context (s/nilable map?)
:inputs (s/keys :req-un [::activity-map
::alignments
::template
::registration])
:rng ::random/rng)
:ret ::xs/context)
(defn complete-context
[{:strs [instructor team]
{:strs [category grouping parent other]} "contextActivities"
:as context}
{{profile-ver-id :inScheme} :template
registration :registration :as inputs}
rng
& {:keys [sub-statement?] :or {sub-statement? false}}]
(let [complete-activities (partial mapv #(complete-activity % inputs rng))]
(cond-> context
;; Context Agents + Groups
instructor (update-in ["instructor"] complete-actor rng)
team (update-in ["team"] complete-group rng)
;; Context Activities
category (update-in ["contextActivities" "category"] complete-activities)
grouping (update-in ["contextActivities" "grouping"] complete-activities)
parent (update-in ["contextActivities" "parent"] complete-activities)
other (update-in ["contextActivities" "other"] complete-activities)
;; Restore profile version ID if needed
;; TODO: WARNING if the Template actively overwrites or contradicts
(and (not sub-statement?)
(->> (get-in context ["contextActivities" "category"])
(some (fn [{id "id"}] (#{profile-ver-id} id)))
not))
(update-in ["contextActivities" "category"] conj {"id" profile-ver-id})
;; Restore registration if needed
;; TODO: WARNING if the Template actively overwrites
(and (not sub-statement?)
(->> (get context "registration")
(not= registration)))
(assoc-in ["registration"] registration))))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Attachments
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(def attachment-gen (s/gen ::xs/attachment))
(defn- complete-attachment
[rng attachment]
(merge (stest/generate attachment-gen 1 (random/rand-unbound-int rng)) attachment))
(s/fdef complete-attachments
:args (s/cat :attachments (s/coll-of map?)
:rng ::random/rng)
:ret ::xs/attachments)
(defn complete-attachments
[attachments rng]
(mapv (partial complete-attachment rng) attachments))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Statement Ref
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(def statement-ref-id-gen (s/gen :statement-ref/id))
(s/fdef complete-statement-ref
:args (s/cat :statement-ref map?
:rng ::random/rng)
:ret ::xs/statement-ref)
(defn complete-statement-ref
[{:strs [id] :as statement-ref} rng]
(cond-> (assoc statement-ref "objectType" "StatementRef")
(nil? id) (assoc "id" (stest/generate statement-ref-id-gen
1
(random/rand-unbound-int rng)))))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Sub Statement
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defn- complete-sub-object
[object inputs rng]
(case (get object "objectType")
"Activity" (complete-activity object inputs rng)
"Agent" (complete-agent object rng)
"Group" (complete-group object rng)
"StatementRef" (complete-statement-ref object rng)
"SubStatement" (throw (ex-info "Cannot have nested SubStatements!"
{:type ::nested-substatement
:object object}))
(let [props (keys object)
types (reduce (fn [types* prop]
(-> (get xp/spec-hint-properties-m prop)
(cset/intersection types*)))
(get xp/default-object-type-m ["object" "object"])
props)]
(condp #(contains? %2 %1) types
"activity" (complete-activity object inputs rng)
"agent" (complete-agent object rng)
"group" (complete-group object rng)
"statement-ref" (complete-statement-ref object rng)
(throw (ex-info "Unknown SubStatement object type"
{:kind ::unknown-object-type
:sub? true
:object object
:types types}))))))
(s/fdef complete-sub-statement
:args (s/cat :sub-statement map?
:inputs (s/keys :req-un [::type-iri-map
::activity-map
::alignments
::template
::registration])
:rng ::random/rng)
:ret ::xs/sub-statement)
;; Unlike top-level statements, sub-statements cannot have IDs or authorities
(defn complete-sub-statement
[sub-statement inputs rng]
(let [{:strs [context attachments]} sub-statement
actor (-> inputs :actor w/stringify-keys)]
(cond-> (-> sub-statement
(assoc "objectType" "SubStatement")
(update "actor" merge actor) ; TODO: Check that actor conforms to template
(update "verb" complete-verb inputs rng)
(update "object" complete-sub-object inputs rng))
;; Optional statement properties
context (update "context" complete-context inputs rng :sub-statement? true)
attachments (update "attachments" complete-attachments rng))))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Statement
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defn- complete-object
[object inputs rng]
(case (get object "objectType")
"Activity" (complete-activity object inputs rng)
"Agent" (complete-agent object rng)
"Group" (complete-group object rng)
"StatementRef" (complete-statement-ref object rng)
"SubStatement" (complete-sub-statement object inputs rng)
(let [props (keys object)
types (reduce (fn [types* prop]
(-> (get xp/spec-hint-properties-m prop)
(cset/intersection types*)))
(get xp/default-object-type-m ["object"])
props)]
(condp #(contains? %2 %1) types
"activity" (complete-activity object inputs rng)
"agent" (complete-agent object rng)
"group" (complete-group object rng)
"statement-ref" (complete-statement-ref object rng)
"sub-statement" (complete-sub-statement object inputs rng)
(throw (ex-info "Unknown Statement object type"
{:kind ::unknown-object-type
:sub? false
:object object
:types types}))))))
(s/fdef complete-statement
:args (s/cat :statement map?
:inputs (s/keys :req-un [::verb-map
::activity-map
::alignments
::registration
::template])
:rng ::random/rng)
:ret ::xs/statement)
(defn complete-statement
"Given `statement`, perform statement healing by filling in missing
values using `rng` and values from `inputs`."
[statement inputs rng]
(let [;; TODO: WARNING if Template contradicts on actor
;; TODO: WARNING if Template overwrites ID or timestamp
{:strs [context attachments authority]} statement
actor (-> inputs :actor w/stringify-keys)]
(cond-> (-> statement
(update "actor" merge actor)
(update "verb" complete-verb inputs rng)
(update "object" complete-object inputs rng))
;; Optional statement properties
;; Result is not updated since it has no required properties
context (update "context" complete-context inputs rng)
attachments (update "attachments" complete-attachments rng)
authority (update "authority" complete-actor rng))))