最初のコミット

.gitignore

@@ -0,0 +1,2 @@
+*.zip
+.vscode

Update_log.txt

@@ -0,0 +1,15 @@
+
+<=2021/07/25 Ver 1.0.2=>
+・1.17.x対応
+・置き方によってはどんなブロックでも破壊できていたのを修正
+・インストール時のメッセージ表示に使用していたスコアボードを削除
+
+<=2020/11/28 Ver 1.0.1=>
+・ホロブロックの中にアイテムを押し込めないように
+・ホロブロック同士を重ねて置くと壊れるように変更
+・マルチプレイ時、橋から橋を生やせる問題を修正
+・チャージ時間を15tickに短縮
+・暗いところでもっとキラキラ光るように！
+
+<=2020/11/27 Ver 1.0.0=>
+・公開

data/h.block/advancements/crafting/re_holo_block.json

@@ -0,0 +1,13 @@
+{
+  "criteria": {
+    "unlock": {
+      "trigger": "minecraft:recipe_unlocked",
+      "conditions": {
+        "recipe": "h.block:re_holo_block"
+      }
+    }
+  },
+  "rewards": {
+    "function": "h.block:craft/holo_block"
+  }
+}

data/h.block/advancements/entered_world.json

@@ -0,0 +1,10 @@
+{
+  "criteria": {
+    "enter": {
+      "trigger": "minecraft:location"
+    }
+  },
+  "rewards": {
+    "function": "h.block:install_check"
+  }
+}

data/h.block/functions/craft/holo_block.mcfunction

@@ -0,0 +1,11 @@
+#まぁまずはアイテムが必要であろう
+give @s item_frame{display:{Name:'{"text":"Re: Holo Block","color":"aqua","italic":false}',Lore:['{"text":" "}','{"text":"[Hold Sneak: Active Bridge Mode]","color":"white","italic":false}','{"text":" "}','{"text":"時間経過で自壊するブロックを設置する。","color":"white","italic":false}','{"text":"壊れると即座に手元に戻ってくる。","color":"white","italic":false}']},CustomModelData:1,ItemName:Re_Holo_Block,Enchantments:[{}],EntityTag:{Invulnerable:1b,Silent:1b,Fixed:1b,Invisible:1b,Tags:["H.Bl_Core_Common","H.Bl_Core","H.Bl_Place"]}} 8
+
+#次回以降も実行するためにレシピ没収
+recipe take @s h.block:re_holo_block
+
+#なんだこのチェストは！消えてもらおう
+clear @s chest 1
+
+#進捗消去
+advancement revoke @s only h.block:crafting/re_holo_block

data/h.block/functions/entity/holo_block/block.mcfunction

@@ -0,0 +1,7 @@
+execute unless entity @e[type=item_frame,tag=H.Bl_Core_Common,limit=1,distance=..0.5,sort=nearest] run kill @e[type=item,nbt={Age:0s,Item:{id:"minecraft:item_frame",Count:1b}},limit=1,distance=..0.5,sort=nearest]
+execute unless entity @e[type=item_frame,tag=H.Bl_Core_Common,limit=1,distance=..0.5,sort=nearest] run kill @s
+
+#消灯
+execute if entity @e[type=item_frame,tag=H.Bl_Break_Soon,limit=1,distance=..0.5,sort=nearest] run item replace entity @s armor.head with item_frame{CustomModelData: 1}
+execute if entity @e[type=item_frame,tag=H.Bl_Break_Soon,limit=1,distance=..0.5,sort=nearest] run data modify entity @s Fire set value -1s
+

data/h.block/functions/entity/holo_block/core.mcfunction

@@ -0,0 +1,21 @@
+
+# ここには設置できない
+    execute unless block ~ ~ ~ #h.block:can_replace if entity @s[tag=H.Bl_Place] run function h.block:entity/holo_block/invalid
+
+# まず設置と効果音
+    execute if block ~ ~ ~ #h.block:can_replace if entity @s[tag=H.Bl_Place] run function h.block:entity/holo_block/place
+
+# ピストンで押すと大爆発 (ボツ処理、でも一応残しておく)
+    #execute if block ~ ~ ~ moving_piston run summon tnt
+
+# そこがガラスじゃないなら即座に死ぬ
+    execute unless entity @s[tag=H.Bl_Dupe] unless block ~ ~ ~ glass unless block ~ ~ ~ piston_head run function h.block:entity/holo_block/destroy
+
+# 見た目 壊れそうになると色が変わる
+    execute if entity @s[scores={H.Bl_Duration=..40}] align xyz positioned ~0.5 ~0.5 ~0.5 run particle minecraft:dust 1 1 1 0.75 ~ ~ ~ 0.15 0.15 0.15 0 1
+    execute if entity @s[scores={H.Bl_Duration=40..}] align xyz positioned ~0.5 ~0.5 ~0.5 run particle minecraft:dust 1 0.5 0.5 0.75 ~ ~ ~ 0.15 0.15 0.15 0 1
+    tag @s[scores={H.Bl_Duration=40}] add H.Bl_Break_Soon
+
+# 時間経過でブロック破壊
+    scoreboard players add @s H.Bl_Duration 1
+    execute if entity @s[scores={H.Bl_Duration=60..}] run function h.block:entity/holo_block/destroy

data/h.block/functions/entity/holo_block/core_2.mcfunction

@@ -0,0 +1,15 @@
+# まず設置と効果音
+    execute unless block ~ ~ ~ end_portal_frame if entity @s[tag=H.Bl_Place] run function h.block:entity/holo_block/place
+
+# そこがガラスじゃないなら即座に死ぬ
+    execute unless block ~ ~ ~ glass unless block ~ ~ ~ piston_head run function h.block:entity/holo_block/destroy
+
+# 見た目 壊れそうになると色が変わる
+    execute if entity @s[scores={H.Bl_Duration=..120}] align xyz positioned ~0.5 ~0.5 ~0.5 run particle minecraft:dust 1 1 1 0.75 ~ ~ ~ 0.15 0.15 0.15 0 1
+    execute if entity @s[scores={H.Bl_Duration=120..}] align xyz positioned ~0.5 ~0.5 ~0.5 run particle minecraft:dust 1 0.5 0.5 0.75 ~ ~ ~ 0.15 0.15 0.15 0 1
+    tag @s[scores={H.Bl_Duration=120}] add H.Bl_Break_Soon
+
+# プレイヤー接近で崩れだす
+    scoreboard players add @s H.Bl_Duration 1
+    execute if entity @s[scores={H.Bl_Duration=..79}] if entity @a[distance=..3] run scoreboard players set @s H.Bl_Duration 80
+    execute if entity @s[scores={H.Bl_Duration=140..}] run function h.block:entity/holo_block/destroy

data/h.block/functions/entity/holo_block/destroy.mcfunction

@@ -0,0 +1,11 @@
+# 同スコアの人にアイテム渡す
+    execute at @a[gamemode=!creative] if score @s H.Bl_ScoreID = @p H.Bl_P.ID run give @p item_frame{display:{Name:'{"text":"Re: Holo Block","color":"aqua","italic":false}',Lore:['{"text":" "}','{"text":"[Hold Sneak: Active Bridge Mode]","color":"white","italic":false}','{"text":" "}','{"text":"時間経過で自壊するブロックを設置する。","color":"white","italic":false}','{"text":"壊れると即座に手元に戻ってくる。","color":"white","italic":false}']},CustomModelData:1,ItemName:Re_Holo_Block,Enchantments:[{}],EntityTag:{Invulnerable:1b,Silent:1b,Fixed:1b,Invisible:1b,Tags:["H.Bl_Core_Common","H.Bl_Core","H.Bl_Place"]}} 1
+
+# シルクタッチ対策
+    kill @e[type=item,nbt={Age:0s,Item:{id:"minecraft:glass",Count:1b}},limit=1,distance=..0.5,sort=nearest]
+
+# えんしゅつ
+    execute align xyz positioned ~0.5 ~0.5 ~0.5 run particle minecraft:end_rod ~ ~ ~ 0 0 0 0.1 5
+    playsound minecraft:entity.chicken.egg block @a ~ ~ ~ 1 1.5
+    execute if block ~ ~ ~ glass run setblock ~ ~ ~ air destroy
+    kill @s

data/h.block/functions/entity/holo_block/invalid.mcfunction

@@ -0,0 +1,8 @@
+
+# 同スコアの人にアイテム渡す
+    execute at @a[gamemode=!creative] if score @s H.Bl_ScoreID = @p H.Bl_P.ID run give @p item_frame{display:{Name:'{"text":"Re: Holo Block","color":"aqua","italic":false}',Lore:['{"text":" "}','{"text":"[Hold Sneak: Active Bridge Mode]","color":"white","italic":false}','{"text":" "}','{"text":"時間経過で自壊するブロックを設置する。","color":"white","italic":false}','{"text":"壊れると即座に手元に戻ってくる。","color":"white","italic":false}']},CustomModelData:1,ItemName:Re_Holo_Block,Enchantments:[{}],EntityTag:{Invulnerable:1b,Silent:1b,Fixed:1b,Invisible:1b,Tags:["H.Bl_Core_Common","H.Bl_Core","H.Bl_Place"]}} 1
+
+# エラーっぽい音と共に消える
+    playsound minecraft:entity.chicken.egg block @a ~ ~ ~ 1 1
+    playsound minecraft:block.note_block.bass block @a ~ ~ ~ 1 1
+    kill @s

data/h.block/functions/entity/holo_block/place.mcfunction

@@ -0,0 +1,22 @@
+
+# スコアコピー
+    execute if entity @s[tag=!H.Bl_Placed_By_Bridge] run scoreboard players operation @s H.Bl_ScoreID = @p[scores={H.Bl_Place=1..}] H.Bl_P.ID
+    execute if entity @s[tag=H.Bl_Placed_By_Bridge] run scoreboard players operation @s H.Bl_ScoreID = @e[type=armor_stand,tag=H.Bl_Snake] H.Bl_ScoreID
+
+# スネイクモード
+    execute unless entity @s[tag=H.Bl_Placed_By_Bridge] at @a[scores={H.Bl_Charge=15..}] if score @s H.Bl_ScoreID = @p H.Bl_P.ID at @s run summon armor_stand ~ ~ ~ {Tags:["H.Bl_Snake","H.Bl_Snake_Place"],Marker:1b,Invisible:1b}
+
+
+# 設定のスコアが1なら見た目がいい感じになる
+    execute if score #H.Bl_Option H.Bl_Option1 matches 1 run execute align xyz positioned ~0.5 ~0.5 ~0.5 run summon armor_stand ~ ~ ~ {Silent:1b,Fire:10000s,Invisible:1b,Small:1b,Marker:1b,Tags:["H.Bl_Block"],ArmorItems:[{},{},{},{id:"minecraft:item_frame",Count:1b,tag:{CustomModelData:1,Enchantments:[{}]}}]}
+
+# ブロック設置
+    execute align xyz positioned ~0.5 ~0.5 ~0.5 run particle minecraft:end_rod ~ ~ ~ 0 0 0 0.05 3
+    playsound minecraft:block.glass.place block @a ~ ~ ~ 1 1.2
+    playsound minecraft:entity.experience_orb.pickup block @a ~ ~ ~ 1 1.5
+    setblock ~ ~ ~ air destroy
+    setblock ~ ~ ~ glass
+
+# タグ削除 次からは実行しない
+    tag @s remove H.Bl_Place
+    tag @s remove H.Bl_Placed_By_Bridge

data/h.block/functions/entity/holo_block/setblock.mcfunction

@@ -0,0 +1,10 @@
+
+# 設定のスコアが1なら見た目がいい感じになる
+    execute if score #H.Bl_Option H.Bl_Option1 matches 1 run execute align xyz positioned ~0.5 ~0.5 ~0.5 run summon armor_stand ~ ~ ~ {Silent:1b,Fire:10000s,Invisible:1b,Small:1b,Marker:1b,Tags:["H.Bl_Block"],ArmorItems:[{},{},{},{id:"minecraft:item_frame",Count:1b,tag:{CustomModelData:1,Enchantments:[{}]}}]}
+
+# ブロック設置
+    execute align xyz positioned ~0.5 ~0.5 ~0.5 run particle minecraft:end_rod ~ ~ ~ 0 0 0 0.05 3
+    playsound minecraft:block.glass.place block @a ~ ~ ~ 1 1.2
+    playsound minecraft:entity.experience_orb.pickup block @a ~ ~ ~ 1 1.5
+    setblock ~ ~ ~ air destroy
+    setblock ~ ~ ~ glass

data/h.block/functions/entity/holo_block/snake/destroy.mcfunction

@@ -0,0 +1,5 @@
+#パーティクルと音
+execute align xyz positioned ~0.5 ~0.5 ~0.5 run particle explosion ~ ~ ~ 0 0 0 0 1
+playsound minecraft:entity.zombie_villager.converted block @a ~ ~0.5 ~ 1 2
+#さよーならー
+kill @s

data/h.block/functions/entity/holo_block/snake/main.mcfunction

@@ -0,0 +1,22 @@
+#初回行動
+execute if entity @s[tag=H.Bl_Snake_Place] run function h.block:entity/holo_block/snake/place
+
+#向きを同期
+execute at @a if score @s H.Bl_ScoreID = @p H.Bl_P.ID run function h.block:entity/holo_block/snake/rotate
+
+#移動 移動成功時に同IDのプレイヤーのブリッジを奪う
+execute if entity @s[scores={H.Bl_Duration=10..32}] run function h.block:entity/holo_block/snake/move
+
+#同IDのプレイヤーがアイテムを持ってないなら消滅
+execute at @a[gamemode=!creative,nbt=!{Inventory:[{id:"minecraft:item_frame",tag:{ItemName:Re_Holo_Block}}]}] if score @s H.Bl_ScoreID = @p H.Bl_P.ID at @s run function h.block:entity/holo_block/snake/destroy
+
+#コイツが存在する限りチャージできない
+execute at @a if score @s H.Bl_ScoreID = @p H.Bl_P.ID at @s run scoreboard players reset @p H.Bl_Charge
+
+#置いたブリッジにIDを移す
+scoreboard players operation @e[type=item_frame,tag=H.Bl_Placed_By_Bridge,limit=1,sort=nearest] H.Bl_ScoreID = @s H.Bl_ScoreID
+tag @e[type=item_frame,tag=H.Bl_Core_Placed_By_Bridge,limit=1,sort=nearest] remove H.Bl_Placed_By_Bridge
+
+#時間経過で消滅
+scoreboard players add @s H.Bl_Duration 1
+execute if entity @s[scores={H.Bl_Duration=32..}] run function h.block:entity/holo_block/snake/destroy

data/h.block/functions/entity/holo_block/snake/move.mcfunction

@@ -0,0 +1,3 @@
+execute if block ~ ~ ~ #h.block:can_replace at @a[gamemode=!creative] if score @s H.Bl_ScoreID = @p H.Bl_P.ID run clear @p item_frame{ItemName:Re_Holo_Block} 1
+execute if block ~ ~ ~ #h.block:can_replace run summon item_frame ~ ~ ~ {Invulnerable:1b,Silent:1b,Fixed:1b,Invisible:1b,Tags:["H.Bl_Core_Common","H.Bl_Core_2","H.Bl_Place","H.Bl_Placed_By_Bridge"]}
+tp @s ^ ^ ^1

data/h.block/functions/entity/holo_block/snake/place.mcfunction

@@ -0,0 +1,10 @@
+#IDコピー
+scoreboard players operation @s H.Bl_ScoreID = @e[type=item_frame,tag=H.Bl_Core,limit=1,sort=nearest] H.Bl_ScoreID
+tag @s remove H.Bl_Snake_Place
+
+#パーティクルと音
+execute align xyz positioned ~0.5 ~0.5 ~0.5 run particle explosion ~ ~ ~ 0 0 0 0 1
+playsound minecraft:entity.zombie_villager.converted block @a ~ ~0.5 ~ 1 2
+
+#コイツが出現すると最初の橋が崩れる
+#execute at @e[type=item_frame,tag=H.Bl_Core_2] if score @s H.Bl_ScoreID = @e[type=item_frame,tag=H.Bl_Core_2,limit=1,sort=nearest] H.Bl_ScoreID as @e[type=item_frame,tag=H.Bl_Core_2,limit=1,sort=nearest] run function h.block:entity/holo_block/destroy

data/h.block/functions/entity/holo_block/snake/rotate.mcfunction

@@ -0,0 +1,3 @@
+execute store result entity @s Rotation[0] float 1 run data get entity @p Rotation[0]
+execute store result entity @s Rotation[1] float 1 run data get entity @p Rotation[1]
+execute store result entity @s Rotation[2] float 1 run data get entity @p Rotation[2]

data/h.block/functions/install.mcfunction

@@ -0,0 +1 @@
+tellraw @a ["\n----------\n\n",{"text":"[Re: Holo Block] の導入に成功しました。\n[Re: Holo Block] has been installed.\n\nCreated by "},{"text":"Chuzume","color":"gold"},"\n\n----------\n"]

data/h.block/functions/install_check.mcfunction

@@ -0,0 +1,2 @@
+execute unless data storage chuz:storage H.Bl_Install run function h.block:install
+data modify storage chuz:storage H.Bl_Install set value 1

data/h.block/functions/item/holo_block/charged.mcfunction

@@ -0,0 +1,5 @@
+playsound minecraft:block.iron_door.open player @a ~ ~ ~ 1 1.5
+playsound minecraft:entity.experience_orb.pickup player @a ~ ~ ~ 1 1.5
+playsound minecraft:block.glass.break player @a ~ ~ ~ 1 1
+particle crit ~ ~0.5 ~ 0 0 0 0.5 25
+title @s actionbar {"text":"| Bridge Mode |","color":"white"}

data/h.block/functions/item/holo_block/main.mcfunction

@@ -0,0 +1,8 @@
+#チャージ
+scoreboard players add @s[scores={H.Bl_Sneak=1..}] H.Bl_Charge 1
+
+#チャージ消去
+scoreboard players reset @s[scores={H.Bl_Place=1..}] H.Bl_Charge
+
+#チャージできたよ！
+execute if entity @s[scores={H.Bl_Charge=15}] run function h.block:item/holo_block/charged

data/h.block/functions/load.mcfunction

@@ -0,0 +1,14 @@
+scoreboard objectives add H.Bl_Duration dummy
+scoreboard objectives add H.Bl_Charge dummy
+scoreboard objectives add H.Bl_Place minecraft.used:minecraft.item_frame
+scoreboard objectives add H.Bl_Sneak minecraft.custom:minecraft.sneak_time
+scoreboard objectives add H.Bl_Blinking dummy
+
+#Option1 ブロックの見た目
+scoreboard objectives add H.Bl_Option1 dummy
+execute unless score #H.Bl_Option H.Bl_Option1 = #H.Bl_Option H.Bl_Option1 run scoreboard players set #H.Bl_Option H.Bl_Option1 0
+
+#スコアID
+scoreboard objectives add H.Bl_P.ID dummy
+scoreboard objectives add H.Bl_ScoreID dummy
+scoreboard objectives add H.Bl_P.ID_Core dummy

data/h.block/functions/main.mcfunction

@@ -0,0 +1,23 @@
+# Holo_Block
+    execute as @e[type=item_frame,tag=H.Bl_Core] at @s run function h.block:entity/holo_block/core
+    execute as @e[type=item_frame,tag=H.Bl_Core_2] at @s run function h.block:entity/holo_block/core_2
+
+# ホロスネイク
+    execute as @e[type=armor_stand,tag=H.Bl_Snake] at @s run function h.block:entity/holo_block/snake/main
+
+# Holo_BlocK(手持ち処理)
+    execute as @a[nbt={SelectedItem:{tag:{ItemName:Re_Holo_Block}}}] at @s run function h.block:item/holo_block/main
+
+# ホロブロック（外見）
+    execute as @e[type=armor_stand,tag=H.Bl_Block] at @s run function h.block:entity/holo_block/block
+
+# スコア
+    function h.block:score_id/player_score_id
+
+# スニーク処理
+    scoreboard players reset @a[scores={H.Bl_Sneak=0}] H.Bl_Charge
+    scoreboard players set @a[scores={H.Bl_Sneak=1..}] H.Bl_Sneak 0
+    scoreboard players reset @a[nbt=!{SelectedItem:{tag:{ItemName:Re_Holo_Block}}}] H.Bl_Charge
+
+# スコアリセット
+    scoreboard players reset @a[scores={H.Bl_Place=1..}] H.Bl_Place

data/h.block/functions/option/better_block.mcfunction

@@ -0,0 +1,6 @@
+#初期設定では1
+scoreboard players add #H.Bl_Option H.Bl_Option1 1
+execute if score #H.Bl_Option H.Bl_Option1 matches 2 run scoreboard players set #H.Bl_Option H.Bl_Option1 0
+
+execute if score #H.Bl_Option H.Bl_Option1 matches 0 run tellraw @s ["\n----------\n\n",{"text":"ホロブロックの見た目: 処理優先\nHolo Block Graphic: Fast"},"\n\n----------\n"]
+execute if score #H.Bl_Option H.Bl_Option1 matches 1 run tellraw @s ["\n----------\n\n",{"text":"ホロブロックの見た目: 描画優先\nHolo Block Graphic: Fancy"},"\n\n----------\n"]

data/h.block/functions/score_id/player_score_id.mcfunction

@@ -0,0 +1,9 @@
+#プレイヤーのID
+execute if entity @a[tag=!H.Bl_HaveID,limit=1] run scoreboard players add #H.Bl_P.ID_Core H.Bl_P.ID_Core 1
+execute as @a[tag=!H.Bl_HaveID,limit=1] run scoreboard players operation @s H.Bl_P.ID = #H.Bl_P.ID_Core H.Bl_P.ID_Core
+tag @a[tag=!H.Bl_HaveID,limit=1,scores={H.Bl_P.ID=0..}] add H.Bl_HaveID
+
+#"H.Bl_NeedID"タグ持ちにプレイヤーと同じIDを付与
+#"H.Bl_ScoreID"はプレイヤー由来のエンティティ限定
+execute as @e[tag=H.Bl_NeedID] at @s run scoreboard players operation @s H.Bl_ScoreID = @p H.Bl_P.ID
+tag @e[tag=H.Bl_NeedID] remove H.Bl_NeedID

data/h.block/functions/score_id/reset_player_id.mcfunction

@@ -0,0 +1,3 @@
+scoreboard objectives remove M.Fw_P.ID
+scoreboard objectives remove M.Fw_P.ID_Core
+tag @a remove H.Bl_HaveID

data/h.block/recipes/re_holo_block.json

@@ -0,0 +1,23 @@
+{
+    "type": "minecraft:crafting_shaped",
+    "pattern": [
+        "#G#",
+        "GEG",
+        "#G#"
+    ],
+    "key": {
+        "#": {
+            "item": "minecraft:quartz"
+        },
+        "G": {
+            "item": "minecraft:glass"
+        },
+        "E": {
+            "item": "minecraft:ender_pearl"
+        }
+    },
+    "result": {
+        "item": "minecraft:chest",
+        "count": 1
+    }
+}

data/h.block/tags/blocks/can_replace.json

@@ -0,0 +1,22 @@
+{
+  "replace": false,
+  "values": [
+    "minecraft:tripwire_hook",
+	  "minecraft:tripwire",
+    "minecraft:air",
+    "minecraft:cave_air",
+    "minecraft:grass",
+    "minecraft:tall_grass",
+    "minecraft:fern",
+    "minecraft:large_fern",
+    "minecraft:seagrass",
+    "minecraft:tall_seagrass",
+    "minecraft:dead_bush",
+    "minecraft:vine",
+    "minecraft:water",
+    "minecraft:lava",
+    "minecraft:nether_sprouts",
+    "minecraft:crimson_roots",
+    "minecraft:warped_roots"
+  ]
+}

data/minecraft/tags/functions/load.json

@@ -0,0 +1,5 @@
+{
+  "values": [
+    "h.block:load"
+  ]
+}

data/minecraft/tags/functions/tick.json

@@ -0,0 +1,5 @@
+{
+  "values": [
+    "h.block:main"
+  ]
+}

pack.mcmeta

@@ -0,0 +1,6 @@
+{
+  "pack": {
+    "pack_format": 7,
+    "description": "Ver 1.0.2 [by Chuzume]"
+  }
+}