TICAS.txt

Lbl 5
DelVar L₁DelVar L₂DelVar L₃DelVar L₄DelVar L₅DelVar L₆

ClrHome
Disp "TI 84 PLUS CE SIMPLE","COMPUTER ALGEBRA SYSTEM","WRITTEN BY 144A
Disp "","SUPPORTED FEATURES:","BASIC 5 FUNCTIONS W/POLY","POLYNOMIAL FACTORING","POLYNOMIAL DERIVATIVES","INDEFINANT INTEGRALS"
Pause 
ClrHome
0→dim(⌊P3
While 1
0→dim(⌊P1
0→dim(⌊P2
""→Str2
Input ">",Str0
" "+Str0→Str0
0→G
Repeat G=0
inString(Str0,"(",G+1)→G
If G>0
Then
sub(Str0,G+1,inString(Str0,")",G)-G-1→Str1
sub(Str0,1,G)+sub(Str0,inString(Str0,")",G),length(Str0)-inString(Str0,")",G)+1)→Str0

If Str1≠"Ans"
Then
0→dim(L₁
For(I,1,27
inString(Str1,sub("ABCDEFGHIJKLMNOPQRSTUVWXYZθ",I,1))→J
If J≠0
I→L₁(1+dim(L₁
End
If dim(L₁)>1
Then
Disp "ERROR: DOES NOT SUPPORT"
Disp "MULTIVARIABLE POLYNOMIALS
Pause 
Goto 5
End
If dim(L₁)=0
Then
1→dim(L₁)
If sub(Str1,1,1)="-"
Then
expr(sub(Str1,2,length(Str1)-1)*­1→L₁(1)
Else
expr(Str1)→L₁(1)
End
Goto 26
End
sub("ABCDEFGHIJKLMNOPQRSTUVWXYZθ",L₁(1),1)→Str2
0→dim(L₁)
0→dim(L₂)
0→J

0→dim(L₁
If sub(Str1,1,1)≠"-"
"+"+Str1→Str1
Str1+"+"→Str1
For(I,1,length(Str1)
J+1→J
If sub(Str1,I,1)="+" or sub(Str1,I,1)="-"
J→L₁(1+dim(L₁
End
1→dim(L₂)
0→L₂(1)
For(I,1,dim(L₁)-1
sub(Str1,L₁(I),L₁(I+1)-L₁(I))→Str3
If inString(Str3,Str2)>0
Then
If sub(Str3,2,1)=Str2
Then
1→J
Else
expr(sub(Str3,2,inString(Str3,Str2)-2)→J
End
If sub(Str3,1,1)="-"
J*­1→J
If inString(Str3,"^")>0
Then
inString(Str3,"^")→L
expr(sub(Str3,L+1,length(Str3)-L))→K
Else
1→K
End
If K≥dim(L₂)
Then
Repeat K+1≤dim(L₂)
augment({0},L₂)→L₂
End
End
J+L₂(dim(L₂)-K)→L₂(dim(L₂)-K)
Else
expr(sub(Str3,2,length(Str3)-1))→J
If inString("+-",sub(Str3,1,1))=2
J*­1→J
J+L₂(dim(L₂))→L₂(dim(L₂)
End
End
Else
⌊P3→L₂

End
L₂→L₁
Lbl 26

If dim(⌊P1)=0
Then
L₁→⌊P1
Else
L₁→⌊P2
End
End
End

"EXPONENTS"

If inString(Str0,"^")>0 and dim(⌊P2)=1
Then
⌊P1→L₁
⌊P2(1)-1→N
L₁→L₄
If N≠0
Then
For(S,1,N
L₄→L₂
dim(L₁)→A
dim(L₂)→B
{B+1,A+1}→dim([A]
Fill(0,[A]
For(C,A,1,­1
L₁(C)→[A](1,A+1-(C-1))
End
For(C,B,1,­1
L₂(C)→[A](B+1-(C-1),1)
End
For(E,2,B+1
For(D,2,A+1
[A](1,D)*[A](E,1)→[A](E,D)
End
End
2→D
2→E
1→Z
0→Y
While Y=0
D→I
E→J
0→C
0→X
While X=0
C+[A](J,I)→C
If I=2 or J=B+1
Then
1→X
Else
I-1→I
J+1→J
End
End
C→L₁(Z)
Z+1→Z
If D=A+1 and E=B+1
Then
1→Y
End
E+1(D=A+1)(E≠B+1)→E
D+(D≠A+1)→D
End
dim(L₁)→dim(L₆
For(Q,1,dim(L₁
L₁(Q)→L₆(dim(L₁)-Q+1)
End
L₆→L₁
End
Else
{1}→L₁
End
prgmLSTTOPOL
L₁→⌊P3
0→dim(⌊P2
End

"FACTORING POLYNOMIALS"
If inString(Str0,"F")>0
Then

0→dim(L₆
0→C
DelVar L₂:DelVar L₃:DelVar L₄:DelVar L₅:DelVar L₄
1→θ

DelVar B:DelVar E:DelVar F
⌊P1→L₁
Input "SEARCH FOR IMAG? (Y/N) ",Str3
Str1→Str2
" "→Str1
Lbl 2
If dim(L₁)=3
Then
If abs(real(L₁(1)))=27 and abs(real(L₁(2)))=9 and abs(real(L₁(3)))=3
{9,3,1}→L₁
End
0→B
1→J
real(L₁(1))→J
For(I,2,dim(L₁
If I<1
3→I
L₁(I)→H
gcd(abs(int(real(J))),abs(int(real(H))))→J
End
If J>1
Then
J*θ→θ
L₁/J→L₁

End
While B=0 and dim(L₁)>2
real(L₁(1)→J
For(I,2,dim(L₁
If I<1
3→I
L₁(I)→H
gcd(abs(int(real(J))),abs(int(real(H))))→J
End
If J>1
L₁/J→L₁

1→B
0→dim(⌊FAC1
0→dim(⌊FAC2
abs(L₁(1))→P
abs(L₁(dim(L₁)))→Q
If √(P)>√(Q)
Then
√(P)→N
Else
√(Q)→N
End
For(F,1,N
int(P/F→H
If HF=P
Then
H→⌊FAC1(1+dim(⌊FAC1
If H≠F
F→⌊FAC1(1+dim(⌊FAC1
End
int(Q/F→H
If HF=Q
Then
H→⌊FAC2(1+dim(⌊FAC2
If R≠F
F→⌊FAC2(1+dim(⌊FAC2
End
End
If dim(⌊FAC2)=0
Goto 2


SortA(⌊FAC1)
SortA(⌊FAC2)

If dim(⌊FAC1)>1
Then
⌊FAC1→L₂
L₂+25(L₂=augment(List(cumSum(L₂)),{π→L₂
SortA(L₂
dim(L₂)-sum(0 xor imag(L₂→dim(L₂
L₂→⌊FAC1
End
If dim(⌊FAC2)>1
Then
⌊FAC2→L₃
L₃+25(L₃=augment(List(cumSum(L₃)),{π→L₃
SortA(L₃
dim(L₃)-sum(0 xor imag(L₃→dim(L₃
L₃→⌊FAC2
End
If Str3="Y"
augment(⌊FAC2,*⌊FAC2)→⌊FAC2


0→dim(L₂
0→dim(L₃
For(I,1,dim(⌊FAC2)
⌊FAC2(I)→A
For(F,1,dim(⌊FAC1)
A→L₂(1+dim(L₂
End
If dim(L₃)>0
augment(L₃,⌊FAC1)→L₃
If dim(L₃)=0
⌊FAC1→L₃
End


0→I
­1→E
dim(L₂)→O
1→B
real(E)→E
2→C
Repeat ((real(B)=0 and imag(B)=0) or (I≥O and C=2)) and I≠0
If C≥2
Then
I+1→I
1→C
L₂(I)/L₃(I)→E
Else
­E→E
2→C
End
dim(L₁)→dim(L₄
L₁(1)→L₄(1)
For(Q,2,dim(L₁
(L₄(Q-1)*E)+L₁(Q)→L₄(Q)
End
L₄(dim(L₄))→B
End

If real(B)=0 and imag(B)=0
Then
1→A
If real(E)>0 or imag(E)>0
­1→A
{L₃(I),L₂(I)*A}→L₅
(­L₅(2)/L₅(1))→L₆(1+dim(L₆

Str1+"("→Str1
If real(L₅(1))<0
Str1+"-"→Str1
For(I,1,dim(L₅
If (real(L₅(I))≠0 or imag(L₅(I))≠0)
Then
dim(L₅)-I→R
If I≠1
Then
If real(L₅(I))≠0
Str1+sub("+-",(real(L₅(I))≥1)+2(real(L₅(I))<0),1)→Str1
If imag(L₅(I))≠0
Then
Str1+sub("+-",(imag(L₅(I))≥1)+2(imag(L₅(I))<0),1)→Str1


End
End
If (abs(real(L₅(I)))≠1 and real(L₅(I))≠0) or (R=0 and real(L₅(I))≠0)
Str1+eval(abs(real(L₅(I))))→Str1
If (imag(abs(L₅(I)))≠1 or R=0) and imag(L₅(I))≠0
Then
If abs(L₅(I))≠1
Str1+eval(abs(imag(L₅(I))))→Str1
Str1+""→Str1
End
If R≥1
Str1+"X"→Str1
If R>1
Str1+"^"+eval(R)→Str1
End
End
Str1+")"→Str1



real(E→E
dim(L₄)-1→dim(L₄
L₄→L₁
End
real(B)→B
imag(B)+B→B
End
abs(real(L₁(1)))→J
For(I,2,dim(L₁)
L₁(I)→H
gcd(abs(int(real(J))),abs(int(real(H))))→J
End
L₁/J→L₁

If dim(L₁)>1
Then
Str1+"("→Str1
If real(L₁(1))<0
Str1+"-"→Str1
For(I,1,dim(L₁
If (real(L₁(I))≠0 or imag(L₁(I))≠0)
Then
dim(L₁)-I→R
If I≠1
Then
If real(L₁(I))≠0
Str1+sub("+-",(real(L₁(I))≥1)+2(real(L₁(I))<0),1)→Str1
If imag(L₁(I))≠0
Then
Str1+sub("+-",(imag(L₁(I))≥1)+2(imag(L₁(I))<0),1)→Str1


End
End
If (abs(real(L₁(I)))≠1 and real(L₁(I))≠0) or (R=0 and real(L₁(I))≠0)
Str1+eval(abs(real(L₁(I))))→Str1
If (abs(imag(L₁(I)))≠1 or R=0) and imag(L₁(I))≠0
Then
If abs(L₁(I))≠1
Str1+eval(abs(imag(L₁(I))))→Str1
Str1+""→Str1
End
If R≥1
Str1+"X"→Str1
If R>1
Str1+"^"+eval(R)→Str1
End
End
Str1+")"→Str1
End
If θ≠1
" "+eval(θ)+sub(Str1,2,length(Str1)-1)→Str1

If length(Str1)>26
Then
Repeat length(Str1)≤26
Disp sub(Str1,1,26)
sub(Str1,27,length(Str1)-26)→Str1
End
End
Disp Str1

Input "DISPLAY ROOTS?(Y/N) ",Str9
If Str9="Y"
Then
If dim(L₁)=3
Then
L₁(1)→A
L₁(2)→B
L₁(3)→C
(­B+√(B²-4AC))/(2A)→X
(­B-√(B²-4AC))/(2A)→Y
If dim(L₆)>0
Then
augment(L₆,{X,Y})→L₆
Else
{X,Y}→L₆
End
End
If dim(L₁)=4
Then
L₁(1)→A
L₁(2)→B
L₁(3)→C
L₁(4)→D
(­B/(3A))→P
(P+(BC-3AD)/(6A²))→Q
(C/(3A))→R
(Q+(Q²+(R-P²))^.5)^(1/3)+(Q-(Q²+(R-P²))^(1/2))^(1/3)+P→U
A*U→S
S+B→M
U*M→X
C+X→J
U*J→L
D+L→R
(­M+√(M²-4AJ))/(2A)→Z
(­M-√(M²-4AJ))/(2A)→θ
If dim(L₆)>0
Then
augment(L₆,{U,Z,θ})→L₆
Else
{U,Z,θ}→L₆
End
End
If dim(L₁)=5
Then
L₁(1)→A
L₁(2)→B
L₁(3)→C
L₁(4)→D
L₁(5)→E
(8AC-3B²)/(8A²)→F
(2B-8ABC+16A²D)/(16A)→G
(­3B^4+16AB²C-64A²BD+256AE)/(256A^4)→H
If real(F)=0 and real(G)=0 and real(H)=0
Then
(E/A)^(1/4)→Q
Q→R
R→S
S→T
Goto 00
End
2F→U
F²-4H→V
­G²→W
(­2U+9UV-27W)/54→I
((3V-U²)/9)→J
B/(4A)→O
I²+J→L
U/3→K
If real(L)<0
Then
√(√(I+√(­L))+√(I-√(­L))-K)→M
Else
√(√(I+√(L))+√(I-√(L))-K)→M
End
real(M)→M
If M=0
Then
­F→L
U²-4V→N
If real(N)<0
Then
√(L+(√(­N))/(2A)→M
If real(M)=0
Then
√(L-(√(­N))/(2A)→M
End
Else
√(L+√(N)/(2A)→M
If real(M)=0
Then
√(L-√(N)/(2A)→M
End
End
End
M²-2(F+M²-(G/M))→N
(­M/2)-O→P
If real(N)<0
Then
P+(√(­N))/2→Q
P-(√(­N))/2→R
Else
P+√(N)/2→Q
P-√(N)/2→R
End
M²-2(F+M²+(G/M))→N
(M/2)-O→P
If real(N)<0
Then
P+(√(­N))/2→S
P-(√(­N))/2→T
Else
P+√(N)/2→S
P-√(N)/2→T
End
Lbl 00
If dim(L₆)>0
Then
augment(L₆,{Q,R,S,T}→L₆
Else
{Q,R,S,T}→L₆
End
End
If dim(L₁)=2
­L₁(2)/L₁(1)→L₆(1+dim(L₆
Disp "ROOTS-"
If dim(L₆)>0
Then
For(I,1,dim(L₆)
Disp L₆(I)Frac
End
Else
Disp "NO ROOTS FOUND "
End
End
DelVar ADelVar BDelVar CDelVar EDelVar FDelVar HDelVar IDelVar JDelVar KDelVar LDelVar MDelVar NDelVar ODelVar PDelVar QDelVar RDelVar SDelVar TDelVar UDelVar VDelVar WDelVar XDelVar YDelVar ZDelVar θ
DelVar L₁DelVar L₂DelVar L₃DelVar L₄DelVar L₅DelVar L₆
End
"INDEFINANT INTEGRALS"
If inString(Str0,"I")>0
Then
⌊P1→L₁
" "→Str5
For(A,dim(L₁),1,­1
L₁(dim(L₁)-A+1)→C
gcd(abs(int(real(A))),abs(int(real(C)))→J

If A<0
­1*J→J
C/J→D
A/J→E
If C≠0
Then
If C<0
Then
Str5+"-("→Str5
Else
Str5+"+"→Str5
End
If D≠1 and D≠­1
Str5+eval(abs(D))→Str5
Str5+"X"→Str5
If A<0
Str5+"-"→Str5
If A≠1
Str5+"^"+eval(abs(A))→Str5
If E≠1
Str5+""+eval(abs(E))→Str5
If C<0
Str5+")"→Str5
End
End
Str5+"+C"→Str5
If sub(Str5,2,1)="+"
Then
sub(Str5,3,length(Str5)-2)→Str5
Else
sub(Str5,2,length(Str5)-1)→Str5
End
" ("+Str5+")"→Str2
If length(Str2)>26
Then
Repeat length(Str2)≤26
Disp sub(Str2,1,26)
sub(Str2,27,length(Str2)-26)→Str2
End
End
Disp Str2
End



"DERIVATIVES"
If inString(Str0,"D")>0
Then
⌊P1→L₁
For(I,1,1
dim(L₁)-1→dim(L₁
For(Q,dim(L₁),1,­1
dim(L₁)+1-Q→P
L₁(P)*Q→L₁(P)
End
End
prgmLSTTOPOL
L₁→⌊P3
End

"MULTIPLICATION"
If inString(Str0,"*")>0
Then
dim(⌊P1)→A
dim(⌊P2)→B
{B+1,A+1}→dim([A]
Fill(0,[A]
For(C,A,1,­1
⌊P1(C)→[A](1,A+1-(C-1))
End
For(C,B,1,­1
⌊P2(C)→[A](B+1-(C-1),1)
End
For(E,2,B+1
For(D,2,A+1
[A](1,D)*[A](E,1)→[A](E,D)
End
End
2→D
2→E
1→Z
0→Y
While Y=0
D→I
E→J
0→C
0→X
While X=0
C+[A](J,I)→C
If I=2 or J=B+1
Then
1→X
Else
I-1→I
J+1→J
End
End
C→L₁(Z)
Z+1→Z
If D=A+1 and E=B+1
Then
1→Y
End
E+1(D=A+1)(E≠B+1)→E
D+(D≠A+1)→D
End
dim(L₁)→dim(L₃
For(I,dim(L₁),1,­1
L₁(I)→L₃(dim(L₁)-I+1)
End
L₃→⌊P3
L₃→L₁
prgmLSTTOPOL
End


"DIVISION
If inString(Str0,"/")>0
Then
DelVar L₁DelVar L₂
⌊P1→L₁
⌊P2→L₂
DelVar L₃
For(A,1,dim(L₁)+1-dim(L₂
L₁(A)/L₂(1)→L₃(A)
For(B,2,dim(L₂
L₃(A)L₂(B
­Ans+L₁(A+(B-1))→L₁(A+(B-1))
End
End
For(A,dim(L₁)-(dim(L₂)-2),dim(L₁
L₁(A→L₃(1+dim(L₃))
End
dim(L₁)-dim(L₂)→N
0→dim(L₄
If dim(L₃)≠0
Then
For(A,N+2,dim(L₃)
L₃(A)→L₄(1+dim(L₄
End
End
N+1→dim(L₃)
L₃→⌊P3
L₃→L₁
Disp "QUOTIENT"
prgmLSTTOPOL
If sum(L₄)≠0
Then
Disp "REMAINDER"
L₄→L₁
prgmLSTTOPOL
End
L₃→⌊P3
End


"ADDITION/SUBTRACTION"
1→θ
If inString(Str0,"+")>0 or inString(Str0,"-")>0
Then
If dim(⌊P1)<dim(⌊P2)
Then
­1→θ
⌊P1→L₃
⌊P2→⌊P1
L₃→⌊P2
End
If dim(⌊P2)≠dim(⌊P1)
Then
Repeat dim(⌊P1)=dim(⌊P2)
augment({0},⌊P2)→⌊P2
End
End
If inString(Str0,"+")>0
θ*⌊P1+θ*⌊P2→⌊P2
If inString(Str0,"-")>0
θ*⌊P1-θ*⌊P2→⌊P2
⌊P2→L₁
prgmLSTTOPOL
⌊P2→⌊P3
End


End
End