-
Notifications
You must be signed in to change notification settings - Fork 5
/
3_bbpptv_original.s
168 lines (143 loc) · 5.56 KB
/
3_bbpptv_original.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
/*
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 3 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software Foundation,
* Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
*
* Authors: Dahmun Goudarzi, Anthony Journault, Matthieu Rivain and François-
* Xavier Standaert
*
*/
AREA bbpptv_code, CODE, READONLY
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ;;
;; BBPPTV MULTIPLICATION MACROS ;;
;; ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ------------------------------------------------------------------------
;; Compute \alpha and xor it to an accumulator
MACRO
compute_alpha_and_xor $res, $tmp_a, $tmp_b, $addr_a, $addr_b, $i, $j
LDR $tmp_a, [$addr_a, $i, LSL #2]
LDR $tmp_b, [$addr_b, $j, LSL #2]
AND $tmp_a, $tmp_b
EOR $res, $tmp_a
LDR $tmp_a, [$addr_a, $j, LSL #2]
LDR $tmp_b, [$addr_b, $i, LSL #2]
AND $tmp_a, $tmp_b
EOR $res, $tmp_a
MEND
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ;;
;; BBPPTV MULTIPLICATION FUNCTION ;;
;; ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
original_bbpptv_mult
;; ------------------------------------------------------------------------
;; Init phase
LDR R7, =RNGTab
;; Table of the form [r | s] storing the random r and s
LDR R10, =randTable
;; ------------------------------------------------------------------------
;; Creating the s_i
MOV R12, #(MASKING_ORDER-2)
loopScreation
get_random R3, R7
ADD R4, R10, #(MASKING_ORDER<<1)*4
STR R3, [R4, R12, LSL #2]
SUBS R12, #2
BNE loopScreation
;; ------------------------------------------------------------------------
;; Cross products computation
MOV R12, #0
loopOverSharesBBPPTV
;; c_i = alpha_i,i
LDR R4, [R0,R12, LSL #2]
LDR R5, [R1,R12, LSL #2]
AND R8, R4, R5
;; nested loop
MOV R11, #(MASKING_ORDER-1)
loopNestedBBPPTV
ADD R4, R12, #2
CMP R4, R11
BHI noNestedLoops
;; t_ij += r_ij
get_random R6, R7
MOV R5, #MASKING_ORDER
MUL R4, R5, R12
ADD R4, R11
STR R6, [R10, R4, LSL #2]
;; t_ij += \alpha_i,j
compute_alpha_and_xor R6, R4, R5, R0, R1, R12, R11
;; t_ij += s_j-1
SUB R5, R11, #1
ADD R4, R10, #(MASKING_ORDER<<1)*4
LDR R3, [R4, R5, LSL #2]
EOR R6, R3
;; t_ij += \alpha_i,j-1
compute_alpha_and_xor R6, R4, R3, R0, R1, R12, R5
;; c_i += t_ij
EOR R8, R6
;; loop nested processing
SUB R11, #2
B loopNestedBBPPTV
noNestedLoops
;; ------------------------------------------------------------------------
;; Randomness correction
;; Comparison test between i and d mod 2 to enter (or not) the correction
MOV R4, #((MASKING_ORDER-1)<<31)
CMP R4, R12, LSL #31
BNE noCorrectionRIJ
;; Case where i and d mod 2 have same parity
SUBS R11, R12, #1
BMI endOfCorrection
loopOverCorrectionRJI
;; c_i = c_i + r_ji
MOV R5, #MASKING_ORDER
MUL R4, R5, R11
ADD R4, R12
LDR R3, [R10, R4, LSL #2]
EOR R8, R3
;; loop over correction of rij processing
SUBS R11, #1
BPL loopOverCorrectionRJI
B endOfCorrection
noCorrectionRIJ
;; Case where i and d mod 2 have different parity
ADD R11, R12, #1
;; t_ii+1 += r_ii+1
get_random R6, R7
MOV R5, #MASKING_ORDER
MUL R4, R5, R12
ADD R4, R11
STR R6, [R10, R4, LSL #2]
;; t_ii+1 += \alpha_i,i+1
compute_alpha_and_xor R6, R4, R5, R0, R1, R12, R11
;; c_i += t_ii+1
EOR R8, R6
endOfCorrection
;; Store the accumulator at each step i
STR R8, [R2, R12, LSL #2]
;; loop over shares processing
ADD R12, #1
CMP R12, #MASKING_ORDER
BNE loopOverSharesBBPPTV
BX LR
LTORG
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ;;
;; RANDOM TABLE USED FOR BBPPTV MULTIPLICATION ;;
;; ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
AREA bbpptv_data, DATA, READWRITE
randTable % 4*((MASKING_ORDER)*(MASKING_ORDER)+ MASKING_ORDER)