Проверка на модальность

[Stepa86]

Диагностика: Использование модальных окон

Модальный метод	Немодальный аналог
Вопрос	ПоказатьВопрос
Предупреждение	ПоказатьПредупреждение
ОткрытьЗначение	ПоказатьЗначение
ВвестиДату	ПоказатьВводДаты
ВвестиЗначение	ПоказатьВводЗначения
ВвестиСтроку	ПоказатьВводСтроки
ВвестиЧисло	ПоказатьВводЧисла
УстановитьВнешнююКомпоненту	НачатьУстановкуВнешнейКомпоненты
УстановитьРасширениеРаботыСФайлами	НачатьУстановкуРасширенияРаботыСФайлами
УстановитьРасширениеРаботыСКриптографией	НачатьУстановкуРасширенияРаботыСКриптографией
ПоместитьФайл	НачатьПомещениеФайла
ОткрытьФормуМодально	ОткрытьФорму
СписокЗначений.ОтметитьЭлементы	СписокЗначений.ПоказатьОтметкуЭлементов
СписокЗначений.ВыбратьЭлемент	СписокЗначений.ПоказатьВыборЭлемента
УправляемаяФорма.ВыбратьИзМеню	УправляемаяФорма.ПоказатьВыборИзМеню
УправляемаяФорма.ВыбратьИзСписка	УправляемаяФорма.ПоказатьВыборИзСписка
УправляемаяФорма.ОткрытьМодально	УправляемаяФорма.Открыть
ДиалогРасписанияРегламентногоЗадания.ОткрытьМодально	ДиалогРасписанияРегламентногоЗадания.Показать
КонструкторФорматнойСтроки.ОткрытьМодально	КонструкторФорматнойСтроки.Показать
ДиалогРедактированияСтандартногоПериода.Редактировать	ДиалогРедактированияСтандартногоПериода.Показать
ДиалогВыбораШрифта.Выбрать	ДиалогВыбораШрифта.Показать
ДиалогВыбораЦвета.Выбрать	ДиалогВыбораЦвета.Показать
ОбработкаРасшифровкиКомпоновкиДанных.ВыбратьДействие	ОбработкаРасшифровкиКомпоновкиДанных.ПоказатьВыборДействия

[Stepa86]

Пример плохо:

&НаКлиенте
Процедура ДобавитьХарактеристику(Команда)
   
    // Выбор вида характеристики
    ВидХарактеристики = ОткрытьФормуМодально("ПланВидовХарактеристик.ФормаВыбора");
   
    Если ВидХарактеристики = Неопределено Тогда
        Возврат;
    КонецЕсли;
   
   
    // Обработка результата выбора
   // ...
КонецПроцедуры

Пример хорошо:

&НаКлиенте
Процедура ДобавитьХарактеристику(Команда)
    // Выбор вида характеристики
    Обработчик = Новый ОписаниеОповещения("ДобавитьХарактеристикуЗавершение", ЭтотОбъект);
    Режим = РежимОткрытияОкнаФормы.БлокироватьВеcьИнтерфейс;
    ОткрытьФорму("ПланВидовХарактеристик.ВидыХарактеристик.ФормаВыбора",,,,,, Обработчик, Режим);
КонецПроцедуры

&НаКлиенте
Процедура ДобавитьХарактеристикуЗавершение(ВидХарактеристики, Параметры) Экспорт

    Если ВидХарактеристики = Неопределено Тогда
        Возврат;
    КонецЕсли;
   
    // Обработка результата выбора
    // ...
КонецПроцедуры

[Stepa86]

Пример плохо:

&НаКлиенте
Процедура ПредставлениеРасписаниеНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
    СтандартнаяОбработка = Ложь;   
    Если РегламентныеЗаданияКлиент.ИзменитьРасписание(Расписание) Тогда
        ЭтаФорма.Модифицированность = Истина;
        ПредставлениеРасписание = Строка(Расписание);   
    КонецЕсли;
КонецПроцедуры

Пример хорошо:

&НаКлиенте
Процедура ПредставлениеРасписаниеНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
    СтандартнаяОбработка = Ложь;
    ДополнительныеПараметры = Новый Структура("Модифицированность", Истина);
    ОписаниеОповещения = Новый ОписаниеОповещения("ИзменитьРасписаниеЗавершение", ЭтотОбъект, ДополнительныеПараметры);
    РегламентныеЗаданияКлиент.ИзменитьРасписание(ОписаниеОповещения, Расписание);
КонецПроцедуры

&НаКлиенте
Процедура ИзменитьРасписаниеЗавершение(Результат, ДополнительныеПараметры) Экспорт
    Если ТипЗнч(Результат) = Тип("РасписаниеРегламентногоЗадания") Тогда
        Расписание = Результат;
        ПредставлениеРасписание = Строка(Расписание);
        ДополнительныеПараметры.Свойство("Модифицированность", Модифицированность)
   КонецЕсли;
КонецПроцедуры

[Stepa86]

Пример плохо:

Функция ИзменитьРасписание(Расписание) Экспорт
    ДиалогРасписания = Новый ДиалогРасписанияРегламентногоЗадания(Расписание);
   Если ДиалогРасписания.ОткрытьМодально() Тогда
        Расписание = ДиалогРасписания.Расписание;
        Возврат Истина;
    КонецЕсли;
    Возврат Ложь;
КонецФункции

Пример хорошо:

Процедура ИзменитьРасписание(ОписаниеОповещения, Расписание) Экспорт
    ДиалогРасписания = Новый ДиалогРасписанияРегламентногоЗадания(Расписание);
    ДиалогРасписания.Показать(ОписаниеОповещения);
КонецПроцедуры

[theshadowco]

@Stepa86
Я создал две задачи для реализации проверок, требующих информацию о типах.

Реализация для глобальных методов в PR #335

[theshadowco]

Эту ишузу закрываю, продолжим по созданны (см связи)