-
-
Notifications
You must be signed in to change notification settings - Fork 118
/
DW.Connectivity.Android.pas
337 lines (300 loc) · 11.1 KB
/
DW.Connectivity.Android.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
unit DW.Connectivity.Android;
{*******************************************************}
{ }
{ Kastri }
{ }
{ Delphi Worlds Cross-Platform Library }
{ }
{ Copyright 2020-2024 Dave Nottage under MIT license }
{ which is located in the root folder of this library }
{ }
{*******************************************************}
// **** NOTE **** If the target device has API level 21 or greater, you need to add dw-kastri-base.jar from the Lib folder to the Libraries node of the
// Android platform of the project in Project Manager
interface
uses
// Android
Androidapi.JNI.Net, Androidapi.JNI.GraphicsContentViewText, Androidapi.JNIBridge,
// DW
DW.Androidapi.JNI.DWNetworkCallback, DW.MultiReceiver.Android, DW.Connectivity;
type
TPlatformConnectivity = class;
TNetworks = TArray<JNetwork>;
TNetworkCallbackDelegate = class(TJavaLocal, JDWNetworkCallbackDelegate)
private
class var FConnectivityManager: JConnectivityManager;
private
FCallback: JDWNetworkCallback;
FIsPendingAvailable: Boolean;
FPlatformConnectivity: TPlatformConnectivity;
procedure ConnectivityChange;
procedure CheckConnectivityChange;
function IsConnectedToInternet: Boolean;
protected
class function ConnectivityManager: JConnectivityManager; static;
class function GetConnectedNetworkInfoFromNetwork(const ANetwork: JNetwork; const ASkipValidation: Boolean): JNetworkInfo; static;
class function GetConnectedNetworkInfo(const ASkipValidation: Boolean; const ANetworkType: Integer = -1): JNetworkInfo; static;
public
{ JDWNetworkCallbackDelegate }
procedure onAvailable(network: JNetwork); cdecl;
procedure onLost(network: JNetwork); cdecl;
procedure onUnavailable; cdecl;
public
constructor Create(const APlatformConnectivity: TPlatformConnectivity);
end;
TConnectivityReceiver = class(TMultiReceiver)
private
FPlatformConnectivity: TPlatformConnectivity;
protected
procedure Receive(context: JContext; intent: JIntent); override;
procedure ConfigureActions; override;
public
constructor Create(const APlatformConnectivity: TPlatformConnectivity);
end;
TPlatformConnectivity = class(TObject)
private
FCallbackDelegate: JDWNetworkCallbackDelegate;
FConnectivity: TConnectivity;
FIsConnectedToInternet: Boolean;
FReceiver: TConnectivityReceiver;
protected
procedure ConnectivityChange(const AIsConnected: Boolean);
function SkipValidation: Boolean;
public
class function GetLocalAddresses: TIPAddresses;
class function IsConnectedToInternet: Boolean; static;
class function IsWifiInternetConnection: Boolean; static;
public
constructor Create(const AConnectivity: TConnectivity);
destructor Destroy; override;
end;
implementation
uses
DW.OSLog,
// RTL
System.SysUtils, System.Classes,
// Android
Androidapi.JNI.JavaTypes, Androidapi.Helpers, Androidapi.JNI.Os, Androidapi.JNI, Androidapi.JNI.Java.Net;
type
TOpenConnectivity = class(TConnectivity);
{ TNetworkCallbackDelegate }
constructor TNetworkCallbackDelegate.Create(const APlatformConnectivity: TPlatformConnectivity);
begin
inherited Create;
FCallback := TJDWNetworkCallback.JavaClass.init(TAndroidHelper.Context, Self, False);
FPlatformConnectivity := APlatformConnectivity;
end;
function TNetworkCallbackDelegate.IsConnectedToInternet: Boolean;
var
LNetworks: TJavaObjectArray<JNetwork>;
I: Integer;
begin
Result := False;
LNetworks := ConnectivityManager.getAllNetworks;
try
for I := 0 to LNetworks.Length - 1 do
begin
if GetConnectedNetworkInfoFromNetwork(LNetworks[I], FPlatformConnectivity.SkipValidation) <> nil then
begin
Result := True;
Break;
end;
end;
finally
LNetworks.Sync;
end;
end;
procedure TNetworkCallbackDelegate.CheckConnectivityChange;
begin
// TOSLog.d('TDWNetworkCallbackDelegate.CheckConnectivityChange');
Sleep(500);
if FIsPendingAvailable then
TThread.Synchronize(nil, ConnectivityChange);
end;
procedure TNetworkCallbackDelegate.ConnectivityChange;
begin
FPlatformConnectivity.ConnectivityChange(IsConnectedToInternet);
end;
class function TNetworkCallbackDelegate.ConnectivityManager: JConnectivityManager;
var
LService: JObject;
begin
if FConnectivityManager = nil then
begin
LService := TAndroidHelper.Context.getSystemService(TJContext.JavaClass.CONNECTIVITY_SERVICE);
FConnectivityManager := TJConnectivityManager.Wrap(LService);
end;
Result := FConnectivityManager;
end;
procedure TNetworkCallbackDelegate.onAvailable(network: JNetwork);
begin
TOSLog.d('TDWNetworkCallbackDelegate.onAvailable');
FIsPendingAvailable := True;
TThread.CreateAnonymousThread(CheckConnectivityChange).Start;
end;
procedure TNetworkCallbackDelegate.onLost(network: JNetwork);
begin
TOSLog.d('TDWNetworkCallbackDelegate.onLost');
FIsPendingAvailable := False;
FPlatformConnectivity.ConnectivityChange(IsConnectedToInternet);
end;
procedure TNetworkCallbackDelegate.onUnavailable;
begin
//
end;
// Based on: https://github.com/jamesmontemagno/ConnectivityPlugin/issues/56
class function TNetworkCallbackDelegate.GetConnectedNetworkInfo(const ASkipValidation: Boolean; const ANetworkType: Integer = -1): JNetworkInfo;
var
LAllNetworks: TJavaObjectArray<JNetwork>;
LAllNetworkInfo: TJavaObjectArray<JNetworkInfo>;
LInfo: JNetworkInfo;
I: Integer;
begin
Result := nil;
if TJBuild_VERSION.JavaClass.SDK_INT >= 21 then
begin
LAllNetworks := ConnectivityManager.getAllNetworks;
try
for I := 0 to LAllNetworks.Length - 1 do
begin
LInfo := GetConnectedNetworkInfoFromNetwork(LAllNetworks[I], ASkipValidation);
if (LInfo <> nil) and ((ANetworkType = -1) or (LInfo.getType = ANetworkType)) then
begin
Result := LInfo;
Break;
end;
end;
finally
LAllNetworks.Sync;
end;
end
else
begin
LAllNetworkInfo := ConnectivityManager.getAllNetworkInfo;
try
for I := 0 to LAllNetworkInfo.Length - 1 do
begin
LInfo := LAllNetworkInfo[I];
if (LInfo <> nil) and ((ANetworkType = -1) or (LInfo.getType = ANetworkType)) and LInfo.isAvailable and LInfo.isConnected then
begin
Result := LInfo;
Break;
end;
end;
finally
LAllNetworkInfo.Sync;
end;
end;
end;
class function TNetworkCallbackDelegate.GetConnectedNetworkInfoFromNetwork(const ANetwork: JNetwork; const ASkipValidation: Boolean): JNetworkInfo;
var
LCapabilities: JNetworkCapabilities;
LInfo: JNetworkInfo;
begin
LInfo := nil;
LCapabilities := ConnectivityManager.getNetworkCapabilities(ANetwork);
// Check if the network has internet capability
if (LCapabilities <> nil) and LCapabilities.hasCapability(TJNetworkCapabilities.JavaClass.NET_CAPABILITY_INTERNET) and
LCapabilities.hasCapability(TJNetworkCapabilities.JavaClass.NET_CAPABILITY_NOT_VPN) then
begin
// ..and is Validated or SDK < 23
if ASkipValidation or (TJBuild_VERSION.JavaClass.SDK_INT < 23) or LCapabilities.hasCapability(TJNetworkCapabilities.JavaClass.NET_CAPABILITY_VALIDATED) then
begin
LInfo := ConnectivityManager.getNetworkInfo(ANetwork);
if (LInfo <> nil) and LInfo.isAvailable and LInfo.isConnected then
Result := LInfo;
end;
// else
// TOSLog.d('Not validated');
end;
end;
{ TConnectivityReceiver }
constructor TConnectivityReceiver.Create(const APlatformConnectivity: TPlatformConnectivity);
begin
inherited Create;
FPlatformConnectivity := APlatformConnectivity;
end;
procedure TConnectivityReceiver.ConfigureActions;
begin
IntentFilter.addAction(TJConnectivityManager.JavaClass.CONNECTIVITY_ACTION);
end;
procedure TConnectivityReceiver.Receive(context: JContext; intent: JIntent);
begin
if TJBuild_VERSION.JavaClass.SDK_INT < 21 then
begin
TOSLog.d('TConnectivityReceiver.Receive');
FPlatformConnectivity.ConnectivityChange(TNetworkCallbackDelegate.GetConnectedNetworkInfo(FPlatformConnectivity.SkipValidation) <> nil);
end;
end;
{ TPlatformConnectivity }
constructor TPlatformConnectivity.Create(const AConnectivity: TConnectivity);
begin
inherited Create;
FConnectivity := AConnectivity;
FIsConnectedToInternet := IsConnectedToInternet;
if TJBuild_VERSION.JavaClass.SDK_INT >= 21 then
FCallbackDelegate := TNetworkCallbackDelegate.Create(Self);
FReceiver := TConnectivityReceiver.Create(Self);
TOSLog.d('TPlatformConnectivity.Create > Connected: %s', [BoolToStr(FIsConnectedToInternet, True)]);
end;
destructor TPlatformConnectivity.Destroy;
begin
// FCallbackDelegate.Free;
FReceiver.Free;
inherited;
end;
class function TPlatformConnectivity.GetLocalAddresses: TIPAddresses;
var
LInterfaces, LAddresses: JEnumeration;
LAddress: JInetAddress;
LIPAddress: TIPAddress;
LClassName: string;
begin
LInterfaces := TJNetworkInterface.JavaClass.getNetworkInterfaces;
while LInterfaces.hasMoreElements do
begin
LAddresses := TJNetworkInterface.Wrap(LInterfaces.nextElement).getInetAddresses;
while LAddresses.hasMoreElements do
begin
LAddress := TJInetAddress.Wrap(LAddresses.nextElement);
if not LAddress.isLoopbackAddress then
begin
LClassName := JStringToString(LAddress.getClass.getName);
if LClassName.Contains('Inet4Address') then
LIPAddress.Version := TIPVersion.IPv4
else if LClassName.Contains('Inet6Address') then
LIPAddress.Version := TIPVersion.IPv6;
LIPAddress.IP := JStringToString(LAddress.getHostAddress);
if LIPAddress.IP.IndexOf('%') > -1 then
LIPAddress.IP := LIPAddress.IP.Substring(0, LIPAddress.IP.IndexOf('%'));
Result := Result + [LIPAddress];
end;
end;
end;
end;
class function TPlatformConnectivity.IsConnectedToInternet: Boolean;
begin
Result := TNetworkCallbackDelegate.GetConnectedNetworkInfo(False) <> nil;
end;
class function TPlatformConnectivity.IsWifiInternetConnection: Boolean;
var
LInfo: JNetworkInfo;
begin
LInfo := TNetworkCallbackDelegate.GetConnectedNetworkInfo(False, TJConnectivityManager.JavaClass.TYPE_WIFI);
Result := LInfo <> nil;
end;
function TPlatformConnectivity.SkipValidation: Boolean;
begin
Result := FConnectivity.SkipValidation;
end;
procedure TPlatformConnectivity.ConnectivityChange(const AIsConnected: Boolean);
begin
TOSLog.d('TPlatformConnectivity.ConnectivityChange(%s)', [BoolToStr(AIsConnected, True)]);
if FIsConnectedToInternet <> AIsConnected then
begin
TOSLog.d('> Changed from %s', [BoolToStr(FIsConnectedToInternet, True)]);
FIsConnectedToInternet := AIsConnected;
TOpenConnectivity(FConnectivity).DoConnectivityChange(FIsConnectedToInternet);
end;
end;
end.