-
Notifications
You must be signed in to change notification settings - Fork 386
/
TextBlockTextRenderer.as
2328 lines (2160 loc) · 61.6 KB
/
TextBlockTextRenderer.as
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
Feathers
Copyright 2012-2016 Bowler Hat LLC. All Rights Reserved.
This program is free software. You can redistribute and/or modify it in
accordance with the terms of the accompanying license agreement.
*/
package feathers.controls.text
{
import feathers.core.FeathersControl;
import feathers.core.IStateContext;
import feathers.core.IStateObserver;
import feathers.core.ITextRenderer;
import feathers.core.IToggle;
import feathers.events.FeathersEventType;
import feathers.skins.IStyleProvider;
import feathers.utils.display.stageToStarling;
import feathers.utils.geom.matrixToScaleX;
import feathers.utils.geom.matrixToScaleY;
import flash.display.BitmapData;
import flash.display.DisplayObjectContainer;
import flash.display.Sprite;
import flash.display3D.Context3DProfile;
import flash.filters.BitmapFilter;
import flash.geom.Matrix;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.text.engine.ContentElement;
import flash.text.engine.ElementFormat;
import flash.text.engine.FontDescription;
import flash.text.engine.SpaceJustifier;
import flash.text.engine.TabStop;
import flash.text.engine.TextBaseline;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextJustifier;
import flash.text.engine.TextLine;
import flash.text.engine.TextLineValidity;
import flash.text.engine.TextRotation;
import starling.core.Starling;
import starling.display.Image;
import starling.events.Event;
import starling.rendering.Painter;
import starling.textures.ConcreteTexture;
import starling.textures.Texture;
import starling.utils.MathUtil;
/**
* Renders text with a native <code>flash.text.engine.TextBlock</code> from
* <a href="http://help.adobe.com/en_US/as3/dev/WS9dd7ed846a005b294b857bfa122bd808ea6-8000.html" target="_top">Flash Text Engine</a>
* (sometimes abbreviated as FTE), and draws it to <code>BitmapData</code>
* before uploading it to a texture on the GPU. Textures are managed
* internally by this component, and they will be automatically disposed
* when the component is disposed.
*
* <p>For longer passages of text, this component will stitch together
* multiple individual textures both horizontally and vertically, as a grid,
* if required. This may require quite a lot of texture memory, possibly
* exceeding the limits of some mobile devices, so use this component with
* caution when displaying a lot of text.</p>
*
* <p>The following example shows how to use
* <code>TextBlockTextRenderer</code> with a <code>Label</code>:</p>
*
* <listing version="3.0">
* var label:Label = new Label();
* label.text = "I am the very model of a modern Major General";
* label.textRendererFactory = function():ITextRenderer
* {
* return new TextBlockTextRenderer();
* };
* this.addChild( label );</listing>
*
* @see ../../../../help/text-renderers.html Introduction to Feathers text renderers
* @see ../../../../help/text-block-text-renderer.html How to use the Feathers TextBlockTextRenderer component
* @see http://help.adobe.com/en_US/as3/dev/WS9dd7ed846a005b294b857bfa122bd808ea6-8000.html Using the Flash Text Engine in ActionScript 3.0 Developer's Guide
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/TextBlock.html flash.text.engine.TextBlock
*/
public class TextBlockTextRenderer extends FeathersControl implements ITextRenderer, IStateObserver
{
/**
* @private
*/
private static const HELPER_POINT:Point = new Point();
/**
* @private
*/
private static const HELPER_RESULT:MeasureTextResult = new MeasureTextResult();
/**
* @private
*/
private static const HELPER_MATRIX:Matrix = new Matrix();
/**
* @private
*/
private static const HELPER_RECTANGLE:Rectangle = new Rectangle();
/**
* @private
*/
private static var HELPER_TEXT_LINES:Vector.<TextLine> = new <TextLine>[];
/**
* @private
* This is enforced by the runtime.
*/
protected static const MAX_TEXT_LINE_WIDTH:Number = 1000000;
/**
* @private
*/
protected static const LINE_FEED:String = "\n";
/**
* @private
*/
protected static const CARRIAGE_RETURN:String = "\r";
/**
* @private
*/
protected static const FUZZY_TRUNCATION_DIFFERENCE:Number = 0.000001;
/**
* The text will be positioned to the left edge.
*
* @see #textAlign
*/
public static const TEXT_ALIGN_LEFT:String = "left";
/**
* The text will be centered horizontally.
*
* @see #textAlign
*/
public static const TEXT_ALIGN_CENTER:String = "center";
/**
* The text will be positioned to the right edge.
*
* @see #textAlign
*/
public static const TEXT_ALIGN_RIGHT:String = "right";
/**
* The default <code>IStyleProvider</code> for all <code>TextBlockTextRenderer</code>
* components.
*
* @default null
* @see feathers.core.FeathersControl#styleProvider
*/
public static var globalStyleProvider:IStyleProvider;
/**
* Constructor.
*/
public function TextBlockTextRenderer()
{
super();
this.isQuickHitAreaEnabled = true;
}
/**
* The TextBlock instance used to render the text before taking a
* texture snapshot.
*/
protected var textBlock:TextBlock;
/**
* An image that displays a snapshot of the native <code>TextBlock</code>
* in the Starling display list when the editor doesn't have focus.
*/
protected var textSnapshot:Image;
/**
* If multiple snapshots are needed due to texture size limits, the
* snapshots appearing after the first are stored here.
*/
protected var textSnapshots:Vector.<Image>;
/**
* @private
*/
protected var _textSnapshotScrollX:Number = 0;
/**
* @private
*/
protected var _textSnapshotScrollY:Number = 0;
/**
* @private
*/
protected var _textSnapshotOffsetX:Number = 0;
/**
* @private
*/
protected var _textSnapshotOffsetY:Number = 0;
/**
* @private
*/
protected var _lastGlobalScaleX:Number = 0;
/**
* @private
*/
protected var _lastGlobalScaleY:Number = 0;
/**
* @private
*/
protected var _lastGlobalContentScaleFactor:Number = 0;
/**
* @private
*/
protected var _textLineContainer:Sprite;
/**
* @private
*/
protected var _textLines:Vector.<TextLine> = new <TextLine>[];
/**
* @private
*/
protected var _measurementTextLineContainer:Sprite;
/**
* @private
*/
protected var _measurementTextLines:Vector.<TextLine> = new <TextLine>[];
/**
* @private
*/
protected var _previousContentWidth:Number = NaN;
/**
* @private
*/
protected var _previousContentHeight:Number = NaN;
/**
* @private
*/
protected var _snapshotWidth:int = 0;
/**
* @private
*/
protected var _snapshotHeight:int = 0;
/**
* @private
*/
protected var _snapshotVisibleWidth:int = 0;
/**
* @private
*/
protected var _snapshotVisibleHeight:int = 0;
/**
* @private
*/
protected var _needsNewTexture:Boolean = false;
/**
* @private
*/
protected var _truncationOffset:int = 0;
/**
* @private
*/
protected var _textElement:TextElement;
/**
* @private
*/
override protected function get defaultStyleProvider():IStyleProvider
{
return TextBlockTextRenderer.globalStyleProvider;
}
/**
* @private
*/
override public function set maxWidth(value:Number):void
{
//this is a special case because truncation may bypass normal rules
//for determining if changing maxWidth should invalidate
var needsInvalidate:Boolean = value > this._explicitMaxWidth && this._lastMeasurementWasTruncated;
super.maxWidth = value;
if(needsInvalidate)
{
this.invalidate(INVALIDATION_FLAG_SIZE);
}
}
/**
* @private
*/
protected var _text:String;
/**
* @inheritDoc
*
* <p>In the following example, the text is changed:</p>
*
* <listing version="3.0">
* textRenderer.text = "Lorem ipsum";</listing>
*
* @default null
*/
public function get text():String
{
return this._textElement ? this._text : null;
}
/**
* @private
*/
public function set text(value:String):void
{
if(this._text == value)
{
return;
}
this._text = value;
if(!this._textElement)
{
this._textElement = new TextElement(value);
}
this._textElement.text = value;
this.content = this._textElement;
this.invalidate(INVALIDATION_FLAG_DATA);
}
/**
* @private
*/
protected var _content:ContentElement;
/**
* Sets the contents of the <code>TextBlock</code> to a complex value
* that is more than simple text. If the <code>text</code> property is
* set after the <code>content</code> property, the <code>content</code>
* property will be replaced with a <code>TextElement</code>.
*
* <p>In the following example, the content is changed to a
* <code>GroupElement</code>:</p>
*
* <listing version="3.0">
* textRenderer.content = new GroupElement( element );</listing>
*
* <p>To simply display a string value, use the <code>text</code> property
* instead:</p>
*
* <listing version="3.0">
* textRenderer.text = "Lorem Ipsum";</listing>
*
* @default null
*
* @see #text
*/
public function get content():ContentElement
{
return this._content;
}
/**
* @private
*/
public function set content(value:ContentElement):void
{
if(this._content == value)
{
return;
}
if(value is TextElement)
{
this._textElement = TextElement(value);
}
else
{
this._textElement = null;
}
this._content = value;
this.invalidate(INVALIDATION_FLAG_DATA);
}
/**
* @private
*/
protected var _elementFormatForState:Object;
/**
* @private
*/
protected var _elementFormat:ElementFormat;
/**
* The font and styles used to draw the text. This property will be
* ignored if the content is not a <code>TextElement</code> instance.
*
* <p>In the following example, the element format is changed:</p>
*
* <listing version="3.0">
* textRenderer.elementFormat = new ElementFormat( new FontDescription( "Source Sans Pro" ) );</listing>
*
* @default null
*
* @see #setElementFormatForState()
* @see #disabledElementFormat
* @see #selectedElementFormat
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/ElementFormat.html flash.text.engine.ElementFormat
*/
public function get elementFormat():ElementFormat
{
return this._elementFormat;
}
/**
* @private
*/
public function set elementFormat(value:ElementFormat):void
{
if(this._elementFormat == value)
{
return;
}
this._elementFormat = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _disabledElementFormat:ElementFormat;
/**
* The font and styles used to draw the text when the component is
* disabled. This property will be ignored if the content is not a
* <code>TextElement</code> instance.
*
* <p>In the following example, the disabled element format is changed:</p>
*
* <listing version="3.0">
* textRenderer.isEnabled = false;
* textRenderer.disabledElementFormat = new ElementFormat( new FontDescription( "Source Sans Pro" ) );</listing>
*
* @default null
*
* @see #elementFormat
* @see #selectedElementFormat
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/ElementFormat.html flash.text.engine.ElementFormat
*/
public function get disabledElementFormat():ElementFormat
{
return this._disabledElementFormat;
}
/**
* @private
*/
public function set disabledElementFormat(value:ElementFormat):void
{
if(this._disabledElementFormat == value)
{
return;
}
this._disabledElementFormat = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _selectedElementFormat:ElementFormat;
/**
* The font and styles used to draw the text when the
* <code>stateContext</code> implements the <code>IToggle</code>
* interface, and it is selected. This property will be ignored if the
* content is not a <code>TextElement</code> instance.
*
* <p>In the following example, the selected element format is changed:</p>
*
* <listing version="3.0">
* textRenderer.selectedElementFormat = new ElementFormat( new FontDescription( "Source Sans Pro" ) );</listing>
*
* @default null
*
* @see #stateContext
* @see feathers.core.IToggle
* @see #elementFormat
* @see #disabledElementFormat
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/ElementFormat.html flash.text.engine.ElementFormat
*/
public function get selectedElementFormat():ElementFormat
{
return this._selectedElementFormat;
}
/**
* @private
*/
public function set selectedElementFormat(value:ElementFormat):void
{
if(this._selectedElementFormat == value)
{
return;
}
this._selectedElementFormat = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _leading:Number = 0;
/**
* The amount of vertical space, in pixels, between lines.
*
* <p>In the following example, the leading is changed to 20 pixels:</p>
*
* <listing version="3.0">
* textRenderer.leading = 20;</listing>
*
* @default 0
*/
public function get leading():Number
{
return this._leading;
}
/**
* @private
*/
public function set leading(value:Number):void
{
if(this._leading == value)
{
return;
}
this._leading = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _textAlign:String = TEXT_ALIGN_LEFT;
/**
* The alignment of the text. For justified text, see the
* <code>textJustifier</code> property.
*
* <p>In the following example, the leading is changed to 20 pixels:</p>
*
* <listing version="3.0">
* textRenderer.textAlign = TextBlockTextRenderer.TEXT_ALIGN_CENTER;</listing>
*
* @default TextBlockTextRenderer.TEXT_ALIGN_LEFT
*
* @see #TEXT_ALIGN_LEFT
* @see #TEXT_ALIGN_CENTER
* @see #TEXT_ALIGN_RIGHT
* @see #textJustifier
*/
public function get textAlign():String
{
return this._textAlign;
}
/**
* @private
*/
public function set textAlign(value:String):void
{
if(this._textAlign == value)
{
return;
}
this._textAlign = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _wordWrap:Boolean = false;
/**
* @inheritDoc
*
* <p>In the following example, word wrap is enabled:</p>
*
* <listing version="3.0">
* textRenderer.wordWrap = true;</listing>
*
* @default false
*/
public function get wordWrap():Boolean
{
return this._wordWrap;
}
/**
* @private
*/
public function set wordWrap(value:Boolean):void
{
if(this._wordWrap == value)
{
return;
}
this._wordWrap = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @inheritDoc
*/
public function get baseline():Number
{
if(this._textLines.length == 0)
{
return 0;
}
return this.calculateLineAscent(this._textLines[0]);
}
/**
* @private
*/
protected var _applyNonLinearFontScaling:Boolean = true;
/**
* Specifies that you want to enhance screen appearance at the expense
* of what-you-see-is-what-you-get (WYSIWYG) print fidelity.
*
* <p>In the following example, this property is changed to false:</p>
*
* <listing version="3.0">
* textRenderer.applyNonLinearFontScaling = false;</listing>
*
* @default true
*
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/TextBlock.html#applyNonLinearFontScaling Full description of flash.text.engine.TextBlock.applyNonLinearFontScaling in Adobe's Flash Platform API Reference
*/
public function get applyNonLinearFontScaling():Boolean
{
return this._applyNonLinearFontScaling;
}
/**
* @private
*/
public function set applyNonLinearFontScaling(value:Boolean):void
{
if(this._applyNonLinearFontScaling == value)
{
return;
}
this._applyNonLinearFontScaling = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _baselineFontDescription:FontDescription;
/**
* The font used to determine the baselines for all the lines created from the block, independent of their content.
*
* <p>In the following example, the baseline font description is changed:</p>
*
* <listing version="3.0">
* textRenderer.baselineFontDescription = new FontDescription( "Source Sans Pro", FontWeight.BOLD );</listing>
*
* @default null
*
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/TextBlock.html#baselineFontDescription Full description of flash.text.engine.TextBlock.baselineFontDescription in Adobe's Flash Platform API Reference
* @see #baselineFontSize
*/
public function get baselineFontDescription():FontDescription
{
return this._baselineFontDescription;
}
/**
* @private
*/
public function set baselineFontDescription(value:FontDescription):void
{
if(this._baselineFontDescription == value)
{
return;
}
this._baselineFontDescription = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _baselineFontSize:Number = 12;
/**
* The font size used to calculate the baselines for the lines created
* from the block.
*
* <p>In the following example, the baseline font size is changed:</p>
*
* <listing version="3.0">
* textRenderer.baselineFontSize = 20;</listing>
*
* @default 12
*
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/TextBlock.html#baselineFontSize Full description of flash.text.engine.TextBlock.baselineFontSize in Adobe's Flash Platform API Reference
* @see #baselineFontDescription
*/
public function get baselineFontSize():Number
{
return this._baselineFontSize;
}
/**
* @private
*/
public function set baselineFontSize(value:Number):void
{
if(this._baselineFontSize == value)
{
return;
}
this._baselineFontSize = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _baselineZero:String = TextBaseline.ROMAN;
/**
* Specifies which baseline is at y=0 for lines created from this block.
*
* <p>In the following example, the baseline zero is changed:</p>
*
* <listing version="3.0">
* textRenderer.baselineZero = TextBaseline.ASCENT;</listing>
*
* @default TextBaseline.ROMAN
*
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/TextBlock.html#baselineZero Full description of flash.text.engine.TextBlock.baselineZero in Adobe's Flash Platform API Reference
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/TextBaseline.html flash.text.engine.TextBaseline
*/
public function get baselineZero():String
{
return this._baselineZero;
}
/**
* @private
*/
public function set baselineZero(value:String):void
{
if(this._baselineZero == value)
{
return;
}
this._baselineZero = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _bidiLevel:int = 0;
/**
* Specifies the bidirectional paragraph embedding level of the text
* block.
*
* <p>In the following example, the bidi level is changed:</p>
*
* <listing version="3.0">
* textRenderer.bidiLevel = 1;</listing>
*
* @default 0
*
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/TextBlock.html#bidiLevel Full description of flash.text.engine.TextBlock.bidiLevel in Adobe's Flash Platform API Reference
*/
public function get bidiLevel():int
{
return this._bidiLevel;
}
/**
* @private
*/
public function set bidiLevel(value:int):void
{
if(this._bidiLevel == value)
{
return;
}
this._bidiLevel = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _lineRotation:String = TextRotation.ROTATE_0;
/**
* Rotates the text lines in the text block as a unit.
*
* <p>In the following example, the line rotation is changed:</p>
*
* <listing version="3.0">
* textRenderer.lineRotation = TextRotation.ROTATE_90;</listing>
*
* @default TextRotation.ROTATE_0
*
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/TextBlock.html#lineRotation Full description of flash.text.engine.TextBlock.lineRotation in Adobe's Flash Platform API Reference
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/TextRotation.html flash.text.engine.TextRotation
*/
public function get lineRotation():String
{
return this._lineRotation;
}
/**
* @private
*/
public function set lineRotation(value:String):void
{
if(this._lineRotation == value)
{
return;
}
this._lineRotation = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _tabStops:Vector.<TabStop>;
/**
* Specifies the tab stops for the text in the text block, in the form
* of a <code>Vector</code> of <code>TabStop</code> objects.
*
* <p>In the following example, the tab stops changed:</p>
*
* <listing version="3.0">
* textRenderer.tabStops = new <TabStop>[ new TabStop( TabAlignment.CENTER ) ];</listing>
*
* @default null
*
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/TextBlock.html#tabStops Full description of flash.text.engine.TextBlock.tabStops in Adobe's Flash Platform API Reference
*/
public function get tabStops():Vector.<TabStop>
{
return this._tabStops;
}
/**
* @private
*/
public function set tabStops(value:Vector.<TabStop>):void
{
if(this._tabStops == value)
{
return;
}
this._tabStops = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _textJustifier:TextJustifier = new SpaceJustifier();
/**
* Specifies the <code>TextJustifier</code> to use during line creation.
*
* <p>In the following example, the text justifier is changed:</p>
*
* <listing version="3.0">
* textRenderer.textJustifier = new SpaceJustifier( "en", LineJustification.ALL_BUT_LAST );</listing>
*
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/TextBlock.html#textJustifier Full description of flash.text.engine.TextBlock.textJustifier in Adobe's Flash Platform API Reference
*/
public function get textJustifier():TextJustifier
{
return this._textJustifier;
}
/**
* @private
*/
public function set textJustifier(value:TextJustifier):void
{
if(this._textJustifier == value)
{
return;
}
this._textJustifier = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _userData:*;
/**
* Provides a way for the application to associate arbitrary data with
* the text block.
*
* <p>In the following example, the user data is changed:</p>
*
* <listing version="3.0">
* textRenderer.userData = { author: "William Shakespeare", title: "Much Ado About Nothing" };</listing>
*
* @see http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/engine/TextBlock.html#userData Full description of flash.text.engine.TextBlock.userData in Adobe's Flash Platform API Reference
*/
public function get userData():*
{
return this._userData;
}
/**
* @private
*/
public function set userData(value:*):void
{
if(this._userData === value)
{
return;
}
this._userData = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private
*/
protected var _pixelSnapping:Boolean = true;
/**
* Determines if the text should be snapped to the nearest whole pixel
* when rendered. When this is <code>false</code>, text may be displayed
* on sub-pixels, which often results in blurred rendering due to
* texture smoothing.
*
* <p>In the following example, the text is not snapped to pixels:</p>
*
* <listing version="3.0">
* textRenderer.pixelSnapping = false;</listing>
*
* @default true
*/
public function get pixelSnapping():Boolean
{
return this._pixelSnapping;
}
/**
* @private
*/
public function set pixelSnapping(value:Boolean):void
{
if(this._pixelSnapping === value)
{
return;
}
this._pixelSnapping = value;
this.invalidate(INVALIDATION_FLAG_STYLES);
}
/**
* @private