/
PKGBUILD
46 lines (39 loc) · 1.2 KB
/
PKGBUILD
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# https://aur.archlinux.org/packages/castor
groups=('modified')
pkgname=castor
pkgver=0.9.0
pkgrel=2
pkgdesc="A Gemini, Gopher and Finger protocol client"
arch=('x86_64')
url="https://git.sr.ht/~julienxx/castor"
license=('MIT')
depends=('gtk3' 'openssl')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::https://git.sr.ht/~julienxx/castor/archive/$pkgver.tar.gz")
sha256sums=('ed57c92a88e8ebe8db286daad9677ffb99287d164d3193d17f8134bb77de5ae1')
prepare() {
cd "$pkgname-$pkgver"
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
# Don't run update-desktop-database during install
sed -i '/update-desktop-database/d' Makefile
}
build() {
cd "$pkgname-$pkgver"
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
check() {
cd "$pkgname-$pkgver"
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features -- --test-threads=1
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
}