/
Connection.st
220 lines (180 loc) · 5.82 KB
/
Connection.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
"=====================================================================
|
| PosgreSQL DBI driver - Connection class and related classes
|
|
======================================================================"
"======================================================================
|
| Written by Mike Anderson gnu-smalltalk@gingerbread.plus.com 2006
| Based on PostgreSQL interface by Thomas Braun shin@shin.homelinux.net
|
| This file is part of the GNU Smalltalk class library.
|
| The GNU Smalltalk class library is free software; you can redistribute it
| and/or modify it under the terms of the GNU Lesser General Public License
| as published by the Free Software Foundation; either version 2.1, or (at
| your option) any later version.
|
| The GNU Smalltalk class library is distributed in the hope that it will be
| useful, but WITHOUT ANY WARRANTY; without even the implied warranty of
| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser
| General Public License for more details.
|
| You should have received a copy of the GNU Lesser General Public License
| along with the GNU Smalltalk class library; see the file COPYING.LIB.
| If not, write to the Free Software Foundation, 59 Temple Place - Suite
| 330, Boston, MA 02110-1301, USA.
|
======================================================================
"
Connection subclass: PGConnection [
| handle |
<comment: nil>
<category: 'DBD-PostgreSQL'>
PGConnection class >> driverName [
<category: 'initialization'>
^'PostgreSQL'
]
PGConnection class >> fieldConverterClass [
<category: 'initialization'>
^PGFieldConverter
]
ConnectionStatus := nil.
PGConnection class >> initialize [
ConnectionStatus := #(#CONNECTION_OK
#CONNECTION_BAD
#CONNECTION_STARTED
#CONNECTION_MADE
#CONNECTION_AWAITING_RESPONSE
#CONNECTION_AUTH_OK
#CONNECTION_SETENV
#CONNECTION_SSL_STARTUP
#CONNECTION_NEEDED).
]
PGConnection class >> connectionStatus: aCode [
<category: 'constants'>
^ConnectionStatus at: aCode + 1
]
PGConnection class >> unrecognizedParameters [
<category: 'private'>
"These are the synonymous parameters which our superclass adds and
PQconnectdb does not understand"
^#('db' 'database' 'hostname').
]
PGConnection class >> paramConnect: aParams user: aUserName password: aPassword [
"Normally you would use Connection>>connect:user:password: with a DSN
specifying the appropriate driver string.
Note that aUserName and aPassword may be nil; for Postgres, the username
defaults to the OS user if not supplied."
<category: 'instance creation'>
"Assemble a connection string in the right format"
| connStr connParams handle conn connOK |
connParams := OrderedCollection new.
aParams keysAndValuesDo: [:k :v |
(self unrecognizedParameters includes: k)
ifFalse: [connParams add: k , '=' , v]].
aUserName notNil ifTrue: [connParams add: 'user=' , aUserName].
aPassword notNil ifTrue: [connParams add: 'password=' , aPassword].
connStr := connParams inject: '' into: [ :a :b | a, ' ', b ].
handle := PQConnection connect: connStr.
connOK := self connectionStatus: handle status.
connOK == #CONNECTION_OK
ifFalse:
[handle finish.
self error: 'Connection failed (' , connOK , ')'].
^(self new)
handle: handle;
yourself
]
handle: aCObject [
<category: 'private'>
handle := aCObject.
self addToBeFinalized
]
finalize [
<category: 'private'>
self close
]
do: aSQLQuery [
<category: 'querying'>
^(self prepare: aSQLQuery) execute
]
select: aSQLQuery [
<category: 'querying'>
^(self prepare: aSQLQuery) execute
]
prepare: aSQLQuery [
<category: 'querying'>
^(PGStatement on: self)
dbHandle: handle;
queryString: aSQLQuery.
]
close [
<category: 'implementations'>
handle ifNotNil: [
self removeToBeFinalized.
handle finish.
handle := nil].
]
database [
<category: 'accessing'>
^handle database
]
primTableAt: aString ifAbsent: aBlock [
| table |
table := PGTable name: aString connection: self.
table columnsArray isEmpty ifTrue: [ ^aBlock value ].
^table
]
]
CObject subclass: PQConnection [
<category: 'DBD-PostgreSQL-Private'>
PQConnection class >> connect: aString [
<cCall: 'PQconnectdb' returning: #{PQConnection} args: #(#string)>
]
status [
<cCall: 'PQstatus' returning: #int args: #(#self)>
]
database [
<cCall: 'PQdb' returning: #string args: #(#self)>
]
errorMessage [
<cCall: 'PQerrorMessage' returning: #string args: #(#self)>
]
finish [
<cCall: 'PQfinish' returning: #void args: #(#self)>
]
exec: aSqlStatement [
<cCall: 'PQexec' returning: #{PQResultSet} args: #(#self #string)>
]
exec: aSqlStatement with: params [
| par |
"Convert the params into an array of C-Strings."
^[par := CStringType gcNew: params size.
params keysAndValuesDo: [:i :each |
par at: i - 1 put: each].
self
exec_params:aSqlStatement
n_par: params size
types: nil
values: par
lengths: nil
formats: nil
res: 0
] ensure: [
"Free the memory we allocated"
par isNil ifFalse: [
0 to: params size - 1 do: [:i |
((par + i) derefAt: 0 type: CObjectType) free ] ].
]
]
exec_params: cmd n_par: parAms types: types values: vals lengths: l formats: f res: r [
<category: 'private'>
<cCall: 'PQexecParams' returning: #{PQResultSet}
args: #(#self #string #int #cObject #cObject #cObject #cObject #int)>
]
]
Eval [
PGConnection initialize
]