forked from senseidb/sensei
-
Notifications
You must be signed in to change notification settings - Fork 0
/
BQL.g4
1429 lines (1109 loc) · 33.4 KB
/
BQL.g4
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*******************************************************************************************
BNF Grammar for BQL
===================
<statement> ::= ( <select_stmt> | <describe_stmt> ) [';']
<select_stmt> ::= SELECT <select_list> [<from_clause>] [<where_clause>] [<given_clause>]
[<additional_clauses>]
<describe_stmt> ::= ( DESC | DESCRIBE ) [<index_name>]
<select_list> ::= '*' | (<column_name>|<aggregation_function>)( ',' <column_name>|<aggregation_function> )*
<column_name_list> ::= <column_name> ( ',' <column_name> )*
<aggregation_function> ::= <function_name> '(' <column_name> ')'
<function_name> ::= <column_name>
<from_clause> ::= FROM <index_name>
<index_name> ::= <identifier> | <quoted_string>
<where_clause> ::= WHERE <search_expr>
<search_expr> ::= <term_expr> ( OR <term_expr> )*
<term_expr> ::= <facet_expr> ( AND <facet_expr> )*
<facet_expr> ::= <predicate>
| '(' <search_expr> ')'
<predicates> ::= <predicate> ( AND <predicate> )*
<predicate> ::= <in_predicate>
| <contains_all_predicate>
| <equal_predicate>
| <not_equal_predicate>
| <query_predicate>
| <between_predicate>
| <range_predicate>
| <time_predicate>
| <match_predicate>
| <like_predicate>
| <null_predicate>
<in_predicate> ::= <column_name> [NOT] IN <value_list> [<except_clause>] [<predicate_props>]
<contains_all_predicate> ::= <column_name> CONTAINS ALL <value_list> [<except_clause>]
[<predicate_props>]
<equal_predicate> ::= <column_name> '=' <value> [<predicate_props>]
<not_equal_predicate> ::= <column_name> '<>' <value> [<predicate_props>]
<query_predicate> ::= QUERY IS <quoted_string>
<between_predicate> ::= <column_name> [NOT] BETWEEN <value> AND <value>
<range_predicate> ::= <column_name> <range_op> <numeric>
<time_predicate> ::= <column_name> IN LAST <time_span>
| <column_name> ( SINCE | AFTER | BEFORE ) <time_expr>
<match_predicate> ::= [NOT] MATCH '(' <column_name_list> ')' AGAINST '(' <quoted_string> ')'
<like_predicate> ::= <column_name> [NOT] LIKE <quoted_string>
<null_predicate> ::= <column_name> IS [NOT] NULL
<value_list> ::= <non_variable_value_list> | <variable>
<non_variable_value_list> ::= '(' <value> ( ',' <value> )* ')'
<python_style_list> ::= '[' <python_style_value>? ( ',' <python_style_value> )* ']'
<python_style_dict> ::= '{''}'
| '{' <key_value_pair> ( ',' <key_value_pair> )* '}'
<python_style_value> ::= <value>
| <python_style_list>
| <python_style_dict>
<value> ::= <numeric>
| <quoted_string>
| TRUE
| FALSE
| <variable>
<range_op> ::= '<' | '<=' | '>=' | '>'
<except_clause> ::= EXCEPT <value_list>
<predicate_props> ::= WITH <prop_list>
<prop_list> ::= '(' <key_value_pair> ( ',' <key_value_pair> )* ')'
<key_value_pair> ::= <quoted_string> ':'
( <value> | <python_style_list> | <python_style_dict> )
<given_clause> ::= GIVEN FACET PARAM <facet_param_list>
<facet_param_list> ::= <facet_param> ( ',' <facet_param> )*
<facet_param> ::= '(' <facet_name> <facet_param_name> <facet_param_type> <facet_param_value> ')'
<facet_param_name> ::= <quoted_string>
<facet_param_type> ::= BOOLEAN | INT | LONG | STRING | BYTEARRAY | DOUBLE
<facet_param_value> ::= <quoted_string>
<additional_clauses> ::= ( <additional_clause> )+
<additional_clause> ::= <order_by_clause>
| <limit_clause>
| <group_by_clause>
| <distinct_clause>
| <execute_clause>
| <browse_by_clause>
| <fetching_stored_clause>
| <route_by_clause>
| <relevance_model_clause>
<order_by_clause> ::= ORDER BY <sort_specs>
<sort_specs> ::= <sort_spec> ( ',' <sort_spec> )*
<sort_spec> ::= <column_name> [<ordering_spec>]
<ordering_spec> ::= ASC | DESC
<group_by_clause> ::= GROUP BY <group_spec>
<distinct_clause> ::= DISTINCT <distinct_spec>
<execute_clause> ::= EXECUTE '(' function_name ((',' python_style_dict) | (',' key_value_pair)*) ')'
<group_spec> ::= <comma_column_name_list> [TOP <max_per_group>]
<distinct_spec> ::= <or_column_name_list>
<or_column_name_list> ::= <column_name> ( OR <column_name> )*
<comma_column_name_list> ::= <column_name> ( (OR | ',') <column_name> )*
<limit_clause> ::= LIMIT [<offset> ','] <count>
<offset> ::= ( <digit> )+
<count> ::= ( <digit> )+
<browse_by_clause> ::= BROWSE BY <facet_specs>
<facet_specs> ::= <facet_spec> ( ',' <facet_spec> )*
<facet_spec> ::= <facet_name> [<facet_expression>]
<facet_expression> ::= '(' <expand_flag> <count> <count> <facet_ordering> ')'
<expand_flag> ::= TRUE | FALSE
<facet_ordering> ::= HITS | VALUE
<fetching_stored_clause> ::= FETCHING STORED [<fetching_flag>]
<fetching_flag> ::= TRUE | FALSE
<route_by_clause> ::= ROUTE BY <quoted_string>
<relevance_model_clause> ::= USING RELEVANCE MODEL <identifier> <prop_list>
[<relevance_model>]
<relevance_model> ::= DEFINED AS <formal_parameters> BEGIN <model_block> END
<formal_parameters> ::= '(' <formal_parameter_decls> ')'
<formal_parameter_decls> ::= <formal_parameter_decl> ( ',' <formal_parameter_decl> )*
<formal_parameter_decl> ::= <variable_modifiers> <type> <variable_declarator_id>
<variable_modifiers> ::= ( <variable_modifier> )*
<variable_modifier> ::= 'final'
<type> ::= <class_or_interface_type> ('[' ']')*
| <primitive_type> ('[' ']')*
| <boxed_type> ('[' ']')*
| <limited_type> ('[' ']')*
<class_or_interface_type> ::= <fast_util_data_type>
<fast_util_data_type> ::= 'IntOpenHashSet'
| 'FloatOpenHashSet'
| 'DoubleOpenHashSet'
| 'LongOpenHashSet'
| 'ObjectOpenHashSet'
| 'Int2IntOpenHashMap'
| 'Int2FloatOpenHashMap'
| 'Int2DoubleOpenHashMap'
| 'Int2LongOpenHashMap'
| 'Int2ObjectOpenHashMap'
| 'Object2IntOpenHashMap'
| 'Object2FloatOpenHashMap'
| 'Object2DoubleOpenHashMap'
| 'Object2LongOpenHashMap'
| 'Object2ObjectOpenHashMap'
<primitive_type> ::= 'boolean' | 'char' | 'byte' | 'short'
| 'int' | 'long' | 'float' | 'double'
<boxed_type> ::= 'Boolean' | 'Character' | 'Byte' | 'Short'
| 'Integer' | 'Long' | 'Float' | 'Double'
<limited_type> ::= 'String' | 'System' | 'Math'
<model_block> ::= ( <block_statement> )+
<block_statement> ::= <local_variable_declaration_stmt>
| <java_statement>
<local_variable_declaration_stmt> ::= <local_variable_declaration> ';'
<local_variable_declaration> ::= <variable_modifiers> <type> <variable_declarators>
<java_statement> ::= <block>
| 'if' <par_expression> <java_statement> [ <else_statement> ]
| 'for' '(' <for_control> ')' <java_statement>
| 'while' <par_expression> <java_statement>
| 'do' <java_statement> 'while> <par_expression> ';'
| 'switch' <par_expression> '{' <switch_block_statement_groups> '}'
| 'return' <expression> ';'
| 'break' [<identifier>] ';'
| 'continue' [<identifier>] ';'
| ';'
| <statement_expression> ';'
<block> ::= '{' ( <block_statement> )* '}'
<else_statement> ::= 'else' <java_statement>
<switch_block_statement_groups> ::= ( <switch_block_statement_group> )*
<switch_block_statement_group> ::= ( <switch_label> )+ ( <block_statement> )*
<switch_label> ::= 'case' <constant_expression> ':'
| 'case' <enum_constant_name> ':'
| 'default' ':'
<for_control> ::= <enhanced_for_control>
| [<for_init>] ';' [<expression>] ';' [<for_update>]
<for_init> ::= <local_variable_declaration>
| <expression_list>
<enhanced_for_control> ::= <variable_modifiers> <type> <identifier> ':' <expression>
<for_update> ::= <expression_list>
<par_expression> ::= '(' <expression> ')'
<expression_list> ::= <expression> ( ',' <expression> )*
<statement_expression> ::= <expression>
<constant_expression> ::= <expression>
<enum_constant_name> ::= <identifier>
<variable_declarators> ::= <variable_declarator> ( ',' <variable_declarator> )*
<variable_declarator> ::= <variable_declarator_id> '=' <variable_initializer>
<variable_declarator_id> ::= <identifier> ('[' ']')*
<variable_initializer> ::= <array_initializer>
| <expression>
<array_initializer> ::= '{' [ <variable_initializer> ( ',' <variable_initializer> )* [','] ] '}'
<expression> ::= <conditional_expression> [ <assignment_operator> <expression> ]
<assignment_operator> ::= '=' | '+=' | '-=' | '*=' | '/=' | '&=' | '|=' | '^=' |
| '%=' | '<<=' | '>>>=' | '>>='
<conditional_expression> ::= <conditional_or_expression> [ '?' <expression> ':' <expression> ]
<conditional_or_expression> ::= <conditional_and_expression> ( '||' <conditional_and_expression> )*
<conditional_and_expression> ::= <inclusive_or_expression> ('&&' <inclusive_or_expression> )*
<inclusive_or_expression> ::= <exclusive_or_expression> ('|' <exclusive_or_expression> )*
<exclusive_or_expression> ::= <and_expression> ('^' <and_expression> )*
<and_expression> ::= <equality_expression> ( '&' <equality_expression> )*
<equality_expression> ::= <instanceof_expression> ( ('==' | '!=') <instanceof_expression> )*
<instanceof_expression> ::= <relational_expression> [ 'instanceof' <type> ]
<relational_expression> ::= <shift_expression> ( <relational_op> <shift_expression> )*
<shift_expression> ::= <additive_expression> ( <shift_op> <additive_expression> )*
<relational_op> ::= '<=' | '>=' | '<' | '>'
<shift_op> ::= '<<' | '>>>' | '>>'
<additive_expression> ::= <multiplicative_expression> ( ('+' | '-') <multiplicative_expression> )*
<multiplicative_expression> ::= <unary_expression> ( ( '*' | '/' | '%' ) <unary_expression> )*
<unary_expression> ::= '+' <unary_expression>
| '-' <unary_expression>
| '++' <unary_expression>
| '--' <unary_expression>
| <unary_expression_not_plus_minus>
<unary_expression_not_plus_minus> ::= '~' <unary_expression>
| '!' <unary_expression>
| <cast_expression>
| <primary> <selector>* [ ('++'|'--') ]
<cast_expression> ::= '(' <primitive_type> ')' <unary_expression>
| '(' (<type> | <expression>) ')' <unary_expression_not_plus_minus>
<primary> ::= <par_expression>
| <literal>
| java_method identifier_suffix
| <java_ident> ('.' <java_method>)* [<identifier_suffix>]
<java_ident> ::= <boxed_type>
| <limited_type>
| <identifier>
<java_method> ::= <identifier>
<identifier_suffix> ::= ('[' ']')+ '.' 'class'
| <arguments>
| '.' 'class'
| '.' 'this'
| '.' 'super' <arguments>
<literal> ::= <integer>
| <real>
| <floating_point_literal>
| <character_literal>
| <quoted_string>
| <boolean_literal>
| 'null'
<boolean_literal> ::= 'true' | 'false'
<selector> ::= '.' <identifier> <arguments>
| '.' 'this'
| '[' <expression> ']'
<arguments> ::= '(' [<expression_list>] ')'
<quoted_string> ::= '"' ( <char> )* '"'
| "'" ( <char> )* "'"
<identifier> ::= <identifier_start> ( <identifier_part> )*
<identifier_start> ::= <alpha> | '-' | '_'
<identifier_part> ::= <identifier_start> | <digit>
<variable> ::= '$' ( <alpha> | <digit> | '_' )+
<column_name> ::= <identifier> | <quoted_string>
<facet_name> ::= <identifier>
<alpha> ::= <alpha_lower_case> | <alpha_upper_case>
<alpha_upper_case> ::= A | B | C | D | E | F | G | H | I | J | K | L | M | N | O
| P | Q | R | S | T | U | V | W | X | Y | Z
<alpha_lower_case> ::= a | b | c | d | e | f | g | h | i | j | k | l | m | n | o
| p | q | r | s | t | u | v | w | x | y | z
<digit> ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9
<numeric> ::= <time_expr>
| <integer>
| <real>
<integer> ::= ( <digit> )+
<real> ::= ( <digit> )+ '.' ( <digit> )+
<time_expr> ::= <time_span> AGO
| <date_time_string>
| NOW
<time_span> ::= [<time_week_part>] [<time_day_part>] [<time_hour_part>]
[<time_minute_part>] [<time_second_part>] [<time_millisecond_part>]
<time_week_part> ::= <integer> ( 'week' | 'weeks' )
<time_day_part> ::= <integer> ( 'day' | 'days' )
<time_hour_part> ::= <integer> ( 'hour' | 'hours' )
<time_minute_part> ::= <integer> ( 'minute' | 'minutes' | 'min' | 'mins')
<time_second_part> ::= <integer> ( 'second' | 'seconds' | 'sec' | 'secs')
<time_millisecond_part> ::= <integer> ( 'millisecond' | 'milliseconds' | 'msec' | 'msecs')
<date_time_string> ::= <date> [<time>]
<date> ::= <digit><digit><digit><digit> ('-' | '/' | '.') <digit><digit>
('-' | '/' | '.') <digit><digit>
<time> ::= DIGIT DIGIT ':' DIGIT DIGIT ':' DIGIT DIGIT
*******************************************************************************************/
grammar BQL;
// Imaginary tokens
tokens
{
COLUMN_LIST,
OR_PRED,
AND_PRED,
EQUAL_PRED,
RANGE_PRED
}
// As the generated lexer will reside in com.senseidb.bql.parsers package,
// we have to add package declaration on top of it
@lexer::header {
}
@lexer::members {
}
// As the generated parser will reside in com.senseidb.bql.parsers
// package, we have to add package declaration on top of it
@parser::header {
import java.util.Arrays;
import java.util.HashMap;
import java.util.HashSet;
import java.util.Iterator;
import java.util.LinkedList;
import java.util.Map;
import java.util.Set;
import org.json.JSONObject;
import org.json.JSONArray;
import org.json.JSONException;
import java.text.ParseException;
import java.text.SimpleDateFormat;
import com.senseidb.util.JSONUtil.FastJSONArray;
import com.senseidb.util.JSONUtil.FastJSONObject;
import com.senseidb.util.Pair;
import com.senseidb.search.req.BQLParserUtils;
}
@parser::members {
private static enum KeyType {
STRING_LITERAL,
IDENT,
STRING_LITERAL_AND_IDENT
}
}
// ***************** parser rules:
statement
: ( select_stmt
| describe_stmt
) SEMI? EOF
;
select_stmt
: SELECT ('*' | cols=selection_list)
(FROM (IDENT | STRING_LITERAL))?
w=where?
given=given_clause?
( order_by = order_by_clause
| limit = limit_clause
| group_by = group_by_clause
| distinct = distinct_clause
| executeMapReduce = execute_clause
| browse_by = browse_by_clause
| fetch_stored = fetching_stored_clause
| route_param = route_by_clause
| rel_model = relevance_model_clause
)*
;
describe_stmt
: DESCRIBE (IDENT | STRING_LITERAL)
;
selection_list
: ( col=column_name
| agrFunction=aggregation_function
)
( COMMA
( col=column_name
| agrFunction=aggregation_function
)
)*
;
aggregation_function
: (id=function_name LPAR (columnVar=column_name | '*') RPAR)
;
column_name
: (id=IDENT | str=STRING_LITERAL)
('.' (id2=IDENT | str2=STRING_LITERAL)
)*
;
function_name
: (min= 'min'|colName=column_name)
;
where
: WHERE search_expr
;
order_by_clause
: ORDER BY (RELEVANCE | sort_specs)
;
sort_specs
: sort=sort_spec
(COMMA sort=sort_spec // It's OK to use variable sort again here
)*
;
sort_spec
: column_name ordering=(ASC | DESC)?
;
limit_clause
: LIMIT (n1=INTEGER COMMA)? n2=INTEGER
;
comma_column_name_list
: col=column_name
((OR | COMMA) col=column_name
)*
;
or_column_name_list
: col=column_name
(OR col=column_name
)*
;
group_by_clause
: GROUP BY comma_column_name_list (TOP top=INTEGER)?
;
distinct_clause
: DISTINCT or_column_name_list
;
browse_by_clause
: BROWSE BY f=facet_spec
(COMMA f=facet_spec
)*
;
execute_clause
: EXECUTE LPAR funName=function_name
( COMMA map=python_style_dict
| ( COMMA p=key_value_pair[KeyType.STRING_LITERAL]
)*
)
RPAR
;
facet_spec
: column_name
(
LPAR
(TRUE | FALSE) COMMA
n1=INTEGER COMMA
n2=INTEGER COMMA
(HITS | VALUE)
RPAR
)*
;
fetching_stored_clause
: FETCHING STORED
( TRUE
| FALSE
)*
;
route_by_clause
: ROUTE BY STRING_LITERAL
;
search_expr
: t=term_expr
(OR t=term_expr)*
;
term_expr
: f=factor_expr
(AND f=factor_expr)*
;
factor_expr
: predicate
| LPAR search_expr RPAR
;
predicate
: in_predicate
| contains_all_predicate
| equal_predicate
| not_equal_predicate
| query_predicate
| between_predicate
| range_predicate
| time_predicate
| match_predicate
| like_predicate
| null_predicate
| empty_predicate
;
in_predicate
: column_name not=NOT? IN value_list except=except_clause? predicate_props?
;
empty_predicate
: value_list IS (NOT)? EMPTY
;
contains_all_predicate
: column_name CONTAINS ALL value_list except=except_clause? predicate_props?
;
equal_predicate
: column_name EQUAL value props=predicate_props?
;
not_equal_predicate
: column_name NOT_EQUAL value predicate_props?
;
query_predicate
: QUERY IS STRING_LITERAL
;
between_predicate
: column_name not=NOT? BETWEEN val1=value AND val2=value
;
range_predicate
: column_name op=(GT | GTE | LT | LTE) val=value
;
time_predicate
: column_name (NOT)? IN LAST time_span
| column_name (NOT)? (since=SINCE | since=AFTER | before=BEFORE) time_expr
;
time_span
: week=time_week_part? day=time_day_part? hour=time_hour_part?
minute=time_minute_part? second=time_second_part? msec=time_millisecond_part?
;
time_week_part
: INTEGER WEEKS
;
time_day_part
: INTEGER DAYS
;
time_hour_part
: INTEGER HOURS
;
time_minute_part
: INTEGER (MINUTES | MINS)
;
time_second_part
: INTEGER (SECONDS | SECS)
;
time_millisecond_part
: INTEGER (MILLISECONDS | MSECS)
;
time_expr
: time_span AGO
| date_time_string
| NOW
;
date_time_string
: DATE TIME?
;
match_predicate
: (NOT)? MATCH LPAR selection_list RPAR AGAINST LPAR STRING_LITERAL RPAR
;
like_predicate
: column_name (NOT)? LIKE STRING_LITERAL
;
null_predicate
: column_name IS (NOT)? NULL
;
non_variable_value_list
: LPAR v=value
( COMMA v=value
)*
RPAR
| LPAR RPAR
;
python_style_list
: '[' v=python_style_value?
( COMMA v=python_style_value
)*
']'
;
python_style_dict
: '{' '}'
| '{' p=key_value_pair[KeyType.STRING_LITERAL]
( COMMA p=key_value_pair[KeyType.STRING_LITERAL]
)*
'}'
;
python_style_value
: value
| python_style_list
| python_style_dict
;
value_list
: non_variable_value_list
| VARIABLE
;
value
: numeric
| STRING_LITERAL
| TRUE
| FALSE
| VARIABLE
;
numeric
: time_expr
| INTEGER
| REAL
;
except_clause
: EXCEPT value_list
;
predicate_props
: WITH prop_list[KeyType.STRING_LITERAL]
;
prop_list[KeyType keyType]
: LPAR p=key_value_pair[keyType]
( COMMA p=key_value_pair[keyType]
)*
RPAR
;
key_value_pair[KeyType keyType]
: ( { $keyType == KeyType.STRING_LITERAL ||
$keyType == KeyType.STRING_LITERAL_AND_IDENT}? STRING_LITERAL
| { $keyType == KeyType.IDENT ||
$keyType == KeyType.STRING_LITERAL_AND_IDENT}? IDENT
)
COLON (v=value | vs=python_style_list | vd=python_style_dict)
;
given_clause
: GIVEN FACET PARAM facet_param_list
;
// =====================================================================
// Relevance model related
// =====================================================================
variable_declarators
: var1=variable_declarator
(COMMA var2=variable_declarator
)*
;
variable_declarator
: variable_declarator_id ('=' variable_initializer)?
;
variable_declarator_id
: IDENT ('[' ']')*
;
variable_initializer
: array_initializer
| expression
;
array_initializer
: '{' (variable_initializer (',' variable_initializer)* (',')?)? '}'
;
type
: class_or_interface_type ('[' ']')*
| primitive_type ('[' ']')*
| boxed_type ('[' ']')*
| limited_type ('[' ']')*
;
class_or_interface_type
: FAST_UTIL_DATA_TYPE
;
type_arguments
: '<'
ta1=type_argument
(COMMA ta2=type_argument
)*
'>'
;
type_argument
: type
| '?' (('extends' | 'super') type)?
;
formal_parameters
: LPAR formal_parameter_decls RPAR
;
formal_parameter_decls
: decl=formal_parameter_decl
(COMMA decl=formal_parameter_decl
)*
;
formal_parameter_decl
: variable_modifiers type variable_declarator_id
;
primitive_type
: { "boolean".equals(_input.LT(1).getText()) }? BOOLEAN
| 'char'
| { "byte".equals(_input.LT(1).getText()) }? BYTE
| 'short'
| { "int".equals(_input.LT(1).getText()) }? INT
| { "long".equals(_input.LT(1).getText()) }? LONG
| 'float'
| { "double".equals(_input.LT(1).getText()) }? DOUBLE
;
boxed_type
: { "Boolean".equals(_input.LT(1).getText()) }? BOOLEAN
| 'Character'
| { "Byte".equals(_input.LT(1).getText()) }? BYTE
| 'Short'
| 'Integer'
| { "Long".equals(_input.LT(1).getText()) }? LONG
| 'Float'
| { "Double".equals(_input.LT(1).getText()) }? DOUBLE
;
limited_type
: 'String'
| 'System'
| 'Math'
;
variable_modifier
: 'final'
;
relevance_model
: DEFINED AS params=formal_parameters
BEGIN model_block END
;
model_block
: block_statement+
;
block
: '{'
block_statement*
'}'
;
block_statement
: local_variable_declaration_stmt
| java_statement
;
local_variable_declaration_stmt
: local_variable_declaration SEMI
;
local_variable_declaration
: variable_modifiers type variable_declarators
;
variable_modifiers
: variable_modifier*
;
java_statement
: block
| 'if' par_expression java_statement (else_statement)?
| FOR LPAR
for_control RPAR java_statement
| 'while' par_expression java_statement
| 'do' java_statement 'while' par_expression SEMI
| 'switch' par_expression '{' switch_block_statement_groups '}'
| 'return' expression SEMI
| 'break' IDENT? SEMI
| 'continue' IDENT? SEMI
| SEMI
| statement_expression SEMI
;
else_statement
: { "else".equals(_input.LT(1).getText()) }? ELSE java_statement
;
switch_block_statement_groups
: (switch_block_statement_group)*
;
switch_block_statement_group
: switch_label+ block_statement*
;
switch_label
: 'case' constant_expression COLON
| 'case' enum_constant_name COLON
| 'default' COLON
;
for_control
: enhanced_for_control
| for_init? SEMI expression? SEMI for_update?
;
for_init
: local_variable_declaration
| expression_list
;
enhanced_for_control
: variable_modifiers type IDENT COLON expression
;
for_update
: expression_list
;
par_expression
: LPAR expression RPAR
;
expression_list
: expression (',' expression)*
;
statement_expression
: expression
;
constant_expression
: expression
;
enum_constant_name
: IDENT
;