-
-
Notifications
You must be signed in to change notification settings - Fork 76
/
zmodel.langium
278 lines (213 loc) · 7.83 KB
/
zmodel.langium
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
grammar ZModel
entry Model:
imports+=ModelImport*
(
declarations+=AbstractDeclaration
)*;
ModelImport:
'import' path=STRING ';'?;
AbstractDeclaration:
DataSource | GeneratorDecl| Plugin | DataModel | Enum | FunctionDecl | Attribute;
// datasource
DataSource:
TRIPLE_SLASH_COMMENT* 'datasource' name=RegularID '{' (fields+=ConfigField)* '}';
// generator
GeneratorDecl:
TRIPLE_SLASH_COMMENT* 'generator' name=RegularID '{' (fields+=ConfigField)* '}';
ConfigField:
TRIPLE_SLASH_COMMENT* name=RegularID '=' value=ConfigExpr;
// plugin
Plugin:
TRIPLE_SLASH_COMMENT* 'plugin' name=RegularID '{' (fields+=PluginField)* '}';
PluginField:
TRIPLE_SLASH_COMMENT* name=RegularID '=' value=(LiteralExpr | ArrayExpr | ObjectExpr);
// expression
Expression:
LogicalExpr;
NumberLiteral:
value=NUMBER;
StringLiteral:
value=STRING;
BooleanLiteral:
value=Boolean;
LiteralExpr:
NumberLiteral | StringLiteral | BooleanLiteral;
ArrayExpr:
'[' (items+=Expression (',' items+=Expression)*)? ']';
ConfigInvocationExpr:
name=ID ('(' ConfigInvocationArgList? ')')?;
fragment ConfigInvocationArgList:
args+=ConfigInvocationArg (',' args+=ConfigInvocationArg)*;
ConfigInvocationArg:
name=ID ':' value=LiteralExpr;
ConfigArrayExpr:
'[' (items+=(LiteralExpr|ConfigInvocationExpr) (',' items+=(LiteralExpr|ConfigInvocationExpr))*)? ']';
// expressions used in configuration fields (e.g. datasource, generator, plugin)
ConfigExpr:
LiteralExpr | InvocationExpr | ConfigArrayExpr;
type ReferenceTarget = FunctionParam | DataModelField | EnumField;
ThisExpr:
value='this';
NullExpr:
value='null';
ReferenceExpr:
target=[ReferenceTarget:RegularIDWithTypeNames] ('(' ReferenceArgList ')')?;
fragment ReferenceArgList:
args+=ReferenceArg (',' args+=ReferenceArg)*;
ReferenceArg:
name=ID ':' value=Expression;
ObjectExpr:
'{'
(fields+=FieldInitializer (',' fields+=FieldInitializer)* ','?)?
'}';
FieldInitializer:
name=(RegularID | STRING) ':' value=(Expression);
InvocationExpr:
function=[FunctionDecl] '(' ArgumentList? ')';
// binary operator precedence follow Javascript's rules:
// https://developer.mozilla.org/en-US/docs/Web/JavaScript/Reference/Operators/Operator_Precedence#table
MemberAccessExpr infers Expression:
PrimaryExpr (
{infer MemberAccessExpr.operand=current}
('.' member=[DataModelField])
)*;
UnaryExpr:
operator=('!') operand=MemberAccessExpr;
CollectionPredicateExpr infers Expression:
MemberAccessExpr (
{infer BinaryExpr.left=current}
operator=('?'|'!'|'^')
'[' right=Expression ']'
)*;
// TODO: support arithmetics?
//
// MultDivExpr infers Expression:
// CollectionPredicateExpr (
// {infer BinaryExpr.left=current}
// operator=('*'|'/')
// right=CollectionPredicateExpr
// )*;
// AddSubExpr infers Expression:
// MultDivExpr (
// {infer BinaryExpr.left=current}
// operator=('+'|'-')
// right=MultDivExpr
// )*;
InExpr infers Expression:
CollectionPredicateExpr (
{infer BinaryExpr.left=current}
operator=('in')
right=CollectionPredicateExpr
)*;
ComparisonExpr infers Expression:
InExpr (
{infer BinaryExpr.left=current}
operator=('>'|'<'|'>='|'<=')
right=InExpr
)*;
EqualityExpr infers Expression:
ComparisonExpr (
{infer BinaryExpr.left=current}
operator=('=='|'!=')
right=ComparisonExpr
)*;
LogicalExpr infers Expression:
EqualityExpr (
{infer BinaryExpr.left=current}
operator=('&&'|'||')
right=EqualityExpr
)*;
PrimaryExpr infers Expression:
'(' Expression ')' |
ThisExpr |
NullExpr |
LiteralExpr |
UnaryExpr |
InvocationExpr |
ArrayExpr|
ReferenceExpr |
ObjectExpr;
fragment ArgumentList:
args+=Argument (',' args+=Argument)*;
Argument:
value=Expression;
// model
DataModel:
(comments+=TRIPLE_SLASH_COMMENT)*
(
((isAbstract?='abstract')? 'model' name=RegularID
('extends' superTypes+=[DataModel] (',' superTypes+=[DataModel])*)?) |
((isView?='view') name=RegularID)
)
'{' (
fields+=DataModelField
| attributes+=DataModelAttribute
)*
'}';
DataModelField:
(comments+=TRIPLE_SLASH_COMMENT)*
name=RegularIDWithTypeNames type=DataModelFieldType (attributes+=DataModelFieldAttribute)*;
DataModelFieldType:
(type=BuiltinType | unsupported=UnsupportedFieldType | reference=[TypeDeclaration:RegularID]) (array?='[' ']')? (optional?='?')?;
UnsupportedFieldType:
'Unsupported' '(' (value=LiteralExpr) ')';
// enum
Enum:
(comments+=TRIPLE_SLASH_COMMENT)*
'enum' name=RegularID '{' (
fields+=EnumField
| attributes+=DataModelAttribute
)+
'}';
EnumField:
(comments+=TRIPLE_SLASH_COMMENT)*
name=RegularIDWithTypeNames (attributes+=DataModelFieldAttribute)*;
// function
FunctionDecl:
TRIPLE_SLASH_COMMENT* 'function' name=RegularID '(' (params+=FunctionParam (',' params+=FunctionParam)*)? ')' ':' returnType=FunctionParamType '{' (expression=Expression)? '}' (attributes+=InternalAttribute)*;
FunctionParam:
TRIPLE_SLASH_COMMENT* name=RegularID ':' type=FunctionParamType (optional?='?')?;
FunctionParamType:
(type=ExpressionType | reference=[TypeDeclaration:RegularID]) (array?='[' ']')?;
// https://github.com/langium/langium/discussions/1012
RegularID returns string:
// include keywords that we'd like to work as ID in most places
ID | 'model' | 'enum' | 'attribute' | 'datasource' | 'plugin' | 'abstract' | 'in' | 'view' | 'import';
RegularIDWithTypeNames returns string:
RegularID | 'String' | 'Boolean' | 'Int' | 'BigInt' | 'Float' | 'Decimal' | 'DateTime' | 'Json' | 'Bytes' | 'Null' | 'Object' | 'Any' | 'Unsupported';
// attribute
Attribute:
(comments+=TRIPLE_SLASH_COMMENT)* 'attribute' name=(INTERNAL_ATTRIBUTE_NAME|MODEL_ATTRIBUTE_NAME|FIELD_ATTRIBUTE_NAME) '(' (params+=AttributeParam (',' params+=AttributeParam)*)? ')' (attributes+=InternalAttribute)*;
AttributeParam:
(comments+=TRIPLE_SLASH_COMMENT)* (default?='_')? name=RegularID ':' type=AttributeParamType (attributes+=InternalAttribute)*;
// FieldReference refers to fields declared in the current model
// TransitiveFieldReference refers to fields declared in the model type of the current field
AttributeParamType:
(type=(ExpressionType | 'FieldReference' | 'TransitiveFieldReference' | 'ContextType') | reference=[TypeDeclaration:RegularID]) (array?='[' ']')? (optional?='?')?;
type TypeDeclaration = DataModel | Enum;
DataModelFieldAttribute:
decl=[Attribute:FIELD_ATTRIBUTE_NAME] ('(' AttributeArgList? ')')?;
DataModelAttribute:
TRIPLE_SLASH_COMMENT* decl=[Attribute:MODEL_ATTRIBUTE_NAME] ('(' AttributeArgList? ')')?;
InternalAttribute:
decl=[Attribute:INTERNAL_ATTRIBUTE_NAME] ('(' AttributeArgList? ')')?;
fragment AttributeArgList:
args+=AttributeArg (',' args+=AttributeArg)*;
AttributeArg:
(name=RegularID ':')? value=Expression;
ExpressionType returns string:
'String' | 'Int' | 'Float' | 'Boolean' | 'DateTime' | 'Null' | 'Object' | 'Any' | 'Unsupported';
BuiltinType returns string:
'String' | 'Boolean' | 'Int' | 'BigInt' | 'Float' | 'Decimal' | 'DateTime' | 'Json' | 'Bytes';
Boolean returns boolean:
'true' | 'false';
hidden terminal WS: /\s+/;
terminal INTERNAL_ATTRIBUTE_NAME: /@@@([_a-zA-Z][\w_]*\.)*[_a-zA-Z][\w_]*/;
terminal MODEL_ATTRIBUTE_NAME: /@@([_a-zA-Z][\w_]*\.)*[_a-zA-Z][\w_]*/;
terminal FIELD_ATTRIBUTE_NAME: /@([_a-zA-Z][\w_]*\.)*[_a-zA-Z][\w_]*/;
terminal ID: /[_a-zA-Z][\w_]*/;
terminal STRING: /"(\\.|[^"\\])*"|'(\\.|[^'\\])*'/;
terminal NUMBER: /[+-]?[0-9]+(\.[0-9]+)?/;
terminal TRIPLE_SLASH_COMMENT: /\/\/\/[^\n\r]*/;
hidden terminal ML_COMMENT: /\/\*[\s\S]*?\*\//;
hidden terminal SL_COMMENT: /\/\/[^\n\r]*/;